csit/suites/bgpcep/bgpuser/cases.robot

   1 *** Settings ***
   2 Documentation     Basic tests for odl-bgpcep-bgp-all feature.
   3 ...
   4 ...               Copyright (c) 2015 Cisco Systems, Inc. and others. All rights reserved.
   5 ...
   6 ...               This program and the accompanying materials are made available under the
   7 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   8 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
   9 ...
  10 ...
  11 ...               Brief description of what this suite should do:
  12 ...               https://wiki.opendaylight.org/view/BGP_LS_PCEP:Lithium_Feature_Tests#How_to_test_2
  13 Suite Setup       Setup_Everything
  14 Suite Teardown    Teardown_Everything
  15 Test Setup        FailFast.Fail_This_Fast_On_Previous_Error
  16 Test Teardown     FailFast.Start_Failing_Fast_If_This_Failed
  17 Library           OperatingSystem
  18 Library           SSHLibrary    prompt=]>    timeout=10s    # FIXME: The prompt should have default value from a common resource, and should be overwritable by pybot -v in scripts.
  19 Library           RequestsLibrary
  20 Library           ${CURDIR}/../../../libraries/HsfJson/hsf_json.py
  21 Variables         ${CURDIR}/../../../variables/Variables.py
  22 Variables         ${CURDIR}/../../../variables/bgpuser/variables.py    ${MININET}
  23 Resource          ${CURDIR}/../../../libraries/ConfigViaRestconf.robot
  24 Resource          ${CURDIR}/../../../libraries/FailFast.robot
  25 Resource          ${CURDIR}/../../../libraries/KillPythonTool.robot
  26 Resource          ${CURDIR}/../../../libraries/WaitForFailure.robot
  27 Resource          ${CURDIR}/../../../libraries/Utils.robot
  28
  29 *** Variables ***
  30 ${directory_for_actual_responses}    ${TEMPDIR}/actual
  31 ${directory_for_expected_responses}    ${TEMPDIR}/expected
  32 ${directory_with_template_folders}    ${CURDIR}/../../../variables/bgpuser/
  33 ${HOLDTIME}    180
  34
  35 *** Test Cases ***
  36 Check_For_Empty_Topology_Before_Talking
  37     [Documentation]    Sanity check example-ipv4-topology is up but empty.
  38     [Tags]    critical
  39     Wait_For_Topology_To_Change_To    ${empty_json}    010_Empty.json    timeout=120s
  40     # TODO: Verify that 120 seconds is not too short if this suite is run immediatelly after ODL is started.
  41
  42 Reconfigure_ODL_To_Accept_Connection
  43     [Documentation]    Configure BGP peer module with initiate-connection set to false.
  44     ${template_as_string}=    BuiltIn.Set_Variable    {'IP': '${MININET}', 'HOLDTIME': '${HOLDTIME}', 'INITIATE': 'false'}
  45     Put_Xml_Template_Folder_Config_Via_Restconf    ${directory_with_template_folders}${/}bgp_peer    ${template_as_string}
  46
  47 Start_Talking_BGP_speaker
  48     [Documentation]    Start Python speaker to connect to ODL, verify that the tool does not promptly exit.
  49     ${command}=    BuiltIn.Set_Variable    python play.py --amount 2 --myip=${MININET} --myport=17900 --peerip=${CONTROLLER} --peerport=1790
  50     # Myport value is needed for checking whether connection at precise port was established.
  51     # TODO: Do we want to define ${BGP_PORT} in Variables.py?
  52     BuiltIn.Log    ${command}
  53     ${output}=    SSHLibrary.Write    ${command}
  54     Read_And_Fail_If_Prompt_Is_Seen
  55
  56 Check_Talking_Connection_Is_Established
  57     [Documentation]    See TCP (BGP) connection in established state.
  58     # This case is separate from the previous one, to resemble structure of the second half of this suite more closely.
  59     Check_Speaker_Is_Connected
  60
  61 Check_Talking_Topology_Is_Filled
  62     [Documentation]    See new routes in example-ipv4-topology as a proof that synchronization was correct.
  63     [Tags]    critical
  64     Wait_For_Topology_To_Change_To    ${filled_json}    020_Filled.json
  65
  66 Kill_Talking_BGP_Speaker
  67     [Documentation]    Abort the Python speaker. Also, attempt to stop failing fast.
  68     [Setup]    FailFast.Run_Even_When_Failing_Fast
  69     Kill_BGP_Speaker
  70     FailFast.Do_Not_Fail_Fast_From_Now_On
  71     # NOTE: It is still possible to remain failing fast, if both previous and this test have failed.
  72     [Teardown]    FailFast.Do_Not_Start_Failing_If_This_Failed
  73
  74 Check_For_Empty_Topology_After_Talking
  75     [Documentation]    See example-ipv4-topology empty again.
  76     [Tags]    critical
  77     Wait_For_Topology_To_Change_To    ${empty_json}    030_Empty.json
  78
  79 Start_Listening_BGP_Speaker
  80     [Documentation]    Start Python speaker in listening mode, verify that the tool does not exit quickly.
  81     ${command}=    BuiltIn.Set_Variable    python play.py --amount 2 --listen --myip=${MININET} --myport=17900 --peerip=${CONTROLLER}
  82     # TODO: ${BGP_TOOL_PORT} is probably not worth the trouble.
  83     Builtin.Log    ${command}
  84     ${output}=    SSHLibrary.Write    ${command}
  85     Read_And_Fail_If_Prompt_Is_Seen
  86
  87 Check_Listening_Connection_Is_Not_Established_Yet
  88     [Documentation]    See no TCP connection, as both ODL and tool are in listening mode.
  89     Check_Speaker_Is_Not_Connected
  90
  91 Check_For_Empty_Topology_Before_Listening
  92     [Documentation]    Sanity check example-ipv4-topology is still empty.
  93     [Tags]    critical
  94     Verify_That_Topology_Does_Not_Change_From    ${empty_json}    040_Empty.json
  95
  96 Reconfigure_ODL_To_Initiate_Connection
  97     [Documentation]    Replace BGP peer config module, now with initiate-connection set to true.
  98     ${template_as_string}=    BuiltIn.Set_Variable    {'IP': '${MININET}', 'HOLDTIME': '${HOLDTIME}', 'INITIATE': 'true'}
  99     Put_Xml_Template_Folder_Config_Via_Restconf    ${directory_with_template_folders}${/}bgp_peer    ${template_as_string}
 100
 101 Check_Listening_Connection_Is_Established
 102     [Documentation]    See TCP (BGP) connection in established state.
 103     Check_Speaker_Is_Connected
 104
 105 Check_Listening_Topology_Is_Filled
 106     [Documentation]    See new routes in example-ipv4-topology as a proof that synchronization was correct.
 107     [Tags]    critical
 108     Wait_For_Topology_To_Change_To    ${filled_json}    050_Filled.json
 109
 110 Kill_Listening_BGP_Speaker
 111     [Documentation]    Abort the Python speaker. Also, attempt to stop failing fast.
 112     [Setup]    FailFast.Run_Even_When_Failing_Fast
 113     Kill_BGP_Speaker
 114     FailFast.Do_Not_Fail_Fast_From_Now_On
 115     # NOTE: It is still possible to remain failing, if both previous and this test failed.
 116     [Teardown]    FailFast.Do_Not_Start_Failing_If_This_Failed
 117
 118 Check_For_Empty_Topology_After_Listening
 119     [Documentation]    Post-condition: Check example-ipv4-topology is empty again.
 120     [Tags]    critical
 121     Wait_For_Topology_To_Change_To    ${empty_json}    060_Empty.json
 122
 123 Delete_Bgp_Peer_Configuration
 124     [Documentation]    Revert the BGP configuration to the original state: without any configured peers.
 125     Delete_Xml_Template_Folder_Config_Via_Restconf    ${directory_with_template_folders}${/}bgp_peer
 126     # TODO: Do we need to check something else?
 127
 128 *** Keywords ***
 129 Setup_Everything
 130     [Documentation]    SSH-login to mininet machine, save prompt to variable, create HTTP session,
 131     ...    prepare directories for responses, put Python tool to mininet machine, setup imported resources.
 132     SSHLibrary.Open_Connection    ${MININET}
 133     Flexible SSH Login     ${MININET_USER}    ${MININET_PASSWORD}
 134     ${current_connection}=    Get_Connection
 135     ${current_prompt}=    BuiltIn.Set_Variable    ${current_connection.prompt}
 136     BuiltIn.Log    ${current_prompt}
 137     Builtin.Set_Suite_Variable    ${prompt}    ${current_prompt}
 138     RequestsLibrary.Create_Session    ses    http://${CONTROLLER}:${RESTCONFPORT}${OPERATIONAL_TOPO_API}    auth=${AUTH}
 139     # TODO: Do not include slash in ${OPERATIONAL_TOPO_API}, having it typed here is more readable.
 140     # TODO: Alternatively, create variable in Variables which starts with http.
 141     # Both TODOs would probably need to update every suite relying on current Variables.
 142     OperatingSystem.Remove_Directory    ${directory_for_expected_responses}    recursive=True
 143     OperatingSystem.Remove_Directory    ${directory_for_actual_responses}    recursive=True
 144     # The previous suite may have been using the same directories.
 145     OperatingSystem.Create_Directory    ${directory_for_expected_responses}
 146     OperatingSystem.Create_Directory    ${directory_for_actual_responses}
 147     SSHLibrary.Put_File    ${CURDIR}/../../../../tools/fastbgp/play.py
 148     ConfigViaRestconf.Setup_Config_Via_Restconf
 149     FailFast.Do_Not_Fail_Fast_From_Now_On
 150
 151 Teardown_Everything
 152     [Documentation]    Create and Log the diff between expected and actual responses, make sure Python tool was killed.
 153     ...    Tear down imported Resources.
 154     ${diff}=    OperatingSystem.Run    diff -dur ${directory_for_expected_responses} ${directory_for_actual_responses}
 155     BuiltIn.Log    ${diff}
 156     KillPythonTool.Search_And_Kill_Remote_Python    'play\.py'
 157     ConfigViaRestconf.Teardown_Config_Via_Restconf
 158     RequestsLibrary.Delete_All_Sessions
 159     SSHLibrary.Close_All_Connections
 160
 161 Wait_For_Topology_To_Change_To
 162     [Arguments]    ${json_topology}    ${filename}    ${timeout}=10s    ${refresh}=1s
 163     [Documentation]    Normalize the expected json topology and save it to ${directory_for_expected_responses}.
 164     ...    Wait until Compare_Topology matches. ${directory_for_actual_responses} will hold its last result.
 165     ${topology_normalized}=    Normalize_And_Save_Expected_Json    ${json_topology}    ${filename}    ${directory_for_expected_responses}
 166     BuiltIn.Wait_Until_Keyword_Succeeds    ${timeout}    ${refresh}    Compare_Topology    ${topology_normalized}    ${filename}
 167
 168 Verify_That_Topology_Does_Not_Change_From
 169     [Arguments]    ${json_topology}    ${filename}    ${timeout}=10s    ${refresh}=1s
 170     [Documentation]    Normalize the expected json topology and save it to ${directory_for_expected_responses}.
 171     ...    Verify that Compare_Topology keeps passing. ${directory_for_actual_responses} will hold its last result.
 172     ${topology_normalized}=    Normalize_And_Save_Expected_Json    ${json_topology}    ${filename}    ${directory_for_expected_responses}
 173     WaitForFailure.Verify_Keyword_Does_Not_Fail_Within_Timeout    ${timeout}    ${refresh}    Compare_Topology    ${topology_normalized}    ${filename}
 174
 175 Compare_Topology
 176     [Arguments]    ${expected_normalized}    ${filename}
 177     [Documentation]    Get current example-ipv4-topology as json, normalize it, save to ${directory_for_actual_responses}.
 178     ...    Check that status code is 200, check that normalized jsons match exactly.
 179     ${response}=    RequestsLibrary.Get    ses    topology/example-ipv4-topology
 180     BuiltIn.Log    ${response.status_code}
 181     BuiltIn.Log    ${response.text}
 182     ${actual_normalized}=    Normalize_And_Save_Expected_Json    ${response.text}    ${filename}    ${directory_for_actual_responses}
 183     BuiltIn.Should_Be_Equal_As_Strings    ${response.status_code}    200
 184     BuiltIn.Should_Be_Equal    ${actual_normalized}    ${expected_normalized}
 185
 186 Normalize_And_Save_Expected_Json
 187     [Arguments]    ${json_text}    ${filename}    ${directory}
 188     [Documentation]    Normalize given json using hsf_json library. Log and save the result to given filename under given directory.
 189     ${json_normalized}=    hsf_json.Hsf_Json    ${json_text}
 190     BuiltIn.Log    ${json_normalized}
 191     OperatingSystem.Create_File    ${directory}${/}${filename}    ${json_normalized}
 192     # TODO: Should we prepend .json to the filename? When we detect it is not already prepended?
 193     [Return]    ${json_normalized}
 194
 195 Kill_BGP_Speaker
 196     [Documentation]    Interrupt play.py, fail if no prompt is seen within SSHLibrary timeout.
 197     ...    Also, check that TCP connection is no longer established.
 198     Write_Bare_Ctrl_C
 199     SSHLibrary.Read_Until_Prompt
 200     Check_Speaker_Is_Not_Connected
 201
 202 Check_Speaker_Is_Not_Connected
 203     [Documentation]    Give it a few tries to see zero established connections.
 204     BuiltIn.Wait_Until_Keyword_Succeeds    3s    1s    Check_Number_Of_Speaker_Connections    0
 205
 206 Check_Speaker_Is_Connected
 207     [Documentation]    Give it several tries to see exactly one established connection.
 208     BuiltIn.Wait_Until_Keyword_Succeeds    5s    1s    Check_Number_Of_Speaker_Connections    1
 209
 210 Check_Number_Of_Speaker_Connections
 211     [Arguments]    ${howmany}
 212     [Documentation]    Run netstat in mininet machine and parse it for number of established connections. Check it is ${howmany}.
 213     ${output}=    SSHLibrary.Execute_Command    netstat -npt 2> /dev/null | grep -E ":17900 .+ ESTABLISHED .+python" | wc -l
 214     BuiltIn.Should_Be_Equal_As_Strings    ${output}    ${howmany}
 215
 216 Read_And_Fail_If_Prompt_Is_Seen
 217     [Documentation]    Try to read SSH to see prompt, but expect to see no prompt within SSHLibrary's timeout.
 218     BuiltIn.Run_Keyword_And_Expect_Error    No match found for '${prompt}' in *.    Read_Text_Before_Prompt
 219
 220 Read_Text_Before_Prompt
 221     [Documentation]    Log text gathered by SSHLibrary.Read_Until_Prompt.
 222     ...    This needs to be a separate keyword just because how Read_And_Fail_If_Prompt_Is_Seen is implemented.
 223     ${text}=    SSHLibrary.Read_Until_Prompt
 224     BuiltIn.Log    ${text}
 225
 226 Write_Bare_Ctrl_C
 227     [Documentation]    Construct ctrl+c character and SSH-write it (without endline). Do not read anything yet.
 228     # TODO: Place this keyword to some Resource so that it can be re-used in other suites.
 229     ${command}=    BuiltIn.Evaluate    chr(int(3))
 230     SSHLibrary.Write_Bare    ${command}