csit/suites/bgpcep/bgpuser/ebgp_peers_basic.robot

   1 *** Settings ***
   2 Documentation     Basic tests for eBGP application peers.
   3 ...
   4 ...               Copyright (c) 2015-2016 Cisco Systems, Inc. and others. All rights reserved.
   5 ...
   6 ...               This program and the accompanying materials are made available under the
   7 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   8 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
   9 ...
  10 ...               Test suite performs basic eBGP functional tests:
  11 ...               Two eBGP peers advertise the same group of prefixes (aka BGP HA)
  12 ...               https://wiki.opendaylight.org/view/BGP_LS_PCEP:BGP
  13 ...               Reported bugs:
  14 ...               Bug 4834 - ODL controller announces the same route twice (two eBGP scenario aka HA)
  15 ...               Bug 4835 - Routes not withdrawn when eBGP peers are disconnected (the same prefixes announced)
  16 ...
  17 ...               TODO: Extend testsuite by tests dedicated to path selection algorithm
  18 ...               TODO: Choose keywords used by more than one test suite to be placed in a common place.
  19 Suite Setup       Setup_Everything
  20 Suite Teardown    Teardown_Everything
  21 Test Setup        SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
  22 Test Teardown     FailFast.Start_Failing_Fast_If_This_Failed
  23 Library           OperatingSystem
  24 Library           RequestsLibrary
  25 Library           ${CURDIR}/../../../libraries/HsfJson/hsf_json.py
  26 Variables         ${CURDIR}/../../../variables/Variables.py
  27 Variables         ${CURDIR}/../../../variables/bgpuser/variables.py    ${ODL_SYSTEM_PROMPT}
  28 Resource          ${CURDIR}/../../../libraries/BGPcliKeywords.robot
  29 Resource          ${CURDIR}/../../../libraries/BGPSpeaker.robot
  30 Resource          ${CURDIR}/../../../libraries/ConfigViaRestconf.robot
  31 Resource          ${CURDIR}/../../../libraries/FailFast.robot
  32 Resource          ${CURDIR}/../../../libraries/KarafKeywords.robot
  33 Resource          ${CURDIR}/../../../libraries/KillPythonTool.robot
  34 Resource          ${CURDIR}/../../../libraries/SetupUtils.robot
  35 Resource          ${CURDIR}/../../../libraries/SSHKeywords.robot
  36 Resource          ${CURDIR}/../../../libraries/Utils.robot
  37 Resource          ${CURDIR}/../../../libraries/WaitForFailure.robot
  38
  39 *** Variables ***
  40 ${BGP_VARIABLES_FOLDER}    ${CURDIR}/../../../variables/bgpuser/
  41 ${HOLDTIME}       180
  42 ${BGP_PEER_LOG_LEVEL}    debug
  43 ${CONTROLLER_LOG_LEVEL}    INFO
  44 ${CONTROLLER_BGP_LOG_LEVEL}    DEFAULT
  45 ${iBGP_PEER1_IP}    127.0.0.1
  46 ${eBGP_PEER1_IP}    127.0.0.3
  47 ${eBGP_PEER2_IP}    127.0.0.4
  48 ${iBGP_PEER1_FIRST_PREFIX_IP}    8.1.0.0
  49 ${eBGP_PEERS_FIRST_PREFIX_IP}    8.0.0.0
  50 ${eBGP_PEER1_FIRST_PREFIX_IP}    ${eBGP_PEERS_FIRST_PREFIX_IP}
  51 ${eBGP_PEER2_FIRST_PREFIX_IP}    ${eBGP_PEERS_FIRST_PREFIX_IP}
  52 ${eBGP_PEER1_NEXT_HOP}    1.1.1.1
  53 ${eBGP_PEER2_NEXT_HOP}    2.2.2.2
  54 ${PREFIX_LEN}     28
  55 ${iBGP_PEER1_PREFIX_LEN}    ${PREFIX_LEN}
  56 ${eBGP_PEER1_PREFIX_LEN}    ${PREFIX_LEN}
  57 ${eBGP_PEER2_PREFIX_LEN}    ${PREFIX_LEN}
  58 ${PREFIX_COUNT}    2
  59 ${iBGP_PEER1_PREFIX_COUNT}    0
  60 ${eBGP_PEER1_PREFIX_COUNT}    ${PREFIX_COUNT}
  61 ${eBGP_PEER2_PREFIX_COUNT}    ${PREFIX_COUNT}
  62 ${eBGP_PEERS_AS}    32768
  63 ${eBGP_PEER1_AS}    ${eBGP_PEERS_AS}
  64 ${eBGP_PEER2_AS}    ${eBGP_PEERS_AS}
  65 ${iBGP_PEER1_LOG_FILE}    bgp_peer1.log
  66 ${eBGP_PEER1_LOG_FILE}    ebgp_peer1.log
  67 ${eBGP_PEER2_LOG_FILE}    ebgp_peer2.log
  68 ${iBGP_PEER1_COMMAND}    python play.py --firstprefix ${iBGP_PEER1_FIRST_PREFIX_IP} --prefixlen ${iBGP_PEER1_PREFIX_LEN} --amount ${iBGP_PEER1_PREFIX_COUNT} --myip=${iBGP_PEER1_IP} --myport=${BGP_TOOL_PORT} --peerip=${ODL_SYSTEM_IP} --peerport=${ODL_BGP_PORT} --${BGP_PEER_LOG_LEVEL} --logfile ${iBGP_PEER1_LOG_FILE}
  69 ${eBGP_PEER1_COMMAND}    python play.py --firstprefix ${eBGP_PEER1_FIRST_PREFIX_IP} --prefixlen ${eBGP_PEER1_PREFIX_LEN} --amount ${eBGP_PEER1_PREFIX_COUNT} --myip=${eBGP_PEER1_IP} --myport=${BGP_TOOL_PORT} --peerip=${ODL_SYSTEM_IP} --peerport=${ODL_BGP_PORT} --nexthop ${eBGP_PEER1_NEXT_HOP} --asnumber ${eBGP_PEER1_AS} --${BGP_PEER_LOG_LEVEL} --logfile ${eBGP_PEER1_LOG_FILE}
  70 ${eBGP_PEER2_COMMAND}    python play.py --firstprefix ${eBGP_PEER2_FIRST_PREFIX_IP} --prefixlen ${eBGP_PEER2_PREFIX_LEN} --amount ${eBGP_PEER2_PREFIX_COUNT} --myip=${eBGP_PEER2_IP} --myport=${BGP_TOOL_PORT} --peerip=${ODL_SYSTEM_IP} --peerport=${ODL_BGP_PORT} --nexthop ${eBGP_PEER2_NEXT_HOP} --asnumber ${eBGP_PEER2_AS} --${BGP_PEER_LOG_LEVEL} --logfile ${eBGP_PEER2_LOG_FILE}
  71 ${iBGP_PEER1_OPTIONS}    &>${iBGP_PEER1_LOG_FILE}
  72 ${eBGP_PEER1_OPTIONS}    &>${eBGP_PEER1_LOG_FILE}
  73 ${eBGP_PEER2_OPTIONS}    &>${eBGP_PEER2_LOG_FILE}
  74 ${DEFAULT_LOG_CHECK_TIMEOUT}    20s
  75 ${DEFAULT_LOG_CHECK_PERIOD}    1s
  76 ${DEFAULT_TOPOLOGY_CHECK_TIMEOUT}    10s
  77 ${DEFAULT_TOPOLOGY_CHECK_PERIOD}    1s
  78
  79 *** Test Cases ***
  80 Configure_BGP_Peers
  81     [Documentation]    Configure an iBGP and two eBGP peers
  82     [Tags]    critical
  83     ${template_as_string}=    BuiltIn.Set_Variable    {'NAME': 'example-ibgp-peer1', 'IP': '${iBGP_PEER1_IP}', 'HOLDTIME': '${HOLDTIME}', 'PEER_PORT': '${BGP_TOOL_PORT}','PEER_ROLE': 'ibgp', 'INITIATE': 'false'}
  84     ConfigViaRestconf.Put_Xml_Template_Folder_Config_Via_Restconf    ${BGP_VARIABLES_FOLDER}${/}ibgp_peers    ${template_as_string}
  85     ${template_as_string}=    BuiltIn.Set_Variable    {'NAME': 'example-ebgp-peer1', 'IP': '${eBGP_PEER1_IP}', 'HOLDTIME': '${HOLDTIME}', 'PEER_PORT': '${BGP_TOOL_PORT}', 'PEER_ROLE': 'ebgp', 'AS_NUMBER': '${eBGP_PEER1_AS}', 'INITIATE': 'false'}
  86     ConfigViaRestconf.Put_Xml_Template_Folder_Config_Via_Restconf    ${BGP_VARIABLES_FOLDER}${/}ebgp_peers    ${template_as_string}
  87     ${template_as_string}=    BuiltIn.Set_Variable    {'NAME': 'example-ebgp-peer2', 'IP': '${eBGP_PEER2_IP}', 'HOLDTIME': '${HOLDTIME}', 'PEER_PORT': '${BGP_TOOL_PORT}','PEER_ROLE': 'ebgp', 'AS_NUMBER': '${eBGP_PEER2_AS}', 'INITIATE': 'false'}
  88     ConfigViaRestconf.Put_Xml_Template_Folder_Config_Via_Restconf    ${BGP_VARIABLES_FOLDER}${/}ebgp_peers    ${template_as_string}
  89     ${template_as_string}=    BuiltIn.Set_Variable    {'NAME': 'example-ibgp-peer1'}
  90     ${result}=    ConfigViaRestconf.Get_Xml_Template_Folder_Config_Via_Restconf    ${BGP_VARIABLES_FOLDER}${/}ibgp_peers    ${template_as_string}
  91     BuiltIn.Log    ${result}
  92     ${template_as_string}=    BuiltIn.Set_Variable    {'NAME': 'example-ebgp-peer1'}
  93     ${result}=    ConfigViaRestconf.Get_Xml_Template_Folder_Config_Via_Restconf    ${BGP_VARIABLES_FOLDER}${/}ebgp_peers    ${template_as_string}
  94     BuiltIn.Log    ${result}
  95     ${template_as_string}=    BuiltIn.Set_Variable    {'NAME': 'example-ebgp-peer2'}
  96     ${result}=    ConfigViaRestconf.Get_Xml_Template_Folder_Config_Via_Restconf    ${BGP_VARIABLES_FOLDER}${/}ebgp_peers    ${template_as_string}
  97     BuiltIn.Log    ${result}
  98
  99 Connect_iBGP_Peer1
 100     [Documentation]    Connect BGP peer
 101     [Tags]    critical
 102     SSHLibrary.Switch Connection    ibgp_peer1_console
 103     Start_Console_Tool    ${iBGP_PEER1_COMMAND}    ${iBGP_PEER1_OPTIONS}
 104     Read_And_Fail_If_Prompt_Is_Seen
 105     Check_Example_IPv4_Topology_Does_Not_Contain    prefix
 106
 107 Connect_eBGP_Peer1
 108     [Documentation]    Connect BGP peer
 109     [Tags]    critical
 110     SSHLibrary.Switch Connection    ebgp_peer1_console
 111     Start_Console_Tool    ${eBGP_PEER1_COMMAND}    ${eBGP_PEER1_OPTIONS}
 112     Read_And_Fail_If_Prompt_Is_Seen
 113
 114 Check_IPv4_Topology_For_First_Path
 115     [Documentation]    The IPv4 topology shall contain the route announced by the first eBGP
 116     BuiltIn.Wait_Until_Keyword_Succeeds    ${DEFAULT_TOPOLOGY_CHECK_TIMEOUT}    ${DEFAULT_TOPOLOGY_CHECK_PERIOD}    Check_Example_IPv4_Topology_Content    "node-id":"${eBGP_PEER1_NEXT_HOP}"
 117     Check_Example_IPv4_Topology_Content    "prefix":"${eBGP_PEER1_FIRST_PREFIX_IP}/${PREFIX_LEN}"
 118
 119 iBGP_Check_Log_For_Introduced_Prefixes
 120     [Documentation]    Check incomming updates for introduced routes
 121     [Tags]    critical
 122     SSHLibrary.Switch Connection    ibgp_peer1_console
 123     ${total_prefix_count}=    BuiltIn.Evaluate    ${eBGP_PEER1_PREFIX_COUNT}
 124     BuiltIn.Wait_Until_Keyword_Succeeds    ${DEFAULT_LOG_CHECK_TIMEOUT}    ${DEFAULT_LOG_CHECK_PERIOD}    Check_File_For_Word_Count    ${iBGP_PEER1_LOG_FILE}    nlri_prefix_received:    ${total_prefix_count}
 125     ${count}=    Count_Key_Value_Pairs    ${iBGP_PEER1_LOG_FILE}    Network Address of Next Hop    ${eBGP_PEER1_NEXT_HOP}
 126     BuiltIn.Should_Be_Equal_As_Integers    ${count}    ${eBGP_PEER1_PREFIX_COUNT}
 127     ${count}=    Count_Key_Value_Pairs    ${iBGP_PEER1_LOG_FILE}    Network Address of Next Hop    ${eBGP_PEER2_NEXT_HOP}
 128     BuiltIn.Should_Be_Equal_As_Integers    ${count}    0
 129
 130 Connect_eBGP_Peer2
 131     [Documentation]    Connect BGP peer and check empty topology
 132     [Tags]    critical
 133     SSHLibrary.Switch Connection    ebgp_peer2_console
 134     Start_Console_Tool    ${eBGP_PEER2_COMMAND}    ${eBGP_PEER2_OPTIONS}
 135     Read_And_Fail_If_Prompt_Is_Seen
 136
 137 Disconnect_eBGP_Peer1
 138     [Documentation]    Stop BGP peer, log topology and store logs
 139     [Tags]    critical
 140     SSHLibrary.Switch Connection    ebgp_peer1_console
 141     Stop_Console_Tool
 142     Store_File_To_Workspace    ${eBGP_PEER1_LOG_FILE}    ${eBGP_PEER1_LOG_FILE}
 143
 144 Check_IPv4_Topology_For_Second_Path
 145     [Documentation]    The IPv4 topology shall contain the route announced by the second eBGP now
 146     BuiltIn.Wait_Until_Keyword_Succeeds    ${DEFAULT_TOPOLOGY_CHECK_TIMEOUT}    ${DEFAULT_TOPOLOGY_CHECK_PERIOD}    Check_Example_IPv4_Topology_Content    "node-id":"${eBGP_PEER2_NEXT_HOP}"
 147     Check_Example_IPv4_Topology_Content    "prefix":"${eBGP_PEER2_FIRST_PREFIX_IP}/${PREFIX_LEN}"
 148
 149 iBGP_Check_Log_For_Updated_Prefixes
 150     [Documentation]    Check incomming updates for updated routes
 151     [Tags]    critical
 152     SSHLibrary.Switch Connection    ibgp_peer1_console
 153     ${total_prefix_count}=    BuiltIn.Evaluate    ${eBGP_PEER1_PREFIX_COUNT} + ${eBGP_PEER2_PREFIX_COUNT}
 154     BuiltIn.Wait_Until_Keyword_Succeeds    ${DEFAULT_LOG_CHECK_TIMEOUT}    ${DEFAULT_LOG_CHECK_PERIOD}    Check_File_For_Word_Count    ${iBGP_PEER1_LOG_FILE}    nlri_prefix_received:    ${total_prefix_count}
 155     ${count}=    Count_Key_Value_Pairs    ${iBGP_PEER1_LOG_FILE}    Network Address of Next Hop    ${eBGP_PEER1_NEXT_HOP}
 156     BuiltIn.Should_Be_Equal_As_Integers    ${count}    ${eBGP_PEER1_PREFIX_COUNT}
 157     ${count}=    Count_Key_Value_Pairs    ${iBGP_PEER1_LOG_FILE}    Network Address of Next Hop    ${eBGP_PEER2_NEXT_HOP}
 158     BuiltIn.Should_Be_Equal_As_Integers    ${count}    ${eBGP_PEER2_PREFIX_COUNT}
 159     [Teardown]    Report_Failure_Due_To_Bug    4834
 160
 161 Disconnect_eBGP_Peer2
 162     [Documentation]    Stop BGP peer, store logs and wait for empty topology
 163     [Tags]    critical
 164     SSHLibrary.Switch Connection    ebgp_peer2_console
 165     Stop_Console_Tool
 166     Store_File_To_Workspace    ${eBGP_PEER2_LOG_FILE}    ${eBGP_PEER2_LOG_FILE}
 167
 168 Check_For_Empty_IPv4_Topology
 169     [Documentation]    The IPv4 topology shall be empty
 170     BuiltIn.Wait_Until_Keyword_Succeeds    ${DEFAULT_TOPOLOGY_CHECK_TIMEOUT}    ${DEFAULT_TOPOLOGY_CHECK_PERIOD}    Check_Example_IPv4_Topology_Does_Not_Contain    prefix
 171     [Teardown]    Report_Failure_Due_To_Bug    4835
 172
 173 iBGP_Check_Log_For_Withdrawn_Prefixes
 174     [Documentation]    Check incomming updates for withdrawn routes
 175     [Tags]    critical
 176     SSHLibrary.Switch Connection    ibgp_peer1_console
 177     ${prefixes_to_be_removed}=    BuiltIn.Evaluate    max(${eBGP_PEER1_PREFIX_COUNT}, ${eBGP_PEER2_PREFIX_COUNT})
 178     BuiltIn.Wait_Until_Keyword_Succeeds    ${DEFAULT_LOG_CHECK_TIMEOUT}    ${DEFAULT_LOG_CHECK_PERIOD}    Check_File_For_Word_Count    ${iBGP_PEER1_LOG_FILE}    withdrawn_prefix_received:    ${prefixes_to_be_removed}
 179     [Teardown]    Report_Failure_Due_To_Bug    4835
 180
 181 Disconnect_iBGP_Peer1
 182     [Documentation]    Stop BGP peer, log topology and store logs
 183     [Tags]    critical
 184     SSHLibrary.Switch Connection    ibgp_peer1_console
 185     Stop_Console_Tool
 186     Store_File_To_Workspace    ${iBGP_PEER1_LOG_FILE}    ${iBGP_PEER1_LOG_FILE}
 187
 188 Delete_BGP_Peers_Configuration
 189     [Documentation]    Delete all previously configured BGP peers.
 190     [Tags]    critical
 191     ${template_as_string}=    BuiltIn.Set_Variable    {'NAME': 'example-ibgp-peer1'}
 192     ConfigViaRestconf.Delete_Xml_Template_Folder_Config_Via_Restconf    ${BGP_VARIABLES_FOLDER}${/}ibgp_peers    ${template_as_string}
 193     ${template_as_string}=    BuiltIn.Set_Variable    {'NAME': 'example-ebgp-peer1'}
 194     ConfigViaRestconf.Delete_Xml_Template_Folder_Config_Via_Restconf    ${BGP_VARIABLES_FOLDER}${/}ebgp_peers    ${template_as_string}
 195     ${template_as_string}=    BuiltIn.Set_Variable    {'NAME': 'example-ebgp-peer2'}
 196     ConfigViaRestconf.Delete_Xml_Template_Folder_Config_Via_Restconf    ${BGP_VARIABLES_FOLDER}${/}ebgp_peers    ${template_as_string}
 197
 198 *** Keywords ***
 199 Setup_Everything
 200     [Documentation]    SSH-login to mininet machine, create HTTP session,
 201     ...    prepare directories for responses, put Python tool to mininet machine, setup imported resources.
 202     SetupUtils.Setup_Utils_For_Setup_And_Teardown
 203     SSHLibrary.Set_Default_Configuration    prompt=${ODL_SYSTEM_PROMPT}
 204     SSHLibrary.Open_Connection    ${ODL_SYSTEM_IP}    alias=ibgp_peer1_console
 205     Utils.Flexible_Controller_Login
 206     SSHLibrary.Open_Connection    ${ODL_SYSTEM_IP}    alias=ebgp_peer1_console
 207     Utils.Flexible_Controller_Login
 208     SSHLibrary.Open_Connection    ${ODL_SYSTEM_IP}    alias=ebgp_peer2_console
 209     Utils.Flexible_Controller_Login
 210     SSHKeywords.Require_Python
 211     SSHKeywords.Assure_Library_Ipaddr    target_dir=.
 212     SSHLibrary.Put_File    ${CURDIR}/../../../../tools/fastbgp/play.py
 213     RequestsLibrary.Create_Session    operational    http://${ODL_SYSTEM_IP}:${RESTCONFPORT}${OPERATIONAL_TOPO_API}    auth=${AUTH}
 214     ConfigViaRestconf.Setup_Config_Via_Restconf
 215     KarafKeywords.Execute_Controller_Karaf_Command_On_Background    log:set ${CONTROLLER_LOG_LEVEL}
 216     KarafKeywords.Execute_Controller_Karaf_Command_On_Background    log:set ${CONTROLLER_BGP_LOG_LEVEL} org.opendaylight.bgpcep
 217     KarafKeywords.Execute_Controller_Karaf_Command_On_Background    log:set ${CONTROLLER_BGP_LOG_LEVEL} org.opendaylight.protocol
 218
 219 Teardown_Everything
 220     [Documentation]    Create and Log the diff between expected and actual responses, make sure Python tool was killed.
 221     ...    Tear down imported Resources.
 222     KillPythonTool.Search_And_Kill_Remote_Python    'play\.py'
 223     ConfigViaRestconf.Teardown_Config_Via_Restconf
 224     RequestsLibrary.Delete_All_Sessions
 225     SSHLibrary.Close_All_Connections
 226
 227 Read_Text_Before_Prompt
 228     [Documentation]    Log text gathered by SSHLibrary.Read_Until_Prompt.
 229     ...    This needs to be a separate keyword just because how Read_And_Fail_If_Prompt_Is_Seen is implemented.
 230     ${text}=    SSHLibrary.Read_Until_Prompt
 231     BuiltIn.Log    ${text}
 232
 233 Check_Example_IPv4_Topology_Content
 234     [Arguments]    ${string_to_check}=${EMPTY}
 235     [Documentation]    Check the example-ipv4-topology content for string
 236     ${response}=    RequestsLibrary.Get Request    operational    topology/example-ipv4-topology
 237     BuiltIn.Log    ${response.status_code}
 238     BuiltIn.Log    ${response.text}
 239     BuiltIn.Should_Contain    ${response.text}    ${string_to_check}
 240
 241 Check_Example_IPv4_Topology_Does_Not_Contain
 242     [Arguments]    ${string_to_check}
 243     [Documentation]    Check the example-ipv4-topology does not contain the string
 244     ${response}=    RequestsLibrary.Get Request    operational    topology/example-ipv4-topology
 245     BuiltIn.Log    ${response.status_code}
 246     BuiltIn.Log    ${response.text}
 247     BuiltIn.Should_Not_Contain    ${response.text}    ${string_to_check}
 248
 249 Store_File_To_Workspace
 250     [Arguments]    ${source_file_name}    ${target_file_name}
 251     [Documentation]    Store the ${source_file_name} to the workspace as ${target_file_name}.
 252     ${output_log}=    SSHLibrary.Execute_Command    cat ${source_file_name}
 253     BuiltIn.Log    ${output_log}
 254     Create File    ${target_file_name}    ${output_log}