csit/suites/bgpcep/bgpingest/singlepeer_changecount.robot

   1 *** Settings ***
   2 Documentation     BGP performance of ingesting from 1 iBGP peer, data change counter is used.
   3 ...
   4 ...               Copyright (c) 2015 Cisco Systems, Inc. and others. All rights reserved.
   5 ...
   6 ...               This program and the accompanying materials are made available under the
   7 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   8 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
   9 ...
  10 ...
  11 ...               This suite uses play.py as single iBGP peer.
  12 ...               The suite only looks at example-ipv4-topology, so RIB is not examined.
  13 ...
  14 ...               This suite requires odl-bgpcep-data-change-counter to be installed so
  15 ...               make sure it is added to "install-features" of any jobs that are going
  16 ...               to invoke it.
  17 ...
  18 ...               The suite consists of two halves, differing on which side initiates BGP connection.
  19 ...               Data change counter is a lightweight way to detect "work is being done".
  20 ...               WaitUtils provide a nice Keyword to wait for stability, but it needs
  21 ...               initial value, that is why Store_Change_Count appears just before work-inducing action.
  22 ...               The time for Wait_For_Stable_* cases to finish is the main performance metric.
  23 ...               After waiting for stability is done, full check on number of prefixes present is performed.
  24 ...
  25 ...               TODO: Currently, if a bug causes zero increase of data changes,
  26 ...               affected test cases will wait for max time. Reconsider.
  27 ...               If zero increase is allowed as stable, higher number of repetitions should be required.
  28 ...
  29 ...               Additionally this test suite is not compatible with Helium and Hydrogen
  30 ...               releases as they don't include data change counter feature.
  31 ...               Use the other version of the suite (singlepeer_prefixcount.robot) to test them.
  32 Suite Setup       Setup_Everything
  33 Suite Teardown    Teardown_Everything
  34 Test Setup        SetupUtils.Setup_Test_With_Logging_And_Fast_Failing
  35 Test Teardown     SetupUtils.Teardown_Test_Show_Bugs_And_Start_Fast_Failing_If_Test_Failed
  36 Library           SSHLibrary    timeout=10s
  37 Library           RequestsLibrary
  38 Variables         ${CURDIR}/../../../variables/Variables.py
  39 Resource          ${CURDIR}/../../../libraries/BGPSpeaker.robot
  40 Resource          ${CURDIR}/../../../libraries/ChangeCounter.robot
  41 Resource          ${CURDIR}/../../../libraries/ConfigViaRestconf.robot
  42 Resource          ${CURDIR}/../../../libraries/FailFast.robot
  43 Resource          ${CURDIR}/../../../libraries/KillPythonTool.robot
  44 Resource          ${CURDIR}/../../../libraries/PrefixCounting.robot
  45 Resource          ${CURDIR}/../../../libraries/SetupUtils.robot
  46
  47 *** Variables ***
  48 ${BGP_TOOL_LOG_LEVEL}    info
  49 ${BGP_VARIABLES_FOLDER}    ${CURDIR}/../../../variables/bgpuser/
  50 ${CHECK_PERIOD}    1
  51 ${CHECK_PERIOD_CHANGE_COUNT}    ${CHECK_PERIOD}
  52 ${CHECK_PERIOD_CHANGE_COUNT_SINGLE}    ${CHECK_PERIOD_CHANGE_COUNT}
  53 ${COUNT}          1000000
  54 ${COUNT_CHANGE_COUNT}    ${COUNT}
  55 ${COUNT_CHANGE_COUNT_SINGLE}    ${COUNT_CHANGE_COUNT}
  56 ${HOLDTIME}       180
  57 ${HOLDTIME_CHANGE_COUNT}    ${HOLDTIME}
  58 ${HOLDTIME_CHANGE_COUNT_SINGLE}    ${HOLDTIME_CHANGE_COUNT}
  59 ${INSERT}         1
  60 ${KARAF_LOG_LEVEL}    INFO
  61 ${KARAF_BGPCEP_LOG_LEVEL}    ${KARAF_LOG_LEVEL}
  62 ${KARAF_PROTOCOL_LOG_LEVEL}    ${KARAF_BGPCEP_LOG_LEVEL}
  63 ${PREFILL}        0
  64 ${REPETITIONS}    1
  65 ${REPETITIONS_CHANGE_COUNT}    ${REPETITIONS}
  66 ${REPETITIONS_CHANGE_COUNT_SINGLE}    ${REPETITIONS_CHANGE_COUNT}
  67 ${RESULTS_FILE_NAME}    bgp.csv
  68 ${TEST_DURATION_MULTIPLIER}    1
  69 ${TEST_DURATION_MULTIPLIER_CHANGE_COUNT}    ${TEST_DURATION_MULTIPLIER}
  70 ${TEST_DURATION_MULTIPLIER_CHANGE_COUNT_SINGLE}    ${TEST_DURATION_MULTIPLIER_CHANGE_COUNT}
  71 ${UPDATE}         single
  72 ${WITHDRAW}       0
  73 # TODO: Option names can be better.
  74 ${last_change_count_single}    -1
  75
  76 *** Test Cases ***
  77 Check_For_Empty_Ipv4_Topology_Before_Talking
  78     [Documentation]    Wait for example-ipv4-topology to come up and empty. Give large timeout for case when BGP boots slower than restconf.
  79     [Tags]    critical
  80     # TODO: Choose which tags to assign and make sure they are assigned correctly.
  81     BuiltIn.Wait_Until_Keyword_Succeeds    120s    1s    PrefixCounting.Check_Ipv4_Topology_Is_Empty
  82
  83 Reconfigure_ODL_To_Accept_Connection
  84     [Documentation]    Configure BGP peer module with initiate-connection set to false.
  85     ${template_as_string} =    BuiltIn.Set_Variable    {'NAME': 'example-bgp-peer', 'IP': '${TOOLS_SYSTEM_IP}', 'HOLDTIME': '${HOLDTIME_CHANGE_COUNT_SINGLE}', 'PEER_PORT': '${BGP_TOOL_PORT}', 'INITIATE': 'false'}
  86     ConfigViaRestconf.Put_Xml_Template_Folder_Config_Via_Restconf    ${BGP_VARIABLES_FOLDER}${/}bgp_peer    ${template_as_string}
  87
  88 Wait_For_Data_Change_Counter_Ready
  89     [Documentation]    Data change counter might have been slower to start than ipv4 topology, wait for it.
  90     BuiltIn.Wait_Until_Keyword_Succeeds    60s    1s    ChangeCounter.Get_Change_Count
  91
  92 Reconfigure_Data_Change_Counter
  93     [Documentation]    Configure data change counter to count transactions in example-ipv4-topology instead of example-linkstate-topology.
  94     ChangeCounter.Reconfigure_Topology_Name    example-ipv4-topology
  95
  96 Change_Karaf_Logging_Levels
  97     [Documentation]    We may want to set more verbose logging here after configuration is done.
  98     KarafKeywords.Set_Bgpcep_Log_Levels    bgpcep_level=${KARAF_BGPCEP_LOG_LEVEL}    protocol_level=${KARAF_PROTOCOL_LOG_LEVEL}
  99
 100 Start_Talking_BGP_Speaker
 101     [Documentation]    Start Python speaker to connect to ODL.
 102     Store_Change_Count
 103     # Myport value is needed for checking whether connection at precise port was established.
 104     BGPSpeaker.Start_BGP_Speaker    --amount ${COUNT_CHANGE_COUNT_SINGLE} --myip=${TOOLS_SYSTEM_IP} --myport=${BGP_TOOL_PORT} --peerip=${ODL_SYSTEM_IP} --peerport=${ODL_BGP_PORT} --insert=${INSERT} --withdraw=${WITHDRAW} --prefill ${PREFILL} --update ${UPDATE} --${BGP_TOOL_LOG_LEVEL} --results ${RESULTS_FILE_NAME}
 105
 106 Wait_For_Stable_Talking_Ipv4_Topology
 107     [Documentation]    Wait until example-ipv4-topology becomes stable. This is done by checking the change counter.
 108     ChangeCounter.Wait_For_Change_Count_To_Become_Stable    timeout=${bgp_filling_timeout}    period=${CHECK_PERIOD_CHANGE_COUNT_SINGLE}    repetitions=${REPETITIONS_CHANGE_COUNT_SINGLE}    count_to_overcome=${last_change_count_single}
 109
 110 Check_Talking_Ipv4_Topology_Count
 111     [Documentation]    Count the routes in example-ipv4-topology and fail if the count is not correct.
 112     [Tags]    critical
 113     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 114     PrefixCounting.Check_Ipv4_Topology_Count    ${COUNT_CHANGE_COUNT_SINGLE}
 115
 116 Kill_Talking_BGP_Speaker
 117     [Documentation]    Abort the Python speaker. Also, attempt to stop failing fast.
 118     [Tags]    critical
 119     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 120     Store_Change_Count
 121     BGPSpeaker.Kill_BGP_Speaker
 122     FailFast.Do_Not_Fail_Fast_From_Now_On
 123     # NOTE: It is still possible to remain failing fast, if both previous and this test have failed.
 124     [Teardown]    SetupUtils.Teardown_Test_Show_Bugs_If_Test_Failed
 125
 126 Store_Results_For_Talking_BGP_Speaker
 127     [Documentation]    Store results for plotting
 128     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 129     Store_File_To_Workspace    totals-${RESULTS_FILE_NAME}    totals-${RESULTS_FILE_NAME}
 130     Store_File_To_Workspace    performance-${RESULTS_FILE_NAME}    performance-${RESULTS_FILE_NAME}
 131     Store_File_To_Workspace    totals-${RESULTS_FILE_NAME}    changecount-talking-totals-${RESULTS_FILE_NAME}
 132     Store_File_To_Workspace    performance-${RESULTS_FILE_NAME}    changecount-talking-performance-${RESULTS_FILE_NAME}
 133
 134 Wait_For_Stable_Ipv4_Topology_After_Talking
 135     [Documentation]    Wait until example-ipv4-topology becomes stable again.
 136     [Tags]    critical
 137     ChangeCounter.Wait_For_Change_Count_To_Become_Stable    timeout=${bgp_emptying_timeout}    period=${CHECK_PERIOD_CHANGE_COUNT_SINGLE}    repetitions=${REPETITIONS_CHANGE_COUNT_SINGLE}    count_to_overcome=${last_change_count_single}
 138
 139 Check_For_Empty_Ipv4_Topology_After_Talking
 140     [Documentation]    Example-ipv4-topology should be empty now.
 141     [Tags]    critical
 142     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 143     PrefixCounting.Check_Ipv4_Topology_Is_Empty
 144
 145 Start_Listening_BGP_Speaker
 146     [Documentation]    Start Python speaker in listening mode.
 147     BGPSpeaker.Start_BGP_Speaker    --amount ${COUNT_CHANGE_COUNT_SINGLE} --listen --myip=${TOOLS_SYSTEM_IP} --myport=${BGP_TOOL_PORT} --peerip=${ODL_SYSTEM_IP} --insert=${INSERT} --withdraw=${WITHDRAW} --prefill ${PREFILL} --update ${UPDATE} --${BGP_TOOL_LOG_LEVEL} --results ${RESULTS_FILE_NAME}
 148
 149 Reconfigure_ODL_To_Initiate_Connection
 150     [Documentation]    Replace BGP peer config module, now with initiate-connection set to true.
 151     Store_Change_Count
 152     ${template_as_string} =    BuiltIn.Set_Variable    {'NAME': 'example-bgp-peer', 'IP': '${TOOLS_SYSTEM_IP}', 'HOLDTIME': '${HOLDTIME_CHANGE_COUNT_SINGLE}', 'PEER_PORT': '${BGP_TOOL_PORT}', 'INITIATE': 'true'}
 153     ConfigViaRestconf.Put_Xml_Template_Folder_Config_Via_Restconf    ${BGP_VARIABLES_FOLDER}${/}bgp_peer    ${template_as_string}
 154
 155 Wait_For_Stable_Listening_Ipv4_Topology
 156     [Documentation]    Wait until example-ipv4-topology becomes stable.
 157     ChangeCounter.Wait_For_Change_Count_To_Become_Stable    timeout=${bgp_filling_timeout}    period=${CHECK_PERIOD_CHANGE_COUNT_SINGLE}    repetitions=${REPETITIONS_CHANGE_COUNT_SINGLE}    count_to_overcome=${last_change_count_single}
 158
 159 Check_Listening_Ipv4_Topology_Count
 160     [Documentation]    Count the routes in example-ipv4-topology and fail if the count is not correct.
 161     [Tags]    critical
 162     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 163     PrefixCounting.Check_Ipv4_Topology_Count    ${COUNT_CHANGE_COUNT_SINGLE}
 164
 165 Kill_Listening_BGP_Speaker
 166     [Documentation]    Abort the Python speaker. Also, attempt to stop failing fast.
 167     [Tags]    critical
 168     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 169     Store_Change_Count
 170     BGPSpeaker.Kill_BGP_Speaker
 171     FailFast.Do_Not_Fail_Fast_From_Now_On
 172     # NOTE: It is still possible to remain failing fast, if both previous and this test have failed.
 173     [Teardown]    SetupUtils.Teardown_Test_Show_Bugs_If_Test_Failed
 174
 175 Store_Results_For_Listening_BGP_Speaker
 176     [Documentation]    Store results for plotting
 177     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 178     Store_File_To_Workspace    totals-${RESULTS_FILE_NAME}    totals-${RESULTS_FILE_NAME}
 179     Store_File_To_Workspace    performance-${RESULTS_FILE_NAME}    performance-${RESULTS_FILE_NAME}
 180     Store_File_To_Workspace    totals-${RESULTS_FILE_NAME}    changecount-listening-totals-${RESULTS_FILE_NAME}
 181     Store_File_To_Workspace    performance-${RESULTS_FILE_NAME}    changecount-listening-performance-${RESULTS_FILE_NAME}
 182
 183 Wait_For_Stable_Ipv4_Topology_After_Listening
 184     [Documentation]    Wait until example-ipv4-topology becomes stable again.
 185     [Tags]    critical
 186     ChangeCounter.Wait_For_Change_Count_To_Become_Stable    timeout=${bgp_emptying_timeout}    period=${CHECK_PERIOD_CHANGE_COUNT_SINGLE}    repetitions=${REPETITIONS_CHANGE_COUNT_SINGLE}    count_to_overcome=${last_change_count_single}
 187
 188 Check_For_Empty_Ipv4_Topology_After_Listening
 189     [Documentation]    Example-ipv4-topology should be empty now.
 190     [Tags]    critical
 191     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 192     PrefixCounting.Check_Ipv4_Topology_Is_Empty
 193
 194 Restore_Karaf_Logging_Levels
 195     [Documentation]    Set logging on bgpcep and protocol to the global value.
 196     KarafKeywords.Set_Bgpcep_Log_Levels    bgpcep_level=${KARAF_LOG_LEVEL}    protocol_level=${KARAF_LOG_LEVEL}
 197
 198 Restore_Data_Change_Counter_Configuration
 199     [Documentation]    Configure data change counter back to count transactions affecting example-linkstate-topology.
 200     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 201     ChangeCounter.Reconfigure_Topology_Name    example-linkstate-topology
 202
 203 Delete_Bgp_Peer_Configuration
 204     [Documentation]    Revert the BGP configuration to the original state: without any configured peers.
 205     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 206     ${template_as_string} =    BuiltIn.Set_Variable    {'NAME': 'example-bgp-peer'}
 207     ConfigViaRestconf.Delete_Xml_Template_Folder_Config_Via_Restconf    ${BGP_VARIABLES_FOLDER}${/}bgp_peer    ${template_as_string}
 208
 209 *** Keywords ***
 210 Setup_Everything
 211     [Documentation]    Setup imported resources, SSH-login to tools system,
 212     ...    create HTTP session, put Python tool to tools system.
 213     SetupUtils.Setup_Utils_For_Setup_And_Teardown
 214     ConfigViaRestconf.Setup_Config_Via_Restconf
 215     ChangeCounter.CC_Setup
 216     PrefixCounting.PC_Setup
 217     SSHLibrary.Set_Default_Configuration    prompt=${TOOLS_SYSTEM_PROMPT}
 218     SSHLibrary.Open_Connection    ${TOOLS_SYSTEM_IP}
 219     Utils.Flexible_Mininet_Login
 220     RequestsLibrary.Create_Session    operational    http://${ODL_SYSTEM_IP}:${RESTCONFPORT}${OPERATIONAL_API}    auth=${AUTH}
 221     # TODO: Do not include slash in ${OPERATIONAL_TOPO_API}, having it typed here is more readable.
 222     # TODO: Alternatively, create variable in Variables which starts with http.
 223     # Both TODOs would probably need to update every suite relying on current Variables.
 224     SSHLibrary.Put_File    ${CURDIR}/../../../../tools/fastbgp/play.py
 225     # Calculate the timeout value based on how many routes are going to be pushed
 226     # TODO: Unify formulas with other suites in this directory.
 227     ${timeout} =    BuiltIn.Evaluate    ${TEST_DURATION_MULTIPLIER_CHANGE_COUNT_SINGLE} * (${COUNT_CHANGE_COUNT_SINGLE} * 3.0 / 10000 + 20)
 228     Builtin.Set_Suite_Variable    ${bgp_filling_timeout}    ${timeout}
 229     Builtin.Set_Suite_Variable    ${bgp_emptying_timeout}    ${bgp_filling_timeout*3.0/4}
 230     KarafKeywords.Execute_Controller_Karaf_Command_On_Background    log:set ${KARAF_LOG_LEVEL}
 231
 232 Teardown_Everything
 233     [Documentation]    Make sure Python tool was killed and tear down imported Resources.
 234     # Environment issue may have dropped the SSH connection, but we do not want Teardown to fail.
 235     BuiltIn.Run_Keyword_And_Ignore_Error    KillPythonTool.Search_And_Kill_Remote_Python    'play\.py'
 236     ConfigViaRestconf.Teardown_Config_Via_Restconf
 237     RequestsLibrary.Delete_All_Sessions
 238     SSHLibrary.Close_All_Connections
 239
 240 Store_Change_Count
 241     [Documentation]    Get the count of changes from BGP change counter. Ignore error or store the value.
 242     ${status}    ${count} =    BuiltIn.Run_Keyword_And_Ignore_Error    ChangeCounter.Get_Change_Count
 243     BuiltIn.Run_Keyword_If    '${status}' == 'PASS'    BuiltIn.Set_Suite_Variable    ${last_change_count_single}    ${count}
 244
 245 Store_File_To_Workspace
 246     [Arguments]    ${src_file_name}    ${dst_file_name}
 247     [Documentation]    Store the provided file from the SSH client to workspace.
 248     ${files}=    SSHLibrary.List Files In Directory    .
 249     ${output_log}=    SSHLibrary.Execute_Command    cat ${src_file_name}
 250     BuiltIn.Log    ${output_log}
 251     Create File    ${dst_file_name}    ${output_log}