csit/suites/controller/singleton_service/global_rpc_isolate.robot

   1 *** Settings ***
   2 Documentation     Controller functional HA testing of global singleton rpcs.
   3 ...
   4 ...               Copyright (c) 2017 Cisco Systems, Inc. and others. All rights reserved.
   5 ...
   6 ...               This program and the accompanying materials are made available under the
   7 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   8 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
   9 Suite Setup       Setup_Suite
  10 Suite Teardown    SSHLibrary.Close_All_Connections
  11 Test Setup        SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
  12 Test Teardown     SetupUtils.Teardown_Test_Show_Bugs_If_Test_Failed
  13 Default Tags      critical
  14 Resource          ${CURDIR}/../../../libraries/ClusterManagement.robot
  15 Resource          ${CURDIR}/../../../libraries/KarafKeywords.robot
  16 Resource          ${CURDIR}/../../../libraries/SetupUtils.robot
  17 Resource          ${CURDIR}/../../../libraries/ShardStability.robot
  18 Resource          ${CURDIR}/../../../libraries/TemplatedRequests.robot
  19 Resource          ${CURDIR}/../../../variables/Variables.robot
  20 Resource          ${CURDIR}/../../../libraries/WaitForFailure.robot
  21
  22 *** Variables ***
  23 ${RPC_URL}        /restconf/operations/basic-rpc-test:basic-global
  24 &{EMPTY_DICT}
  25 ${SERVICE}        Basic-rpc-test']
  26 ${TEST_LOG_LEVEL}    info
  27 @{TEST_LOG_COMPONENTS}    org.opendaylight.controller.remote.rpc
  28 ${EOS_URL}        /restconf/operational/entity-owners:entity-owners
  29 ${RPC_STATUS_ISOLATED}    501
  30
  31 *** Test Cases ***
  32 Get_Basic_Rpc_Test_Owner
  33     [Documentation]    Find a service owner and successors.
  34     Get_Present_Brt_Owner_And_Successors    1    store=${True}
  35
  36 Rpc_Before_Isolation_On_Owner
  37     [Documentation]    Run rpc on the service owner.
  38     Run_Rpc    ${brt_owner}
  39
  40 Rpc_Before_Isolation_On_Successors
  41     [Documentation]    Run rpc on non owher cluster nodes.
  42     FOR    ${idx}    IN    @{brt_successors}
  43         Run_Rpc    ${idx}
  44     END
  45
  46 Isolate_Current_Owner_Member
  47     [Documentation]    Isolating cluster node which is the owner.
  48     ClusterManagement.Isolate_Member_From_List_Or_All    ${brt_owner}
  49     BuiltIn.Set Suite variable    ${old_brt_owner}    ${brt_owner}
  50     BuiltIn.Set Suite variable    ${old_brt_successors}    ${brt_successors}
  51
  52 Verify_New_Basic_Rpc_Test_Owner_Elected
  53     [Documentation]    Verify new owner of the service is elected.
  54     ${idx}=    Collections.Get_From_List    ${old_brt_successors}    0
  55     BuiltIn.Wait_Until_Keyword_Succeeds    70s    10s    ShardStability.Shards_Stability_Get_Details    ${DEFAULT_SHARD_LIST}    member_index_list=${old_brt_successors}
  56     BuiltIn.Wait_Until_Keyword_Succeeds    60s    5s    Verify_Owner_Elected    ${True}    ${old_brt_owner}    ${idx}
  57     Get_Present_Brt_Owner_And_Successors    ${idx}    store=${True}
  58
  59 Rpc_On_Isolated_Node
  60     [Documentation]    Run rpc on isolated cluster node.
  61     ${session} =    Resolve_Http_Session_For_Member    member_index=${old_brt_owner}
  62     BuiltIn.Run_Keyword_And_Ignore_Error    Get_And_Log_EOS_Output_To_Karaf_Log    ${session}
  63     BuiltIn.Pass_Execution    Rpc on isolated node may work for some time(bug 8207), then will fail (bug 8214)
  64     ${resp} =    RequestsLibrary.Post Request    ${session}    ${RPC_URL}    data=${EMPTY}
  65     BuiltIn.Should_Be_Equal_As_Numbers    ${resp.status_code}    ${RPC_STATUS_ISOLATED}
  66
  67 Rpc_On_Non_Isolated_Cluster_Nodes
  68     [Documentation]    Run rpc on remained cluster nodes.
  69     FOR    ${idx}    IN    @{old_brt_successors}
  70         BuiltIn.Wait_Until_Keyword_Succeeds    60s    5s    Run_Rpc    ${idx}
  71     END
  72
  73 Rejoin_Isolated_Member
  74     [Documentation]    Rejoin isolated node
  75     ClusterManagement.Rejoin_Member_From_List_Or_All    ${old_brt_owner}
  76     BuiltIn.Wait_Until_Keyword_Succeeds    70s    10s    ShardStability.Shards_Stability_Get_Details    ${DEFAULT_SHARD_LIST}
  77
  78 Rpc_After_Rejoin_On_New_Owner
  79     [Documentation]    Run rpc on the new service owner node.
  80     Run_Rpc    ${brt_owner}
  81
  82 Rpc_After_Rejoin_On_Old_Owner
  83     [Documentation]    Run rpc on rejoined cluster node.
  84     Run_Rpc    ${old_brt_owner}
  85
  86 Rpc_After_Rejoin_On_All
  87     [Documentation]    Run rpc again on all nodes.
  88     Run_Rpc    ${brt_owner}
  89     FOR    ${idx}    IN    @{brt_successors}
  90         Run_Rpc    ${idx}
  91     END
  92
  93 *** Keywords ***
  94 Setup_Suite
  95     [Documentation]    FIXME: Add a documentation.
  96     SetupUtils.Setup_Utils_For_Setup_And_Teardown    http_timeout=30
  97     SetupUtils.Setup_Logging_For_Debug_Purposes_On_List_Or_All    ${TEST_LOG_LEVEL}    ${TEST_LOG_COMPONENTS}
  98
  99 Run_Rpc
 100     [Arguments]    ${node_idx}
 101     [Documentation]    Run rpc and log the entity ownership service details to karaf log.
 102     ...    Logging the details was a developer's request during the implementation to improve debugging.
 103     ${session} =    Resolve_Http_Session_For_Member    member_index=${node_idx}
 104     Get_And_Log_EOS_Output_To_Karaf_Log    ${session}
 105     TemplatedRequests.Post_To_Uri    ${RPC_URL}    ${EMPTY}    ${HEADERS_XML}    ${ACCEPT_XML}    session=${session}
 106
 107 Verify_Owner_Elected
 108     [Arguments]    ${new_elected}    ${old_owner}    ${node_to_ask}
 109     [Documentation]    Verify new owner was elected or remained the same.
 110     ${owner}    ${successors}=    Get_Present_Brt_Owner_And_Successors    ${node_to_ask}
 111     BuiltIn.Run_Keyword_If    ${new_elected}    BuiltIn.Should_Not_Be_Equal_As_Numbers    ${old_owner}    ${owner}
 112     BuiltIn.Run_Keyword_Unless    ${new_elected}    BuiltIn.Should_Be_Equal_As_numbers    ${old_owner}    ${owner}
 113
 114 Get_Present_Brt_Owner_And_Successors
 115     [Arguments]    ${node_to_ask}    ${store}=${False}
 116     [Documentation]    Find a basic rpc test service owner and successors and store them if indicated.
 117     ${brt_owner}    ${brt_successors}=    ClusterManagement.Get_Owner_And_Successors_For_Device    ${SERVICE}    org.opendaylight.mdsal.ServiceEntityType    ${node_to_ask}
 118     BuiltIn.Run_Keyword_If    ${store}    BuiltIn.Set_Suite_Variable    ${brt_owner}    ${brt_owner}
 119     BuiltIn.Run_Keyword_If    ${store}    BuiltIn.Set_Suite_Variable    ${brt_successors}    ${brt_successors}
 120     BuiltIn.Return_From_Keyword    ${brt_owner}    ${brt_successors}
 121
 122 Get_And_Log_EOS_Output_To_Karaf_Log
 123     [Arguments]    ${session}
 124     [Documentation]    Log the entity ownership service details to karaf.log
 125     ${out} =    TemplatedRequests.Get_From_Uri    ${EOS_URL}    session=${session}
 126     KarafKeywords.Log_Message_To_Controller_Karaf    EOS rest resp: ${out}