csit/suites/bgpcep/bgpingest/singlepeer_changecount.robot

   1 *** Settings ***
   2 Documentation     BGP performance of ingesting from 1 iBGP peer, data change counter is used.
   3 ...
   4 ...               Copyright (c) 2015 Cisco Systems, Inc. and others. All rights reserved.
   5 ...
   6 ...               This program and the accompanying materials are made available under the
   7 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   8 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
   9 ...
  10 ...
  11 ...               This suite uses play.py as single iBGP peer.
  12 ...               The suite only looks at example-ipv4-topology, so RIB is not examined.
  13 ...
  14 ...               This suite requires odl-bgpcep-data-change-counter to be installed so
  15 ...               make sure it is added to "install-features" of any jobs that are going
  16 ...               to invoke it.
  17 ...
  18 ...               The suite consists of two halves, differing on which side initiates BGP connection.
  19 ...               Data change counter is a lightweight way to detect "work is being done".
  20 ...               WaitUtils provide a nice Keyword to wait for stability, but it needs
  21 ...               initial value, that is why Store_Change_Count appears just before work-inducing action.
  22 ...               The time for Wait_For_Stable_* cases to finish is the main performance metric.
  23 ...               After waiting for stability is done, full check on number of prefixes present is performed.
  24 ...
  25 ...               TODO: Currently, if a bug causes zero increase of data changes,
  26 ...               affected test cases will wait for max time. Reconsider.
  27 ...               If zero increase is allowed as stable, higher number of repetitions should be required.
  28 ...
  29 ...               Additionally this test suite is not compatible with Helium and Hydrogen
  30 ...               releases as they don't include data change counter feature.
  31 ...               Use the other version of the suite (singlepeer_prefixcount.robot) to test them.
  32 Suite Setup       Setup_Everything
  33 Suite Teardown    Teardown_Everything
  34 Test Setup        SetupUtils.Setup_Test_With_Logging_And_Fast_Failing
  35 Test Teardown     FailFast.Start_Failing_Fast_If_This_Failed
  36 Library           SSHLibrary    timeout=10s
  37 Library           RequestsLibrary
  38 Variables         ${CURDIR}/../../../variables/Variables.py
  39 Resource          ${CURDIR}/../../../libraries/BGPSpeaker.robot
  40 Resource          ${CURDIR}/../../../libraries/ChangeCounter.robot
  41 Resource          ${CURDIR}/../../../libraries/ConfigViaRestconf.robot
  42 Resource          ${CURDIR}/../../../libraries/FailFast.robot
  43 Resource          ${CURDIR}/../../../libraries/KillPythonTool.robot
  44 Resource          ${CURDIR}/../../../libraries/PrefixCounting.robot
  45 Resource          ${CURDIR}/../../../libraries/SetupUtils.robot
  46
  47 *** Variables ***
  48 ${BGP_VARIABLES_FOLDER}    ${CURDIR}/../../../variables/bgpuser/
  49 ${HOLDTIME}       180
  50 ${HOLDTIME_CHANGE_COUNT}    ${HOLDTIME}
  51 ${COUNT}          1000000
  52 ${COUNT_CHANGE_COUNT}    ${COUNT}
  53 ${CHECK_PERIOD}    1
  54 ${CHECK_PERIOD_CHANGE_COUNT}    ${CHECK_PERIOD}
  55 ${REPETITIONS_CHANGE_COUNT}    1
  56 ${INSERT}    1
  57 ${WITHDRAW}    0
  58 ${PREFILL}    0
  59 ${UPDATE}    single
  60 ${BGP_TOOL_LOG_LEVEL}    info
  61 ${CONTROLLER_LOG_LEVEL}    INFO
  62 ${CONTROLLER_BGP_LOG_LEVEL}    DEFAULT
  63 ${RESULTS_FILE_NAME}    bgp.csv
  64
  65 # TODO: Option names can be better.
  66 ${last_change_count}    -1
  67
  68 *** Test Cases ***
  69 Check_For_Empty_Ipv4_Topology_Before_Talking
  70     [Documentation]    Wait for example-ipv4-topology to come up and empty. Give large timeout for case when BGP boots slower than restconf.
  71     [Tags]    critical
  72     # TODO: Choose which tags to assign and make sure they are assigned correctly.
  73     BuiltIn.Wait_Until_Keyword_Succeeds    120s    1s    PrefixCounting.Check_Ipv4_Topology_Is_Empty
  74
  75 Reconfigure_ODL_To_Accept_Connection
  76     [Documentation]    Configure BGP peer module with initiate-connection set to false.
  77     ${template_as_string} =    BuiltIn.Set_Variable    {'NAME': 'example-bgp-peer', 'IP': '${TOOLS_SYSTEM_IP}', 'HOLDTIME': '${HOLDTIME_CHANGE_COUNT}', 'PEER_PORT': '${BGP_TOOL_PORT}', 'INITIATE': 'false'}
  78     ConfigViaRestconf.Put_Xml_Template_Folder_Config_Via_Restconf    ${BGP_VARIABLES_FOLDER}${/}bgp_peer    ${template_as_string}
  79
  80 Wait_For_Data_Change_Counter_Ready
  81     [Documentation]    Data change counter might have been slower to start than ipv4 topology, wait for it.
  82     BuiltIn.Wait_Until_Keyword_Succeeds    60s    1s    ChangeCounter.Get_Change_Count
  83
  84 Reconfigure_Data_Change_Counter
  85     [Documentation]    Configure data change counter to count transactions in example-ipv4-topology instead of example-linkstate-topology.
  86     ChangeCounter.Reconfigure_Topology_Name    example-ipv4-topology
  87
  88 Start_Talking_BGP_Speaker
  89     [Documentation]    Start Python speaker to connect to ODL.
  90     Store_Change_Count
  91     # Myport value is needed for checking whether connection at precise port was established.
  92     BGPSpeaker.Start_BGP_Speaker    --amount ${COUNT_CHANGE_COUNT} --myip=${TOOLS_SYSTEM_IP} --myport=${BGP_TOOL_PORT} --peerip=${ODL_SYSTEM_IP} --peerport=${ODL_BGP_PORT} --insert=${INSERT} --withdraw=${WITHDRAW} --prefill ${PREFILL} --update ${UPDATE} --${BGP_TOOL_LOG_LEVEL} --results ${RESULTS_FILE_NAME}
  93
  94 Wait_For_Stable_Talking_Ipv4_Topology
  95     [Documentation]    Wait until example-ipv4-topology becomes stable. This is done by checking the change counter.
  96     ChangeCounter.Wait_For_Change_Count_To_Become_Stable    timeout=${bgp_filling_timeout}    period=${CHECK_PERIOD_CHANGE_COUNT}    repetitions=${REPETITIONS_CHANGE_COUNT}    count_to_overcome=${last_change_count}
  97
  98 Check_Talking_Ipv4_Topology_Count
  99     [Documentation]    Count the routes in example-ipv4-topology and fail if the count is not correct.
 100     [Tags]    critical
 101     PrefixCounting.Check_Ipv4_Topology_Count    ${COUNT_CHANGE_COUNT}
 102
 103 Kill_Talking_BGP_Speaker
 104     [Documentation]    Abort the Python speaker. Also, attempt to stop failing fast.
 105     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 106     Store_Change_Count
 107     BGPSpeaker.Kill_BGP_Speaker
 108     FailFast.Do_Not_Fail_Fast_From_Now_On
 109     # NOTE: It is still possible to remain failing fast, if both previous and this test have failed.
 110     [Teardown]    FailFast.Do_Not_Start_Failing_If_This_Failed
 111
 112 Store_Results_For_Talking_BGP_Speaker
 113     [Documentation]    Store results for plotting
 114     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 115     Store_File_To_Workspace    totals-${RESULTS_FILE_NAME}    totals-${RESULTS_FILE_NAME}
 116     Store_File_To_Workspace    performance-${RESULTS_FILE_NAME}    performance-${RESULTS_FILE_NAME}
 117     Store_File_To_Workspace    totals-${RESULTS_FILE_NAME}    changecount-talking-totals-${RESULTS_FILE_NAME}
 118     Store_File_To_Workspace    performance-${RESULTS_FILE_NAME}    changecount-talking-performance-${RESULTS_FILE_NAME}
 119
 120 Wait_For_Stable_Ipv4_Topology_After_Talking
 121     [Documentation]    Wait until example-ipv4-topology becomes stable again.
 122     [Tags]    critical
 123     ChangeCounter.Wait_For_Change_Count_To_Become_Stable    timeout=${bgp_emptying_timeout}    period=${CHECK_PERIOD_CHANGE_COUNT}    repetitions=${REPETITIONS_CHANGE_COUNT}    count_to_overcome=${last_change_count}
 124
 125 Check_For_Empty_Ipv4_Topology_After_Talking
 126     [Documentation]    Example-ipv4-topology should be empty now.
 127     [Tags]    critical
 128     PrefixCounting.Check_Ipv4_Topology_Is_Empty
 129
 130 Start_Listening_BGP_Speaker
 131     [Documentation]    Start Python speaker in listening mode.
 132     BGPSpeaker.Start_BGP_Speaker    --amount ${COUNT_CHANGE_COUNT} --listen --myip=${TOOLS_SYSTEM_IP} --myport=${BGP_TOOL_PORT} --peerip=${ODL_SYSTEM_IP} --insert=${INSERT} --withdraw=${WITHDRAW} --prefill ${PREFILL} --update ${UPDATE} --${BGP_TOOL_LOG_LEVEL} --results ${RESULTS_FILE_NAME}
 133
 134 Reconfigure_ODL_To_Initiate_Connection
 135     [Documentation]    Replace BGP peer config module, now with initiate-connection set to true.
 136     Store_Change_Count
 137     ${template_as_string} =    BuiltIn.Set_Variable    {'NAME': 'example-bgp-peer', 'IP': '${TOOLS_SYSTEM_IP}', 'HOLDTIME': '${HOLDTIME_CHANGE_COUNT}', 'PEER_PORT': '${BGP_TOOL_PORT}', 'INITIATE': 'true'}
 138     ConfigViaRestconf.Put_Xml_Template_Folder_Config_Via_Restconf    ${BGP_VARIABLES_FOLDER}${/}bgp_peer    ${template_as_string}
 139
 140 Wait_For_Stable_Listening_Ipv4_Topology
 141     [Documentation]    Wait until example-ipv4-topology becomes stable.
 142     ChangeCounter.Wait_For_Change_Count_To_Become_Stable    timeout=${bgp_filling_timeout}    period=${CHECK_PERIOD_CHANGE_COUNT}    repetitions=${REPETITIONS_CHANGE_COUNT}    count_to_overcome=${last_change_count}
 143
 144 Check_Listening_Ipv4_Topology_Count
 145     [Documentation]    Count the routes in example-ipv4-topology and fail if the count is not correct.
 146     [Tags]    critical
 147     PrefixCounting.Check_Ipv4_Topology_Count    ${COUNT_CHANGE_COUNT}
 148
 149 Kill_Listening_BGP_Speaker
 150     [Documentation]    Abort the Python speaker. Also, attempt to stop failing fast.
 151     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 152     Store_Change_Count
 153     BGPSpeaker.Kill_BGP_Speaker
 154     FailFast.Do_Not_Fail_Fast_From_Now_On
 155     # NOTE: It is still possible to remain failing fast, if both previous and this test have failed.
 156     [Teardown]    FailFast.Do_Not_Start_Failing_If_This_Failed
 157
 158 Store_Results_For_Listening_BGP_Speaker
 159     [Documentation]    Store results for plotting
 160     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 161     Store_File_To_Workspace    totals-${RESULTS_FILE_NAME}    totals-${RESULTS_FILE_NAME}
 162     Store_File_To_Workspace    performance-${RESULTS_FILE_NAME}    performance-${RESULTS_FILE_NAME}
 163     Store_File_To_Workspace    totals-${RESULTS_FILE_NAME}    changecount-listening-totals-${RESULTS_FILE_NAME}
 164     Store_File_To_Workspace    performance-${RESULTS_FILE_NAME}    changecount-listening-performance-${RESULTS_FILE_NAME}
 165
 166 Wait_For_Stable_Ipv4_Topology_After_Listening
 167     [Documentation]    Wait until example-ipv4-topology becomes stable again.
 168     [Tags]    critical
 169     ChangeCounter.Wait_For_Change_Count_To_Become_Stable    timeout=${bgp_emptying_timeout}    period=${CHECK_PERIOD_CHANGE_COUNT}    repetitions=${REPETITIONS_CHANGE_COUNT}    count_to_overcome=${last_change_count}
 170
 171 Check_For_Empty_Ipv4_Topology_After_Listening
 172     [Documentation]    Example-ipv4-topology should be empty now.
 173     [Tags]    critical
 174     PrefixCounting.Check_Ipv4_Topology_Is_Empty
 175
 176 Restore_Data_Change_Counter_Configuration
 177     [Documentation]    Configure data change counter back to count transactions affecting example-linkstate-topology.
 178     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 179     ChangeCounter.Reconfigure_Topology_Name    example-linkstate-topology
 180
 181 Delete_Bgp_Peer_Configuration
 182     [Documentation]    Revert the BGP configuration to the original state: without any configured peers.
 183     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 184     ${template_as_string} =    BuiltIn.Set_Variable    {'NAME': 'example-bgp-peer'}
 185     ConfigViaRestconf.Delete_Xml_Template_Folder_Config_Via_Restconf    ${BGP_VARIABLES_FOLDER}${/}bgp_peer    ${template_as_string}
 186
 187 *** Keywords ***
 188 Setup_Everything
 189     [Documentation]    Setup imported resources, SSH-login to tools system,
 190     ...    create HTTP session, put Python tool to tools system.
 191     SetupUtils.Setup_Utils_For_Setup_And_Teardown
 192     ConfigViaRestconf.Setup_Config_Via_Restconf
 193     ChangeCounter.CC_Setup
 194     PrefixCounting.PC_Setup
 195     SSHLibrary.Set_Default_Configuration    prompt=${TOOLS_SYSTEM_PROMPT}
 196     SSHLibrary.Open_Connection    ${TOOLS_SYSTEM_IP}
 197     Utils.Flexible_Mininet_Login
 198     RequestsLibrary.Create_Session    operational    http://${ODL_SYSTEM_IP}:${RESTCONFPORT}${OPERATIONAL_API}    auth=${AUTH}
 199     # TODO: Do not include slash in ${OPERATIONAL_TOPO_API}, having it typed here is more readable.
 200     # TODO: Alternatively, create variable in Variables which starts with http.
 201     # Both TODOs would probably need to update every suite relying on current Variables.
 202     SSHLibrary.Put_File    ${CURDIR}/../../../../tools/fastbgp/play.py
 203     # Calculate the timeout value based on how many routes are going to be pushed
 204     ${count} =    Builtin.Convert_To_Integer    ${COUNT_CHANGE_COUNT}
 205     # TODO: Replace 20 with some formula from period and repetitions.
 206     Builtin.Set_Suite_Variable    ${bgp_filling_timeout}    ${count*3/10000+20}
 207     Builtin.Set_Suite_Variable    ${bgp_emptying_timeout}    ${bgp_filling_timeout*3/4}
 208     # Timeout in case of doubled number of updates per iteration (per prefix count increase in the simplest mixed scenario)
 209     Builtin.Run_Keyword_If    '${UPDATE}' == 'mixed'    Builtin.Set_Suite_Variable    ${bgp_filling_timeout}    ${count*6/10000+20}
 210     KarafKeywords.Execute_Controller_Karaf_Command_On_Background    log:set ${CONTROLLER_LOG_LEVEL}
 211     KarafKeywords.Execute_Controller_Karaf_Command_On_Background    log:set ${CONTROLLER_BGP_LOG_LEVEL} org.opendaylight.bgpcep
 212     KarafKeywords.Execute_Controller_Karaf_Command_On_Background    log:set ${CONTROLLER_BGP_LOG_LEVEL} org.opendaylight.protocol
 213
 214
 215 Teardown_Everything
 216     [Documentation]    Make sure Python tool was killed and tear down imported Resources.
 217     KillPythonTool.Search_And_Kill_Remote_Python    'play\.py'
 218     ConfigViaRestconf.Teardown_Config_Via_Restconf
 219     RequestsLibrary.Delete_All_Sessions
 220     SSHLibrary.Close_All_Connections
 221
 222 Store_Change_Count
 223     [Documentation]    Get the count of changes from BGP change counter. Ignore error or store the value.
 224     ${status}    ${count} =    BuiltIn.Run_Keyword_And_Ignore_Error    ChangeCounter.Get_Change_Count
 225     BuiltIn.Run_Keyword_If    '${status}' == 'PASS'    BuiltIn.Set_Suite_Variable    ${last_change_count}    ${count}
 226
 227 Store_File_To_Workspace
 228     [Arguments]    ${src_file_name}    ${dst_file_name}
 229     [Documentation]    Store the provided file from the SSH client to workspace.
 230     ${files}=    SSHLibrary.List Files In Directory    .
 231     ${output_log}=    SSHLibrary.Execute_Command    cat ${src_file_name}
 232     BuiltIn.Log    ${output_log}
 233     Create File    ${dst_file_name}    ${output_log}