csit/suites/bgpcep/bgpingest/singlepeer_prefixcount.robot

   1 *** Settings ***
   2 Documentation     BGP performance of ingesting from 1 iBGP peer, data change counter is NOT used.
   3 ...
   4 ...               Copyright (c) 2015 Cisco Systems, Inc. and others. All rights reserved.
   5 ...
   6 ...               This program and the accompanying materials are made available under the
   7 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   8 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
   9 ...
  10 ...
  11 ...               This suite uses play.py as single iBGP peer.
  12 ...               The suite only looks at example-ipv4-topology, so RIB is not examined.
  13 ...
  14 ...               The suite consists of two halves, differing on which side initiates BGP connection.
  15 ...               State of "work is being done" is detected by increasing value of prefixes in topology.
  16 ...               The time for Wait_For_Stable_* cases to finish is the main performance metric.
  17 ...               After waiting for stability is done, full check on number of prefixes present is performed.
  18 ...
  19 ...               TODO: Currently, if a bug causes prefix count to remain at zero,
  20 ...               affected test cases will wait for max time. Reconsider.
  21 ...               If zero is allowed as stable, higher period or repetitions would be required.
  22 ...
  23 ...               The prefix counting is quite heavyweight and may induce large variation in time.
  24 ...               Try the other version of the suite (singlepeer_changecount.robot) to get better precision.
  25 Suite Setup       Setup_Everything
  26 Suite Teardown    Teardown_Everything
  27 Test Setup        SetupUtils.Setup_Test_With_Logging_And_Fast_Failing
  28 Test Teardown     SetupUtils.Teardown_Test_Show_Bugs_And_Start_Fast_Failing_If_Test_Failed
  29 Library           SSHLibrary    timeout=10s
  30 Library           RequestsLibrary
  31 Variables         ${CURDIR}/../../../variables/Variables.py
  32 Resource          ${CURDIR}/../../../libraries/BGPSpeaker.robot
  33 Resource          ${CURDIR}/../../../libraries/ConfigViaRestconf.robot
  34 Resource          ${CURDIR}/../../../libraries/FailFast.robot
  35 Resource          ${CURDIR}/../../../libraries/KillPythonTool.robot
  36 Resource          ${CURDIR}/../../../libraries/PrefixCounting.robot
  37 Resource          ${CURDIR}/../../../libraries/SetupUtils.robot
  38
  39 *** Variables ***
  40 ${BGP_TOOL_LOG_LEVEL}    info
  41 ${BGP_VARIABLES_FOLDER}    ${CURDIR}/../../../variables/bgpuser/
  42 ${CHECK_PERIOD}    1
  43 ${CHECK_PERIOD_PREFIX_COUNT}    ${CHECK_PERIOD}
  44 ${CHECK_PERIOD_PREFIX_COUNT_SINGLE}    ${CHECK_PERIOD_PREFIX_COUNT}
  45 ${COUNT}          1000000
  46 ${COUNT_PREFIX_COUNT}    ${COUNT}
  47 ${COUNT_PREFIX_COUNT_SINGLE}    ${COUNT_PREFIX_COUNT}
  48 ${HOLDTIME}       180
  49 ${HOLDTIME_PREFIX_COUNT}    ${HOLDTIME}
  50 ${HOLDTIME_PREFIX_COUNT_SINGLE}    ${HOLDTIME_PREFIX_COUNT}
  51 ${INSERT}         1
  52 ${KARAF_LOG_LEVEL}    INFO
  53 ${KARAF_BGPCEP_LOG_LEVEL}    ${KARAF_LOG_LEVEL}
  54 ${KARAF_PROTOCOL_LOG_LEVEL}    ${KARAF_BGPCEP_LOG_LEVEL}
  55 ${PREFILL}        0
  56 ${REPETITIONS}    1
  57 ${REPETITIONS_PREFIX_COUNT}    ${REPETITIONS}
  58 ${REPETITIONS_PREFIX_COUNT_SINGLE}    ${REPETITIONS_PREFIX_COUNT}
  59 ${RESULTS_FILE_NAME}    bgp.csv
  60 ${TEST_DURATION_MULTIPLIER}    1
  61 ${TEST_DURATION_MULTIPLIER_PREFIX_COUNT}    ${TEST_DURATION_MULTIPLIER}
  62 ${TEST_DURATION_MULTIPLIER_PREFIX_COUNT_SINGLE}    ${TEST_DURATION_MULTIPLIER_PREFIX_COUNT}
  63 ${UPDATE}         single
  64 ${WITHDRAW}       0
  65 # TODO: Option names can be better.
  66
  67 *** Test Cases ***
  68 Check_For_Empty_Ipv4_Topology_Before_Talking
  69     [Documentation]    Wait for example-ipv4-topology to come up and empty. Give large timeout for case when BGP boots slower than restconf.
  70     [Tags]    critical
  71     # TODO: Choose which tags to assign and make sure they are assigned correctly.
  72     BuiltIn.Wait_Until_Keyword_Succeeds    120s    1s    PrefixCounting.Check_Ipv4_Topology_Is_Empty
  73
  74 Reconfigure_ODL_To_Accept_Connection
  75     [Documentation]    Configure BGP peer module with initiate-connection set to false.
  76     ${template_as_string} =    BuiltIn.Set_Variable    {'NAME': 'example-bgp-peer', 'IP': '${TOOLS_SYSTEM_IP}', 'HOLDTIME': '${HOLDTIME_PREFIX_COUNT_SINGLE}', 'PEER_PORT': '${BGP_TOOL_PORT}', 'INITIATE': 'false'}
  77     ConfigViaRestconf.Put_Xml_Template_Folder_Config_Via_Restconf    ${BGP_VARIABLES_FOLDER}${/}bgp_peer    ${template_as_string}
  78
  79 Change_Karaf_Logging_Levels
  80     [Documentation]    We may want to set more verbose logging here after configuration is done.
  81     KarafKeywords.Set_Bgpcep_Log_Levels    bgpcep_level=${KARAF_BGPCEP_LOG_LEVEL}    protocol_level=${KARAF_PROTOCOL_LOG_LEVEL}
  82
  83 Start_Talking_BGP_Speaker
  84     [Documentation]    Start Python speaker to connect to ODL.
  85     # Myport value is needed for checking whether connection at precise port was established.
  86     BGPSpeaker.Start_BGP_Speaker    --amount ${COUNT_PREFIX_COUNT_SINGLE} --myip=${TOOLS_SYSTEM_IP} --myport=${BGP_TOOL_PORT} --peerip=${ODL_SYSTEM_IP} --peerport=${ODL_BGP_PORT} --insert=${INSERT} --withdraw=${WITHDRAW} --prefill ${PREFILL} --update ${UPDATE} --${BGP_TOOL_LOG_LEVEL} --results ${RESULTS_FILE_NAME}
  87
  88 Wait_For_Stable_Talking_Ipv4_Topology
  89     [Documentation]    Wait until example-ipv4-topology becomes stable. This is done by checking stability of prefix count.
  90     PrefixCounting.Wait_For_Ipv4_Topology_Prefixes_To_Become_Stable    timeout=${bgp_filling_timeout}    period=${CHECK_PERIOD_PREFIX_COUNT_SINGLE}    repetitions=${REPETITIONS_PREFIX_COUNT_SINGLE}    excluded_count=0
  91
  92 Check_Talking_Ipv4_Topology_Count
  93     [Documentation]    Count the routes in example-ipv4-topology and fail if the count is not correct.
  94     [Tags]    critical
  95     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
  96     PrefixCounting.Check_Ipv4_Topology_Count    ${COUNT_PREFIX_COUNT_SINGLE}
  97
  98 Kill_Talking_BGP_Speaker
  99     [Documentation]    Abort the Python speaker. Also, attempt to stop failing fast.
 100     [Tags]    critical
 101     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 102     BGPSpeaker.Kill_BGP_Speaker
 103     FailFast.Do_Not_Fail_Fast_From_Now_On
 104     # NOTE: It is still possible to remain failing fast, if both previous and this test have failed.
 105     [Teardown]    SetupUtils.Teardown_Test_Show_Bugs_If_Test_Failed
 106
 107 Store_Results_For_Talking_BGP_Speaker
 108     [Documentation]    Store results for plotting
 109     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 110     Store_File_To_Workspace    totals-${RESULTS_FILE_NAME}    totals-${RESULTS_FILE_NAME}
 111     Store_File_To_Workspace    performance-${RESULTS_FILE_NAME}    performance-${RESULTS_FILE_NAME}
 112     Store_File_To_Workspace    totals-${RESULTS_FILE_NAME}    prefixcount-talking-totals-${RESULTS_FILE_NAME}
 113     Store_File_To_Workspace    performance-${RESULTS_FILE_NAME}    prefixcount-talking-performance-${RESULTS_FILE_NAME}
 114
 115 Wait_For_Stable_Ipv4_Topology_After_Talking
 116     [Documentation]    Wait until example-ipv4-topology becomes stable again.
 117     [Tags]    critical
 118     # TODO: Is is possible to have failed at Check_Talking_Ipv4_Topology_Count and still have initial period of constant count?
 119     # FIXME: If yes, do count here to get the initial value and use it (if nonzero).
 120     # TODO: If yes, decide whether access to the FailFast state should have keyword or just variable name.
 121     PrefixCounting.Wait_For_Ipv4_Topology_Prefixes_To_Become_Stable    timeout=${bgp_filling_timeout}    period=${CHECK_PERIOD_PREFIX_COUNT_SINGLE}    repetitions=${REPETITIONS_PREFIX_COUNT_SINGLE}    excluded_count=${COUNT_PREFIX_COUNT_SINGLE}
 122
 123 Check_For_Empty_Ipv4_Topology_After_Talking
 124     [Documentation]    Example-ipv4-topology should be empty now.
 125     [Tags]    critical
 126     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 127     PrefixCounting.Check_Ipv4_Topology_Is_Empty
 128
 129 Start_Listening_BGP_Speaker
 130     [Documentation]    Start Python speaker in listening mode.
 131     BGPSpeaker.Start_BGP_Speaker    --amount ${COUNT_PREFIX_COUNT_SINGLE} --listen --myip=${TOOLS_SYSTEM_IP} --myport=${BGP_TOOL_PORT} --peerip=${ODL_SYSTEM_IP} --insert=${INSERT} --withdraw=${WITHDRAW} --prefill ${PREFILL} --update ${UPDATE} --${BGP_TOOL_LOG_LEVEL} --results ${RESULTS_FILE_NAME}
 132
 133 Reconfigure_ODL_To_Initiate_Connection
 134     [Documentation]    Replace BGP peer config module, now with initiate-connection set to true.
 135     ${template_as_string} =    BuiltIn.Set_Variable    {'NAME': 'example-bgp-peer', 'IP': '${TOOLS_SYSTEM_IP}', 'HOLDTIME': '${HOLDTIME_PREFIX_COUNT_SINGLE}', 'PEER_PORT': '${BGP_TOOL_PORT}', 'INITIATE': 'true'}
 136     ConfigViaRestconf.Put_Xml_Template_Folder_Config_Via_Restconf    ${BGP_VARIABLES_FOLDER}${/}bgp_peer    ${template_as_string}
 137
 138 Wait_For_Stable_Listening_Ipv4_Topology
 139     [Documentation]    Wait until example-ipv4-topology becomes stable.
 140     PrefixCounting.Wait_For_Ipv4_Topology_Prefixes_To_Become_Stable    timeout=${bgp_filling_timeout}    period=${CHECK_PERIOD_PREFIX_COUNT_SINGLE}    repetitions=${REPETITIONS_PREFIX_COUNT_SINGLE}    excluded_count=0
 141
 142 Check_Listening_Ipv4_Topology_Count
 143     [Documentation]    Count the routes in example-ipv4-topology and fail if the count is not correct.
 144     [Tags]    critical
 145     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 146     PrefixCounting.Check_Ipv4_Topology_Count    ${COUNT_PREFIX_COUNT_SINGLE}
 147
 148 Kill_Listening_BGP_Speaker
 149     [Documentation]    Abort the Python speaker. Also, attempt to stop failing fast.
 150     [Tags]    critical
 151     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 152     BGPSpeaker.Kill_BGP_Speaker
 153     FailFast.Do_Not_Fail_Fast_From_Now_On
 154     # NOTE: It is still possible to remain failing fast, if both previous and this test have failed.
 155     [Teardown]    SetupUtils.Teardown_Test_Show_Bugs_If_Test_Failed
 156
 157 Store_Results_For_Listening_BGP_Speaker
 158     [Documentation]    Store results for plotting
 159     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 160     Store_File_To_Workspace    totals-${RESULTS_FILE_NAME}    totals-${RESULTS_FILE_NAME}
 161     Store_File_To_Workspace    performance-${RESULTS_FILE_NAME}    performance-${RESULTS_FILE_NAME}
 162     Store_File_To_Workspace    totals-${RESULTS_FILE_NAME}    prefixcount-listening-totals-${RESULTS_FILE_NAME}
 163     Store_File_To_Workspace    performance-${RESULTS_FILE_NAME}    prefixcount-listening-performance-${RESULTS_FILE_NAME}
 164
 165 Wait_For_Stable_Ipv4_Topology_After_Listening
 166     [Documentation]    Wait until example-ipv4-topology becomes stable again.
 167     [Tags]    critical
 168     PrefixCounting.Wait_For_Ipv4_Topology_Prefixes_To_Become_Stable    timeout=${bgp_filling_timeout}    period=${CHECK_PERIOD_PREFIX_COUNT_SINGLE}    repetitions=${REPETITIONS_PREFIX_COUNT_SINGLE}    excluded_count=${COUNT_PREFIX_COUNT_SINGLE}
 169
 170 Check_For_Empty_Ipv4_Topology_After_Listening
 171     [Documentation]    Example-ipv4-topology should be empty now.
 172     [Tags]    critical
 173     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 174     PrefixCounting.Check_Ipv4_Topology_Is_Empty
 175
 176 Restore_Karaf_Logging_Levels
 177     [Documentation]    Set logging on bgpcep and protocol to the global value.
 178     KarafKeywords.Set_Bgpcep_Log_Levels    bgpcep_level=${KARAF_LOG_LEVEL}    protocol_level=${KARAF_LOG_LEVEL}
 179
 180 Delete_Bgp_Peer_Configuration
 181     [Documentation]    Revert the BGP configuration to the original state: without any configured peers.
 182     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 183     ${template_as_string} =    BuiltIn.Set_Variable    {'NAME': 'example-bgp-peer'}
 184     ConfigViaRestconf.Delete_Xml_Template_Folder_Config_Via_Restconf    ${BGP_VARIABLES_FOLDER}${/}bgp_peer    ${template_as_string}
 185
 186 *** Keywords ***
 187 Setup_Everything
 188     [Documentation]    Setup imported resources, SSH-login to tools system,
 189     ...    create HTTP session, put Python tool to tools system.
 190     SetupUtils.Setup_Utils_For_Setup_And_Teardown
 191     ConfigViaRestconf.Setup_Config_Via_Restconf
 192     PrefixCounting.PC_Setup
 193     SSHLibrary.Set_Default_Configuration    prompt=${TOOLS_SYSTEM_PROMPT}
 194     SSHLibrary.Open_Connection    ${TOOLS_SYSTEM_IP}
 195     Utils.Flexible_Mininet_Login
 196     RequestsLibrary.Create_Session    operational    http://${ODL_SYSTEM_IP}:${RESTCONFPORT}${OPERATIONAL_API}    auth=${AUTH}
 197     # TODO: Do not include slash in ${OPERATIONAL_TOPO_API}, having it typed here is more readable.
 198     # TODO: Alternatively, create variable in Variables which starts with http.
 199     # Both TODOs would probably need to update every suite relying on current Variables.
 200     SSHLibrary.Put_File    ${CURDIR}/../../../../tools/fastbgp/play.py
 201     # Calculate the timeout value based on how many routes are going to be pushed
 202     # TODO: Replace 20 with some formula from period and repetitions.
 203     ${timeout} =    BuiltIn.Evaluate    ${TEST_DURATION_MULTIPLIER_PREFIX_COUNT_SINGLE} * (${COUNT_PREFIX_COUNT_SINGLE} * 3.0 / 10000 + 20)
 204     Builtin.Set_Suite_Variable    ${bgp_filling_timeout}    ${timeout}
 205     Builtin.Set_Suite_Variable    ${bgp_emptying_timeout}    ${bgp_filling_timeout*3.0/4}
 206     KarafKeywords.Execute_Controller_Karaf_Command_On_Background    log:set ${KARAF_LOG_LEVEL}
 207
 208 Teardown_Everything
 209     [Documentation]    Make sure Python tool was killed and tear down imported Resources.
 210     # Environment issue may have dropped the SSH connection, but we do not want Teardown to fail.
 211     BuiltIn.Run_Keyword_And_Ignore_Error    KillPythonTool.Search_And_Kill_Remote_Python    'play\.py'
 212     ConfigViaRestconf.Teardown_Config_Via_Restconf
 213     RequestsLibrary.Delete_All_Sessions
 214     SSHLibrary.Close_All_Connections
 215
 216 Store_File_To_Workspace
 217     [Arguments]    ${src_file_name}    ${dst_file_name}
 218     [Documentation]    Store the provided file from the SSH client to workspace.
 219     ${files}=    SSHLibrary.List Files In Directory    .
 220     ${output_log}=    SSHLibrary.Execute_Command    cat ${src_file_name}
 221     BuiltIn.Log    ${output_log}
 222     Create File    ${dst_file_name}    ${output_log}