csit/suites/bgpcep/bgpuser/cases.robot

   1 *** Settings ***
   2 Documentation     Basic tests for odl-bgpcep-bgp-all feature.
   3 ...
   4 ...               Copyright (c) 2015 Cisco Systems, Inc. and others. All rights reserved.
   5 ...
   6 ...               This program and the accompanying materials are made available under the
   7 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   8 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
   9 ...
  10 ...
  11 ...               Brief description of what this suite should do:
  12 ...               https://wiki.opendaylight.org/view/BGP_LS_PCEP:Lithium_Feature_Tests#How_to_test_2
  13 Suite Setup       Setup_Everything
  14 Suite Teardown    Teardown_Everything
  15 Test Setup        SetupUtils.Setup_Test_With_Logging_And_Fast_Failing
  16 Test Teardown     FailFast.Start_Failing_Fast_If_This_Failed
  17 Library           OperatingSystem
  18 Library           SSHLibrary    prompt=]>    timeout=10s    # FIXME: The prompt should have default value from a common resource, and should be overwritable by pybot -v in scripts.
  19 Library           RequestsLibrary
  20 Library           ${CURDIR}/../../../libraries/HsfJson/hsf_json.py
  21 Variables         ${CURDIR}/../../../variables/Variables.py
  22 Variables         ${CURDIR}/../../../variables/bgpuser/variables.py    ${MININET}
  23 Resource          ${CURDIR}/../../../libraries/BGPSpeaker.robot
  24 Resource          ${CURDIR}/../../../libraries/ConfigViaRestconf.robot
  25 Resource          ${CURDIR}/../../../libraries/FailFast.robot
  26 Resource          ${CURDIR}/../../../libraries/KarafKeywords.robot
  27 Resource          ${CURDIR}/../../../libraries/KillPythonTool.robot
  28 Resource          ${CURDIR}/../../../libraries/SetupUtils.robot
  29 Resource          ${CURDIR}/../../../libraries/Utils.robot
  30 Resource          ${CURDIR}/../../../libraries/WaitForFailure.robot
  31
  32 *** Variables ***
  33 ${directory_for_actual_responses}    ${TEMPDIR}/actual
  34 ${directory_for_expected_responses}    ${TEMPDIR}/expected
  35 ${directory_with_template_folders}    ${CURDIR}/../../../variables/bgpuser/
  36 ${HOLDTIME}       180
  37
  38 *** Test Cases ***
  39 Check_For_Empty_Topology_Before_Talking
  40     [Documentation]    Sanity check example-ipv4-topology is up but empty.
  41     [Tags]    critical
  42     Wait_For_Topology_To_Change_To    ${empty_json}    010_Empty.json    timeout=120s
  43     # TODO: Verify that 120 seconds is not too short if this suite is run immediatelly after ODL is started.
  44
  45 Reconfigure_ODL_To_Accept_Connection
  46     [Documentation]    Configure BGP peer module with initiate-connection set to false.
  47     ${template_as_string}=    BuiltIn.Set_Variable    {'IP': '${MININET}', 'HOLDTIME': '${HOLDTIME}', 'PEER_PORT': '${BGP_TOOL_PORT}', 'INITIATE': 'false'}
  48     ConfigViaRestconf.Put_Xml_Template_Folder_Config_Via_Restconf    ${directory_with_template_folders}${/}bgp_peer    ${template_as_string}
  49
  50 Start_Talking_BGP_speaker
  51     [Documentation]    Start Python speaker to connect to ODL, verify that the tool does not promptly exit.
  52     # Myport value is needed for checking whether connection at precise port was established.
  53     BGPSpeaker.Start_BGP_Speaker    --amount 2 --myip=${MININET} --myport=${BGP_TOOL_PORT} --peerip=${CONTROLLER} --peerport=${ODL_BGP_PORT}
  54     Read_And_Fail_If_Prompt_Is_Seen
  55
  56 Check_Talking_Connection_Is_Established
  57     [Documentation]    See TCP (BGP) connection in established state.
  58     # This case is separate from the previous one, to resemble structure of the second half of this suite more closely.
  59     Check_Speaker_Is_Connected
  60
  61 Check_Talking_Topology_Is_Filled
  62     [Documentation]    See new routes in example-ipv4-topology as a proof that synchronization was correct.
  63     [Tags]    critical
  64     Wait_For_Topology_To_Change_To    ${filled_json}    020_Filled.json
  65
  66 Kill_Talking_BGP_Speaker
  67     [Documentation]    Abort the Python speaker. Also, attempt to stop failing fast.
  68     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
  69     BGPSpeaker.Kill_BGP_Speaker
  70     FailFast.Do_Not_Fail_Fast_From_Now_On
  71     # NOTE: It is still possible to remain failing fast, if both previous and this test have failed.
  72     [Teardown]    FailFast.Do_Not_Start_Failing_If_This_Failed
  73
  74 Check_For_Empty_Topology_After_Talking
  75     [Documentation]    See example-ipv4-topology empty again.
  76     [Tags]    critical
  77     Wait_For_Topology_To_Change_To    ${empty_json}    030_Empty.json
  78
  79 Start_Listening_BGP_Speaker
  80     [Documentation]    Start Python speaker in listening mode, verify that the tool does not exit quickly.
  81     BGPSpeaker.Start_BGP_Speaker    --amount 2 --listen --myip=${MININET} --myport=${BGP_TOOL_PORT} --peerip=${CONTROLLER}
  82     Read_And_Fail_If_Prompt_Is_Seen
  83
  84 Check_Listening_Connection_Is_Not_Established_Yet
  85     [Documentation]    See no TCP connection, as both ODL and tool are in listening mode.
  86     Check_Speaker_Is_Not_Connected
  87
  88 Check_For_Empty_Topology_Before_Listening
  89     [Documentation]    Sanity check example-ipv4-topology is still empty.
  90     [Tags]    critical
  91     Verify_That_Topology_Does_Not_Change_From    ${empty_json}    040_Empty.json
  92
  93 Reconfigure_ODL_To_Initiate_Connection
  94     [Documentation]    Replace BGP peer config module, now with initiate-connection set to true.
  95     ${template_as_string}=    BuiltIn.Set_Variable    {'IP': '${MININET}', 'HOLDTIME': '${HOLDTIME}', 'PEER_PORT': '${BGP_TOOL_PORT}', 'INITIATE': 'true'}
  96     ConfigViaRestconf.Put_Xml_Template_Folder_Config_Via_Restconf    ${directory_with_template_folders}${/}bgp_peer    ${template_as_string}
  97
  98 Check_Listening_Connection_Is_Established
  99     [Documentation]    See TCP (BGP) connection in established state.
 100     Check_Speaker_Is_Connected
 101
 102 Check_Listening_Topology_Is_Filled
 103     [Documentation]    See new routes in example-ipv4-topology as a proof that synchronization was correct.
 104     [Tags]    critical
 105     Wait_For_Topology_To_Change_To    ${filled_json}    050_Filled.json
 106
 107 Kill_Listening_BGP_Speaker
 108     [Documentation]    Abort the Python speaker. Also, attempt to stop failing fast.
 109     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 110     BGPSpeaker.Kill_BGP_Speaker
 111     FailFast.Do_Not_Fail_Fast_From_Now_On
 112     # NOTE: It is still possible to remain failing, if both previous and this test failed.
 113     [Teardown]    FailFast.Do_Not_Start_Failing_If_This_Failed
 114
 115 Check_For_Empty_Topology_After_Listening
 116     [Documentation]    Post-condition: Check example-ipv4-topology is empty again.
 117     [Tags]    critical
 118     Wait_For_Topology_To_Change_To    ${empty_json}    060_Empty.json
 119
 120 Delete_Bgp_Peer_Configuration
 121     [Documentation]    Revert the BGP configuration to the original state: without any configured peers.
 122     ConfigViaRestconf.Delete_Xml_Template_Folder_Config_Via_Restconf    ${directory_with_template_folders}${/}bgp_peer
 123     # TODO: Do we need to check something else?
 124
 125 *** Keywords ***
 126 Setup_Everything
 127     [Documentation]    SSH-login to mininet machine, save prompt to variable, create HTTP session,
 128     ...    prepare directories for responses, put Python tool to mininet machine, setup imported resources.
 129     SetupUtils.Setup_Utils_For_Setup_And_Teardown
 130     SSHLibrary.Open_Connection    ${MININET}
 131     Utils.Flexible_SSH_Login    ${MININET_USER}    ${MININET_PASSWORD}
 132     ${current_connection}=    Get_Connection
 133     ${current_prompt}=    BuiltIn.Set_Variable    ${current_connection.prompt}
 134     BuiltIn.Log    ${current_prompt}
 135     Builtin.Set_Suite_Variable    ${prompt}    ${current_prompt}
 136     RequestsLibrary.Create_Session    ses    http://${CONTROLLER}:${RESTCONFPORT}${OPERATIONAL_TOPO_API}    auth=${AUTH}
 137     # TODO: Do not include slash in ${OPERATIONAL_TOPO_API}, having it typed here is more readable.
 138     # TODO: Alternatively, create variable in Variables which starts with http.
 139     # Both TODOs would probably need to update every suite relying on current Variables.
 140     OperatingSystem.Remove_Directory    ${directory_for_expected_responses}    recursive=True
 141     OperatingSystem.Remove_Directory    ${directory_for_actual_responses}    recursive=True
 142     # The previous suite may have been using the same directories.
 143     OperatingSystem.Create_Directory    ${directory_for_expected_responses}
 144     OperatingSystem.Create_Directory    ${directory_for_actual_responses}
 145     SSHLibrary.Put_File    ${CURDIR}/../../../../tools/fastbgp/play.py
 146     ConfigViaRestconf.Setup_Config_Via_Restconf
 147
 148 Teardown_Everything
 149     [Documentation]    Create and Log the diff between expected and actual responses, make sure Python tool was killed.
 150     ...    Tear down imported Resources.
 151     ${diff}=    OperatingSystem.Run    diff -dur ${directory_for_expected_responses} ${directory_for_actual_responses}
 152     BuiltIn.Log    ${diff}
 153     KillPythonTool.Search_And_Kill_Remote_Python    'play\.py'
 154     ConfigViaRestconf.Teardown_Config_Via_Restconf
 155     RequestsLibrary.Delete_All_Sessions
 156     SSHLibrary.Close_All_Connections
 157
 158 Wait_For_Topology_To_Change_To
 159     [Arguments]    ${json_topology}    ${filename}    ${timeout}=10s    ${refresh}=1s
 160     [Documentation]    Normalize the expected json topology and save it to ${directory_for_expected_responses}.
 161     ...    Wait until Compare_Topology matches. ${directory_for_actual_responses} will hold its last result.
 162     ${topology_normalized}=    Normalize_And_Save_Expected_Json    ${json_topology}    ${filename}    ${directory_for_expected_responses}
 163     BuiltIn.Wait_Until_Keyword_Succeeds    ${timeout}    ${refresh}    Compare_Topology    ${topology_normalized}    ${filename}
 164
 165 Verify_That_Topology_Does_Not_Change_From
 166     [Arguments]    ${json_topology}    ${filename}    ${timeout}=10s    ${refresh}=1s
 167     [Documentation]    Normalize the expected json topology and save it to ${directory_for_expected_responses}.
 168     ...    Verify that Compare_Topology keeps passing. ${directory_for_actual_responses} will hold its last result.
 169     ${topology_normalized}=    Normalize_And_Save_Expected_Json    ${json_topology}    ${filename}    ${directory_for_expected_responses}
 170     WaitForFailure.Verify_Keyword_Does_Not_Fail_Within_Timeout    ${timeout}    ${refresh}    Compare_Topology    ${topology_normalized}    ${filename}
 171
 172 Compare_Topology
 173     [Arguments]    ${expected_normalized}    ${filename}
 174     [Documentation]    Get current example-ipv4-topology as json, normalize it, save to ${directory_for_actual_responses}.
 175     ...    Check that status code is 200, check that normalized jsons match exactly.
 176     ${response}=    RequestsLibrary.Get    ses    topology/example-ipv4-topology
 177     BuiltIn.Log    ${response.status_code}
 178     BuiltIn.Log    ${response.text}
 179     ${actual_normalized}=    Normalize_And_Save_Expected_Json    ${response.text}    ${filename}    ${directory_for_actual_responses}
 180     BuiltIn.Should_Be_Equal_As_Strings    ${response.status_code}    200
 181     BuiltIn.Should_Be_Equal    ${actual_normalized}    ${expected_normalized}
 182
 183 Normalize_And_Save_Expected_Json
 184     [Arguments]    ${json_text}    ${filename}    ${directory}
 185     [Documentation]    Normalize given json using hsf_json library. Log and save the result to given filename under given directory.
 186     ${json_normalized}=    hsf_json.Hsf_Json    ${json_text}
 187     BuiltIn.Log    ${json_normalized}
 188     OperatingSystem.Create_File    ${directory}${/}${filename}    ${json_normalized}
 189     # TODO: Should we prepend .json to the filename? When we detect it is not already prepended?
 190     [Return]    ${json_normalized}
 191
 192 Check_Speaker_Is_Not_Connected
 193     [Documentation]    Give it a few tries to see zero established connections.
 194     BuiltIn.Wait_Until_Keyword_Succeeds    3s    1s    Check_Number_Of_Speaker_Connections    0
 195
 196 Check_Speaker_Is_Connected
 197     [Documentation]    Give it several tries to see exactly one established connection.
 198     BuiltIn.Wait_Until_Keyword_Succeeds    5s    1s    Check_Number_Of_Speaker_Connections    1
 199
 200 Check_Number_Of_Speaker_Connections
 201     [Arguments]    ${howmany}
 202     [Documentation]    Run netstat in mininet machine and parse it for number of established connections. Check it is ${howmany}.
 203     ${output}=    SSHLibrary.Execute_Command    netstat -npt 2> /dev/null | grep -E ":17900 .+ ESTABLISHED .+python" | wc -l
 204     BuiltIn.Should_Be_Equal_As_Strings    ${output}    ${howmany}
 205
 206 Read_And_Fail_If_Prompt_Is_Seen
 207     [Documentation]    Try to read SSH to see prompt, but expect to see no prompt within SSHLibrary's timeout.
 208     ${passed}=    BuiltIn.Run_Keyword_And_Return_Status    BuiltIn.Run_Keyword_And_Expect_Error    No match found for '${prompt}' in *.    Read_Text_Before_Prompt
 209     BuiltIn.Return_From_Keyword_If    ${passed}
 210     BGPSpeaker.Dump_BGP_Speaker_Logs
 211     Builtin.Fail    The prompt was seen but it was not expected yet
 212
 213 Read_Text_Before_Prompt
 214     [Documentation]    Log text gathered by SSHLibrary.Read_Until_Prompt.
 215     ...    This needs to be a separate keyword just because how Read_And_Fail_If_Prompt_Is_Seen is implemented.
 216     ${text}=    SSHLibrary.Read_Until_Prompt
 217     BuiltIn.Log    ${text}