csit/suites/bgpcep/bgpingest/manypeers_peercount.robot

   1 *** Settings ***
   2 Documentation     BGP performance of ingesting from many iBGP rrc peers, iBGPs receive updates.
   3 ...
   4 ...               Copyright (c) 2016 Cisco Systems, Inc. and others. All rights reserved.
   5 ...
   6 ...               This program and the accompanying materials are made available under the
   7 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   8 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
   9 ...
  10 ...               This suite uses play.py processes as iBGP rrc peers.
  11 ...               This is analogue of single peer performance suite, which uses many peers.
  12 ...               Each peer is of ibgp rrc type, and they contribute to the same example-bgp-rib,
  13 ...               and thus to the same single example-ipv4-topology.
  14 ...               The suite looks at example-ipv4-topology and checks BGP peers log for received updates.
  15 ...
  16 ...               ODL distinguishes peers by their IP addresses.
  17 ...               Currently, this suite requires python utils to be started on ODL System,
  18 ...               to guarantee IP address block is available for them to bind to.
  19 ...
  20 ...               Brief description how to configure BGP peer can be found here:
  21 ...               https://wiki.opendaylight.org/view/BGP_LS_PCEP:User_Guide#BGP_Peer
  22 ...               http://docs.opendaylight.org/en/stable-boron/user-guide/bgp-user-guide.html#bgp-peering
  23 Suite Setup       Setup_Everything
  24 Suite Teardown    Teardown_Everything
  25 Test Setup        SetupUtils.Setup_Test_With_Logging_And_Fast_Failing
  26 Test Teardown     SetupUtils.Teardown_Test_Show_Bugs_And_Start_Fast_Failing_If_Test_Failed
  27 Library           DateTime
  28 Library           RequestsLibrary
  29 Library           SSHLibrary    timeout=10s
  30 Resource          ../../../libraries/BGPSpeaker.robot
  31 Resource          ../../../libraries/FailFast.robot
  32 Resource          ../../../libraries/KarafKeywords.robot
  33 Resource          ../../../libraries/KillPythonTool.robot
  34 Resource          ../../../libraries/PrefixCounting.robot
  35 Resource          ../../../libraries/SetupUtils.robot
  36 Resource          ../../../libraries/SSHKeywords.robot
  37 Resource          ../../../libraries/TemplatedRequests.robot
  38 Resource          ../../../libraries/Utils.robot
  39 Resource          ../../../variables/Variables.robot
  40
  41 *** Variables ***
  42 ${BGP_TOOL_LOG_LEVEL}    info
  43 ${BGP_PEERS_LOG_FILE_NAME}    bgp_peer.log
  44 ${BGP_VARIABLES_FOLDER}    ${CURDIR}/../../../variables/bgpuser/
  45 ${CHECK_PERIOD_PREFIX_COUNT_MANY_RRC}    60
  46 ${COUNT}          300000    # With AdjRibsOut, the amount of data present is on the same scale as 600k ingest with single peer.
  47 ${COUNT_PREFIX_COUNT_MANY_RRC}    ${COUNT}
  48 ${FIRST_PEER_IP}    127.0.0.1
  49 ${HOLDTIME}       180
  50 ${HOLDTIME_PREFIX_COUNT_MANY_RRC}    ${HOLDTIME}
  51 ${KARAF_LOG_LEVEL}    INFO
  52 ${KARAF_BGPCEP_LOG_LEVEL}    ${KARAF_LOG_LEVEL}
  53 ${KARAF_PROTOCOL_LOG_LEVEL}    ${KARAF_BGPCEP_LOG_LEVEL}
  54 ${MULTIPLICITY_PREFIX_COUNT_MANY_RRC}    2
  55 ${REPETITIONS_PREFIX_COUNT_MANY_RRC}    2
  56 ${TEST_DURATION_MULTIPLIER}    1
  57 ${TEST_DURATION_MULTIPLIER_PREFIX_COUNT_MANY_RRC}    ${TEST_DURATION_MULTIPLIER}
  58 ${RIB_INSTANCE}    example-bgp-rib
  59 ${PROTOCOL_OPENCONFIG}    ${RIB_INSTANCE}
  60 ${DEVICE_NAME}    controller-config
  61
  62 *** Test Cases ***
  63 Check_For_Empty_Ipv4_Topology_Before_Talking
  64     [Documentation]    Wait for example-ipv4-topology to come up and empty. Give large timeout for case when BGP boots slower than restconf.
  65     [Tags]    critical
  66     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
  67     BuiltIn.Wait_Until_Keyword_Succeeds    120s    1s    PrefixCounting.Check_Ipv4_Topology_Is_Empty
  68
  69 Reconfigure_ODL_To_Accept_Connections
  70     [Documentation]    Configure BGP peer modules with initiate-connection set to false.
  71     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
  72     FOR    ${index}    IN RANGE    1    ${MULTIPLICITY_PREFIX_COUNT_MANY_RRC}+1
  73         ${peer_name} =    BuiltIn.Set_Variable    example-bgp-peer-${index}
  74         ${peer_ip} =    BuiltIn.Evaluate    str(ipaddr.IPAddress('${FIRST_PEER_IP}') + ${index} - 1)    modules=ipaddr
  75         &{mapping}    BuiltIn.Create_Dictionary    DEVICE_NAME=${DEVICE_NAME}    NAME=${peer_name}    IP=${peer_ip}    HOLDTIME=${HOLDTIME_PREFIX_COUNT_MANY_RRC}
  76         ...    PEER_PORT=${BGP_TOOL_PORT}    PEER_ROLE=rr-client    INITIATE=false    BGP_RIB=${RIB_INSTANCE}    PASSIVE_MODE=true
  77         ...    BGP_RIB_OPENCONFIG=${PROTOCOL_OPENCONFIG}    RIB_INSTANCE_NAME=${RIB_INSTANCE}    RR_CLIENT=true
  78         TemplatedRequests.Put_As_Xml_Templated    ${BGP_VARIABLES_FOLDER}${/}ibgp_peers    mapping=${mapping}
  79     END
  80
  81 Start_Talking_BGP_Manager
  82     [Documentation]    Start Python manager to connect speakers to ODL.
  83     BGPSpeaker.Start_BGP_Manager    --amount=${COUNT_PREFIX_COUNT_MANY_RRC} --multiplicity=${MULTIPLICITY_PREFIX_COUNT_MANY_RRC} --myip=${FIRST_PEER_IP} --myport=${BGP_TOOL_PORT} --peerip=${ODL_SYSTEM_IP} --peerport=${ODL_BGP_PORT} --logfile=${BGP_PEERS_LOG_FILE_NAME} --${BGP_TOOL_LOG_LEVEL}
  84
  85 Wait_For_Ipv4_Topology
  86     [Documentation]    Wait until example-ipv4-topology reaches the target prefix count.
  87     [Tags]    critical
  88     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
  89     BuiltIn.Log    max. ${bgp_filling_timeout}s    console=yes
  90     Init_Check_Ipv4_Topology_Keyword    ${COUNT_PREFIX_COUNT_MANY_RRC}    ${REPETITIONS_PREFIX_COUNT_MANY_RRC}
  91     ${message}=    BuiltIn.Wait_Until_Keyword_Succeeds    ${bgp_filling_timeout}    ${CHECK_PERIOD_PREFIX_COUNT_MANY_RRC}    Check_Ipv4_Topology
  92     BuiltIn.Should_Be_Equal_As_Strings    ${message}    Target value reached.
  93
  94 Check_Logs_For_Updates
  95     [Documentation]    Check BGP peer logs for received updates.
  96     [Tags]    critical
  97     ${timeout} =    BuiltIn.Set_Variable    ${bgp_filling_timeout}
  98     FOR    ${index}    IN RANGE    1    ${MULTIPLICITY_PREFIX_COUNT_MANY_RRC}+1
  99         ${bgp_peer_label} =    BuiltIn.Set_Variable    BGP-Dummy-${index}
 100         ${expected_prefixcount} =    BuiltIn.Evaluate    ${COUNT_PREFIX_COUNT_MANY_RRC} - ${COUNT_PREFIX_COUNT_MANY_RRC} / ${MULTIPLICITY_PREFIX_COUNT_MANY_RRC}
 101         ${expected_string} =    BuiltIn.Set_Variable    total_received_nlri_prefix_counter: ${expected_prefixcount}
 102         BuiltIn.Wait_Until_Keyword_Succeeds    ${timeout}    1s    Check_File_For_Occurence    ${BGP_PEERS_LOG_FILE_NAME}    ${bgp_peer_label}
 103         ...    ${expected_string}    2
 104         ${timeout} =    BuiltIn.Set_Variable    20s
 105         # FIXME: Calculation of ${expected_prefixcount} correct just when the ${COUNT_PREFIX_COUNT_MANY_RRC} is a multiplication of ${MULTIPLICITY_PREFIX_COUNT_MANY_RRC}
 106     END
 107
 108 Kill_Talking_BGP_Speakers
 109     [Documentation]    Abort the Python speakers. Also, attempt to stop failing fast.
 110     [Tags]    critical
 111     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 112     BGPSpeaker.Kill_BGP_Speaker
 113     FailFast.Do_Not_Fail_Fast_From_Now_On
 114     # NOTE: It is still possible to remain failing fast, if both previous and this test have failed.
 115     [Teardown]    FailFast.Do_Not_Start_Failing_If_This_Failed
 116
 117 Wait_For_Stable_Ipv4_Topology_After_Talking
 118     [Documentation]    Wait until example-ipv4-topology becomes stable again.
 119     [Tags]    critical
 120     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 121     PrefixCounting.Wait_For_Ipv4_Topology_Prefixes_To_Become_Stable    timeout=${bgp_emptying_timeout}    period=${CHECK_PERIOD_PREFIX_COUNT_MANY_RRC}    repetitions=${REPETITIONS_PREFIX_COUNT_MANY_RRC}    excluded_count=${COUNT_PREFIX_COUNT_MANY_RRC}
 122
 123 Check_For_Empty_Ipv4_Topology_After_Talking
 124     [Documentation]    Example-ipv4-topology should be empty now.
 125     [Tags]    critical
 126     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 127     PrefixCounting.Check_Ipv4_Topology_Is_Empty
 128
 129 Delete_Bgp_Peer_Configuration
 130     [Documentation]    Revert the BGP configuration to the original state: without any configured peers.
 131     [Tags]    critical
 132     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 133     FOR    ${index}    IN RANGE    1    ${MULTIPLICITY_PREFIX_COUNT_MANY_RRC}+1
 134         ${peer_name} =    BuiltIn.Set_Variable    example-bgp-peer-${index}
 135         ${peer_ip} =    BuiltIn.Evaluate    str(ipaddr.IPAddress('${FIRST_PEER_IP}') + ${index} - 1)    modules=ipaddr
 136         &{mapping}    BuiltIn.Create_Dictionary    DEVICE_NAME=${DEVICE_NAME}    NAME=${peer_name}    IP=${peer_ip}    BGP_RIB_OPENCONFIG=${PROTOCOL_OPENCONFIG}
 137         TemplatedRequests.Delete_Templated    ${BGP_VARIABLES_FOLDER}${/}ibgp_peers    mapping=${mapping}
 138     END
 139
 140 *** Keywords ***
 141 Setup_Everything
 142     [Documentation]    Setup imported resources, SSH-login to ODL system,
 143     ...    create HTTP session, put Python tool to ODL system.
 144     SetupUtils.Setup_Utils_For_Setup_And_Teardown
 145     TemplatedRequests.Create_Default_Session
 146     PrefixCounting.PC_Setup
 147     RequestsLibrary.Create_Session    operational    http://${ODL_SYSTEM_IP}:${RESTCONFPORT}    auth=${AUTH}    timeout=125    max_retries=0
 148     # TODO: Do not include slash in ${OPERATIONAL_TOPO_API}, having it typed here is more readable.
 149     # TODO: Alternatively, create variable in Variables which starts with http.
 150     # Both TODOs would probably need to update every suite relying on current Variables.
 151     SSHLibrary.Set_Default_Configuration    prompt=${ODL_SYSTEM_PROMPT}
 152     SSHLibrary.Open_Connection    ${ODL_SYSTEM_IP}
 153     SSHKeywords.Flexible_Controller_Login
 154     SSHKeywords.Require_Python
 155     SSHKeywords.Assure_Library_Ipaddr    target_dir=.
 156     SSHLibrary.Put_File    ${CURDIR}/../../../../tools/fastbgp/play.py
 157     # Calculate the timeout value based on how many routes are going to be pushed.
 158     ${period} =    DateTime.Convert_Time    ${CHECK_PERIOD_PREFIX_COUNT_MANY_RRC}    result_format=number
 159     ${timeout} =    BuiltIn.Evaluate    ${MULTIPLICITY_PREFIX_COUNT_MANY_RRC} * ${TEST_DURATION_MULTIPLIER_PREFIX_COUNT_MANY_RRC} * (${COUNT_PREFIX_COUNT_MANY_RRC} * 6.0 / 10000 + ${period} * (${REPETITIONS_PREFIX_COUNT_MANY_RRC} + 1)) + 20
 160     Builtin.Set_Suite_Variable    ${bgp_filling_timeout}    ${timeout}
 161     ${timeout} =    BuiltIn.Evaluate    ${TEST_DURATION_MULTIPLIER_PREFIX_COUNT_MANY_RRC} * (${COUNT_PREFIX_COUNT_MANY_RRC} * 2.0 / 10000 + ${period} * (${REPETITIONS_PREFIX_COUNT_MANY_RRC} + 1)) + 20
 162     Builtin.Set_Suite_Variable    ${bgp_emptying_timeout}    ${timeout}
 163     KarafKeywords.Execute_Controller_Karaf_Command_On_Background    log:set ${KARAF_LOG_LEVEL}
 164
 165 Teardown_Everything
 166     [Documentation]    Make sure Python tool was killed and tear down imported Resources.
 167     # Environment issue may have dropped the SSH connection, but we do not want Teardown to fail.
 168     BuiltIn.Run_Keyword_And_Ignore_Error    KillPythonTool.Search_And_Kill_Remote_Python    'play\.py'
 169     BuiltIn.Run_Keyword_And_Ignore_Error    Utils.Get_Sysstat_Statistics
 170     RequestsLibrary.Delete_All_Sessions
 171     SSHLibrary.Close_All_Connections
 172
 173 Init_Check_Ipv4_Topology_Keyword
 174     [Arguments]    ${expected_count}=0    ${deadlock_cycles}=-1
 175     [Documentation]    Initialise test variables for Check_Ipv4_Topology keyword.
 176     ${deadlock_cycles}=    Convert To Integer    ${deadlock_cycles}
 177     BuiltIn.Set_Test_Variable    ${deadlock_cycles}
 178     BuiltIn.Set_Test_Variable    ${ipv4_topology_deadlock_countdown}    ${deadlock_cycles}
 179     BuiltIn.Set_Test_Variable    ${expected_count}
 180     BuiltIn.Set_Test_Variable    ${ipv4_topology_last_count}    -1
 181
 182 Check_Ipv4_Topology
 183     [Documentation]    Check and log the IPv4 topology count. PASS if ${expected_count} or ${actual_count} not changed for ${deadlock_cycles} keyword calls.
 184     ${actual_count} =    PrefixCounting.Get_Ipv4_Topology_Count
 185     ${ipv4_topology_deadlock_countdown}=    BuiltIn.Set_Variable_If    (${actual_count} == ${ipv4_topology_last_count}) and (${ipv4_topology_deadlock_countdown} >= 0)    ${ipv4_topology_deadlock_countdown - 1}    ${deadlock_cycles}
 186     ${hour}    ${min}    ${sec} =    BuiltIn.Get_Time    hour min sec
 187     BuiltIn.Set_Test_Variable    ${ipv4_topology_deadlock_countdown}
 188     BuiltIn.Set_Test_Variable    ${ipv4_topology_last_count}    ${actual_count}
 189     BuiltIn.Log    ${hour}:${min}:${sec} actual/expected prefix count is ${actual_count}/${expected_count} (countdown:${ipv4_topology_deadlock_countdown})    console=yes
 190     BuiltIn.Return_From_Keyword_If    ${ipv4_topology_deadlock_countdown} == 0    Deadlock detected (ipv4-topology not changed for ${deadlock_cycles} cycles)
 191     BuiltIn.Should_Be_Equal_As_Integers    ${actual_count}    ${expected_count}
 192     [Return]    Target value reached.
 193
 194 Check_File_For_Occurence
 195     [Arguments]    ${file_name}    ${keyword}    ${value}=''    ${threshold}=1
 196     [Documentation]    Check file for ${keyword} or ${keyword} ${value} pair and returns number of occurences
 197     ${output_log}=    SSHLibrary.Execute_Command    grep '${keyword}' '${file_name}' | grep -c '${value}'
 198     ${count}=    Convert To Integer    ${output_log}
 199     BuiltIn.Should_Be_True    ${count} >= ${threshold}
 200     [Return]    ${count}