csit/suites/bgpcep/bgpingest/manypeers_prefixcount.robot

   1 *** Settings ***
   2 Documentation     BGP performance of ingesting from many iBGP peers, data change counter NOT used.
   3 ...
   4 ...               Copyright (c) 2015 Cisco Systems, Inc. and others. All rights reserved.
   5 ...
   6 ...               This program and the accompanying materials are made available under the
   7 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   8 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
   9 ...
  10 ...
  11 ...               This suite uses play.py processes as iBGP peers.
  12 ...               This is analogue of single peer performance suite, which uses many peers.
  13 ...               Each peer is of ibgp type, and they contribute to the same example-bgp-rib,
  14 ...               and thus to the same single example-ipv4-topology.
  15 ...               The suite only looks at example-ipv4-topology, so RIB is not examined.
  16 ...
  17 ...               The suite consists of two halves, differing on which side initiates BGP connection.
  18 ...               State of "work is being done" is detected by increasing value of prefixes in topology.
  19 ...               The time for Wait_For_Stable_* cases to finish is the main performance metric.
  20 ...               After waiting for stability is done, full check on number of prefixes present is performed.
  21 ...
  22 ...               TODO: Currently, if a bug causes prefix count to remain at zero,
  23 ...               affected test cases will wait for max time. Reconsider.
  24 ...               If zero is allowed as stable, higher period or repetitions would be required.
  25 ...
  26 ...               The prefix counting is quite heavyweight and may induce large variation in time.
  27 ...               Try the other version of the suite (manypeers_changecount.robot) to get better precision.
  28 ...
  29 ...               ODL distinguishes peers by their IP addresses.
  30 ...               Currently, this suite requires python utils to be started on ODL System,
  31 ...               to guarantee IP address block is available for them to bind to.
  32 ...               TODO: Figure out how to use Docker and docker IP pool available in RelEng.
  33 ...
  34 ...               Currently, 127.0.0.1 is hardcoded as the first peer address to use.
  35 ...               TODO: Figure out how to make it configurable.
  36 ...               As peer IP adresses are set incrementally, we need ipaddr to be used in Robot somehow.
  37 ...
  38 ...               Brief description how to configure BGP peer can be found here:
  39 ...               https://wiki.opendaylight.org/view/BGP_LS_PCEP:User_Guide#BGP_Peer
  40 ...               http://docs.opendaylight.org/en/stable-boron/user-guide/bgp-user-guide.html#bgp-peering
  41 ...
  42 ...               TODO: Is there a need for version of this suite where ODL connects to pers?
  43 ...               Note that configuring ODL is slow, which may affect measured performance singificantly.
  44 ...               Advanced TODO: Give manager ability to start pushing on trigger long after connections are established.
  45 Suite Setup       Setup_Everything
  46 Suite Teardown    Teardown_Everything
  47 Test Setup        SetupUtils.Setup_Test_With_Logging_And_Fast_Failing
  48 Test Teardown     SetupUtils.Teardown_Test_Show_Bugs_And_Start_Fast_Failing_If_Test_Failed
  49 Library           DateTime
  50 Library           RequestsLibrary
  51 Library           SSHLibrary    timeout=10s
  52 Resource          ../../../libraries/BGPSpeaker.robot
  53 Resource          ../../../libraries/FailFast.robot
  54 Resource          ../../../libraries/KarafKeywords.robot
  55 Resource          ../../../libraries/KillPythonTool.robot
  56 Resource          ../../../libraries/PrefixCounting.robot
  57 Resource          ../../../libraries/SetupUtils.robot
  58 Resource          ../../../libraries/SSHKeywords.robot
  59 Resource          ../../../libraries/TemplatedRequests.robot
  60 Resource          ../../../libraries/Utils.robot
  61 Resource          ../../../variables/Variables.robot
  62
  63 *** Variables ***
  64 ${BGP_TOOL_LOG_LEVEL}    info
  65 ${BGP_VARIABLES_FOLDER}    ${CURDIR}/../../../variables/bgpuser/
  66 ${CHECK_PERIOD}    60    # ${MULTIPLICITY*2} recommended for this suite, but keeping the common default.
  67 ${CHECK_PERIOD_PREFIX_COUNT}    ${CHECK_PERIOD}
  68 ${CHECK_PERIOD_PREFIX_COUNT_MANY}    ${CHECK_PERIOD_PREFIX_COUNT}
  69 ${COUNT}          600000
  70 ${COUNT_PREFIX_COUNT}    ${COUNT}
  71 ${COUNT_PREFIX_COUNT_MANY}    ${COUNT_PREFIX_COUNT}
  72 ${FIRST_PEER_IP}    127.0.0.1
  73 ${HOLDTIME}       180
  74 ${HOLDTIME_PREFIX_COUNT}    ${HOLDTIME}
  75 ${HOLDTIME_PREFIX_COUNT_MANY}    ${HOLDTIME_PREFIX_COUNT}
  76 ${KARAF_LOG_LEVEL}    INFO
  77 ${KARAF_BGPCEP_LOG_LEVEL}    ${KARAF_LOG_LEVEL}
  78 ${KARAF_PROTOCOL_LOG_LEVEL}    ${KARAF_BGPCEP_LOG_LEVEL}
  79 ${MULTIPLICITY}    2    # Changed in releng-builder variables
  80 ${MULTIPLICITY_PREFIX_COUNT}    ${MULTIPLICITY}
  81 ${MULTIPLICITY_PREFIX_COUNT_MANY}    ${MULTIPLICITY_PREFIX_COUNT}
  82 ${REPETITIONS}    1
  83 ${REPETITIONS_PREFIX_COUNT}    ${REPETITIONS}
  84 ${REPETITIONS_PREFIX_COUNT_MANY}    ${REPETITIONS_PREFIX_COUNT}
  85 ${TEST_DURATION_MULTIPLIER}    1
  86 ${TEST_DURATION_MULTIPLIER_PREFIX_COUNT}    ${TEST_DURATION_MULTIPLIER}
  87 ${TEST_DURATION_MULTIPLIER_PREFIX_COUNT_MANY}    ${TEST_DURATION_MULTIPLIER_PREFIX_COUNT}
  88 ${RIB_INSTANCE}    example-bgp-rib
  89 ${PROTOCOL_OPENCONFIG}    ${RIB_INSTANCE}
  90 ${DEVICE_NAME}    controller-config
  91 # TODO: Option names can be better.
  92
  93 *** Test Cases ***
  94 Check_For_Empty_Ipv4_Topology_Before_Talking
  95     [Documentation]    Wait for example-ipv4-topology to come up and empty. Give large timeout for case when BGP boots slower than restconf.
  96     [Tags]    critical
  97     # TODO: Choose which tags to assign and make sure they are assigned correctly.
  98     BuiltIn.Wait_Until_Keyword_Succeeds    120s    1s    PrefixCounting.Check_Ipv4_Topology_Is_Empty
  99
 100 Reconfigure_ODL_To_Accept_Connections
 101     [Documentation]    Configure BGP peer modules with initiate-connection set to false.
 102     FOR    ${index}    IN RANGE    1    ${MULTIPLICITY_PREFIX_COUNT_MANY}+1
 103         ${peer_name} =    BuiltIn.Set_Variable    example-bgp-peer-${index}
 104         ${peer_ip} =    BuiltIn.Evaluate    str(ipaddr.IPAddress('${FIRST_PEER_IP}') + ${index} - 1)    modules=ipaddr
 105         &{mapping}    Create Dictionary    DEVICE_NAME=${DEVICE_NAME}    BGP_NAME=${peer_name}    IP=${peer_ip}    HOLDTIME=${HOLDTIME_PREFIX_COUNT_MANY}
 106         ...    PEER_PORT=${BGP_TOOL_PORT}    INITIATE=false    BGP_RIB=${RIB_INSTANCE}    PASSIVE_MODE=true    BGP_RIB_OPENCONFIG=${PROTOCOL_OPENCONFIG}
 107         ...    RIB_INSTANCE_NAME=${RIB_INSTANCE}
 108         TemplatedRequests.Put_As_Xml_Templated    ${BGP_VARIABLES_FOLDER}${/}bgp_peer    mapping=${mapping}
 109         # FIXME: Add testcase to change bgpcep and protocol log levels, when a Keyword that does it without messing with current connection is ready.
 110     END
 111
 112 Change_Karaf_Logging_Levels
 113     [Documentation]    We may want to set more verbose logging here after configuration is done.
 114     KarafKeywords.Set_Bgpcep_Log_Levels    bgpcep_level=${KARAF_BGPCEP_LOG_LEVEL}    protocol_level=${KARAF_PROTOCOL_LOG_LEVEL}
 115
 116 Start_Talking_BGP_Manager
 117     [Documentation]    Start Python manager to connect speakers to ODL.
 118     # Myport value is needed for checking whether connection at precise port was established.
 119     BGPSpeaker.Start_BGP_Manager    --amount=${COUNT_PREFIX_COUNT_MANY} --multiplicity=${MULTIPLICITY_PREFIX_COUNT_MANY} --myip=${FIRST_PEER_IP} --myport=${BGP_TOOL_PORT} --peerip=${ODL_SYSTEM_IP} --peerport=${ODL_BGP_PORT}
 120
 121 Wait_For_Stable_Talking_Ipv4_Topology
 122     [Documentation]    Wait until example-ipv4-topology becomes stable. This is done by checking stability of prefix count.
 123     PrefixCounting.Wait_For_Ipv4_Topology_Prefixes_To_Become_Stable    timeout=${bgp_filling_timeout}    period=${CHECK_PERIOD_PREFIX_COUNT_MANY}    repetitions=${REPETITIONS_PREFIX_COUNT_MANY}    excluded_count=0
 124
 125 Check_Talking_Ipv4_Topology_Count
 126     [Documentation]    Count the routes in example-ipv4-topology and fail if the count is not correct.
 127     [Tags]    critical
 128     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 129     PrefixCounting.Check_Ipv4_Topology_Count    ${COUNT_PREFIX_COUNT_MANY}
 130
 131 Kill_Talking_BGP_Speakers
 132     [Documentation]    Abort the Python speakers. Also, attempt to stop failing fast.
 133     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 134     BGPSpeaker.Kill_BGP_Speaker
 135     FailFast.Do_Not_Fail_Fast_From_Now_On
 136     # NOTE: It is still possible to remain failing fast, if both previous and this test have failed.
 137     [Teardown]    SetupUtils.Teardown_Test_Show_Bugs_If_Test_Failed
 138
 139 Wait_For_Stable_Ipv4_Topology_After_Talking
 140     [Documentation]    Wait until example-ipv4-topology becomes stable again.
 141     [Tags]    critical
 142     # TODO: Is is possible to have failed at Check_Talking_Ipv4_Topology_Count and still have initial period of constant count?
 143     # FIXME: If yes, do count here to get the initial value and use it (if nonzero).
 144     # TODO: If yes, decide whether access to the FailFast state should have keyword or just variable name.
 145     PrefixCounting.Wait_For_Ipv4_Topology_Prefixes_To_Become_Stable    timeout=${bgp_filling_timeout}    period=${CHECK_PERIOD_PREFIX_COUNT_MANY}    repetitions=${REPETITIONS_PREFIX_COUNT_MANY}    excluded_count=${COUNT_PREFIX_COUNT_MANY}
 146
 147 Check_For_Empty_Ipv4_Topology_After_Talking
 148     [Documentation]    Example-ipv4-topology should be empty now.
 149     [Tags]    critical
 150     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 151     PrefixCounting.Check_Ipv4_Topology_Is_Empty
 152
 153 Restore_Karaf_Logging_Levels
 154     [Documentation]    Set logging on bgpcep and protocol to the global value.
 155     KarafKeywords.Set_Bgpcep_Log_Levels    bgpcep_level=${KARAF_LOG_LEVEL}    protocol_level=${KARAF_LOG_LEVEL}
 156
 157 Delete_Bgp_Peer_Configuration
 158     [Documentation]    Revert the BGP configuration to the original state: without any configured peers.
 159     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 160     # TODO: Is it useful to extract peer naming logic to separate Keyword?
 161     FOR    ${index}    IN RANGE    1    ${MULTIPLICITY_PREFIX_COUNT_MANY}+1
 162         ${peer_name} =    BuiltIn.Set_Variable    example-bgp-peer-${index}
 163         ${peer_ip} =    BuiltIn.Evaluate    str(ipaddr.IPAddress('${FIRST_PEER_IP}') + ${index} - 1)    modules=ipaddr
 164         &{mapping}    BuiltIn.Create_Dictionary    DEVICE_NAME=${DEVICE_NAME}    BGP_NAME=${peer_name}    IP=${peer_ip}    BGP_RIB_OPENCONFIG=${PROTOCOL_OPENCONFIG}
 165         TemplatedRequests.Delete_Templated    ${BGP_VARIABLES_FOLDER}${/}bgp_peer    mapping=${mapping}
 166     END
 167
 168 *** Keywords ***
 169 Setup_Everything
 170     [Documentation]    Setup imported resources, SSH-login to ODL system,
 171     ...    create HTTP session, put Python tool to ODL system.
 172     SetupUtils.Setup_Utils_For_Setup_And_Teardown
 173     TemplatedRequests.Create_Default_Session
 174     PrefixCounting.PC_Setup
 175     RequestsLibrary.Create_Session    operational    http://${ODL_SYSTEM_IP}:${RESTCONFPORT}    auth=${AUTH}    timeout=125    max_retries=0
 176     # TODO: Do not include slash in ${OPERATIONAL_TOPO_API}, having it typed here is more readable.
 177     # TODO: Alternatively, create variable in Variables which starts with http.
 178     # Both TODOs would probably need to update every suite relying on current Variables.
 179     SSHLibrary.Set_Default_Configuration    prompt=${ODL_SYSTEM_PROMPT}
 180     SSHLibrary.Open_Connection    ${ODL_SYSTEM_IP}
 181     SSHKeywords.Flexible_Controller_Login
 182     SSHKeywords.Require_Python
 183     SSHKeywords.Assure_Library_Ipaddr    target_dir=.
 184     SSHLibrary.Put_File    ${CURDIR}/../../../../tools/fastbgp/play.py
 185     # Calculate the timeout value based on how many routes are going to be pushed.
 186     ${period} =    DateTime.Convert_Time    ${CHECK_PERIOD_PREFIX_COUNT_MANY}    result_format=number
 187     ${timeout} =    BuiltIn.Evaluate    ${TEST_DURATION_MULTIPLIER_PREFIX_COUNT_MANY} * (${COUNT_PREFIX_COUNT_MANY} * 3.0 / 10000 + ${period} * (${REPETITIONS_PREFIX_COUNT_MANY} + 1)) + 20
 188     Builtin.Set_Suite_Variable    ${bgp_filling_timeout}    ${timeout}
 189     ${timeout} =    BuiltIn.Evaluate    ${TEST_DURATION_MULTIPLIER_PREFIX_COUNT_MANY} * (${COUNT_PREFIX_COUNT_MANY} * 2.0 / 10000 + ${period} * (${REPETITIONS_PREFIX_COUNT_MANY} + 1)) + 20
 190     Builtin.Set_Suite_Variable    ${bgp_emptying_timeout}    ${timeout}
 191     KarafKeywords.Execute_Controller_Karaf_Command_On_Background    log:set ${KARAF_LOG_LEVEL}
 192
 193 Teardown_Everything
 194     [Documentation]    Make sure Python tool was killed and tear down imported Resources.
 195     # Environment issue may have dropped the SSH connection, but we do not want Teardown to fail.
 196     BuiltIn.Run_Keyword_And_Ignore_Error    KillPythonTool.Search_And_Kill_Remote_Python    'play\.py'
 197     BuiltIn.Run_Keyword_And_Ignore_Error    Utils.Get_Sysstat_Statistics
 198     RequestsLibrary.Delete_All_Sessions
 199     SSHLibrary.Close_All_Connections