csit/suites/controller/singleton_service/global_rpc_kill.robot

   1 *** Settings ***
   2 Documentation     Controller functional HA testing of global singleton rpcs.
   3 ...
   4 ...               Copyright (c) 2017 Cisco Systems, Inc. and others. All rights reserved.
   5 ...
   6 ...               This program and the accompanying materials are made available under the
   7 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   8 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
   9 Suite Setup       Setup_Suite
  10 Suite Teardown    SSHLibrary.Close_All_Connections
  11 Test Setup        SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
  12 Test Teardown     SetupUtils.Teardown_Test_Show_Bugs_If_Test_Failed
  13 Default Tags      critical
  14 Resource          ${CURDIR}/../../../libraries/ClusterManagement.robot
  15 Resource          ${CURDIR}/../../../libraries/KarafKeywords.robot
  16 Resource          ${CURDIR}/../../../libraries/ShardStability.robot
  17 Resource          ${CURDIR}/../../../libraries/SetupUtils.robot
  18 Resource          ${CURDIR}/../../../libraries/TemplatedRequests.robot
  19 Resource          ${CURDIR}/../../../libraries/WaitForFailure.robot
  20 Resource          ${CURDIR}/../../../variables/Variables.robot
  21
  22 *** Variables ***
  23 ${RPC_URL}        /restconf/operations/basic-rpc-test:basic-global
  24 &{EMPTY_DICT}
  25 ${SERVICE}        Basic-rpc-test']
  26 ${TEST_LOG_LEVEL}    info
  27 @{TEST_LOG_COMPONENTS}    org.opendaylight.controller.remote.rpc
  28 ${EOS_URL}        /restconf/operational/entity-owners:entity-owners
  29
  30 *** Test Cases ***
  31 Get_Basic_Rpc_Test_Owner
  32     [Documentation]    Find a service owner and successors.
  33     Get_Present_Brt_Owner_And_Successors    1    store=${True}
  34
  35 Rpc_Before_Stopping_On_Owner
  36     [Documentation]    Run rpc on the service owner.
  37     Run_Rpc    ${brt_owner}
  38
  39 Rpc_Before_Stop_On_Successors
  40     [Documentation]    Run rpc on non owher cluster nodes.
  41     FOR    ${idx}    IN    @{brt_successors}
  42         Run_Rpc    ${idx}
  43     END
  44
  45 Stop_Current_Owner_Member
  46     [Documentation]    Stop cluster node which is the owner.
  47     ClusterManagement.Stop_Single_Member    ${brt_owner}
  48     BuiltIn.Set Suite variable    ${old_brt_owner}    ${brt_owner}
  49     BuiltIn.Set Suite variable    ${old_brt_successors}    ${brt_successors}
  50
  51 Verify_New_Basic_Rpc_Test_Owner_Elected
  52     [Documentation]    Verify new owner of the service is elected.
  53     ${idx}=    Collections.Get_From_List    ${old_brt_successors}    0
  54     BuiltIn.Wait_Until_Keyword_Succeeds    60s    5s    Verify_Owner_Elected    ${True}    ${old_brt_owner}    ${idx}
  55     Get_Present_Brt_Owner_And_Successors    ${idx}    store=${True}
  56
  57 Rpc_On_Remained_Cluster_Nodes
  58     [Documentation]    Run rpc on remained cluster nodes.
  59     FOR    ${idx}    IN    @{old_brt_successors}
  60         BuiltIn.Wait_Until_Keyword_Succeeds    60s    5s    Run_Rpc    ${idx}
  61     END
  62
  63 Restart_Stopped_Member
  64     [Documentation]    Restart stopped node
  65     ClusterManagement.Start_Single_Member    ${old_brt_owner}
  66
  67 Verify_New_Owner_Remained_After_Rejoin
  68     [Documentation]    Verify no owner change happened after rejoin.
  69     WaitForFailure.Verify_Keyword_Does_Not_Fail_Within_Timeout    15s    2s    Verify_Owner_Elected    ${False}    ${brt_owner}    ${brt_owner}
  70     BuiltIn.Wait_Until_Keyword_Succeeds    70s    10s    ShardStability.Shards_Stability_Get_Details    ${DEFAULT_SHARD_LIST}
  71
  72 Rpc_After_Rejoin_On_New_Owner
  73     [Documentation]    Run rpc on the new service owner node.
  74     Run_Rpc    ${brt_owner}
  75
  76 Rpc_After_Rejoin_On_Old_Owner
  77     [Documentation]    Run rpc on rejoined cluster node.
  78     Run_Rpc    ${old_brt_owner}
  79
  80 Rpc_After_Rejoin_On_All
  81     [Documentation]    Run rpc again on all nodes.
  82     Run_Rpc    ${brt_owner}
  83     FOR    ${idx}    IN    @{brt_successors}
  84         Run_Rpc    ${idx}
  85     END
  86
  87 *** Keywords ***
  88 Setup_Suite
  89     [Documentation]    FIXME: Add a documentation.
  90     SetupUtils.Setup_Utils_For_Setup_And_Teardown    http_timeout=30
  91     SetupUtils.Setup_Logging_For_Debug_Purposes_On_List_Or_All    ${TEST_LOG_LEVEL}    ${TEST_LOG_COMPONENTS}
  92
  93 Run_Rpc
  94     [Arguments]    ${node_idx}
  95     [Documentation]    Run rpc and log the entity ownership service details to karaf log.
  96     ...    Logging the details was a developer's request during the implementation to improve debugging.
  97     ${session} =    Resolve_Http_Session_For_Member    member_index=${node_idx}
  98     ${out} =    TemplatedRequests.Get_From_Uri    ${EOS_URL}    session=${session}
  99     KarafKeywords.Log_Message_To_Controller_Karaf    EOS rest resp: ${out}
 100     TemplatedRequests.Post_To_Uri    ${RPC_URL}    ${EMPTY}    ${HEADERS_XML}    ${ACCEPT_XML}    session=${session}
 101
 102 Verify_Owner_Elected
 103     [Arguments]    ${new_elected}    ${old_owner}    ${node_to_ask}
 104     [Documentation]    Verify new owner was elected or remained the same.
 105     ${owner}    ${successors}=    Get_Present_Brt_Owner_And_Successors    ${node_to_ask}
 106     BuiltIn.Run_Keyword_If    ${new_elected}    BuiltIn.Should_Not_Be_Equal_As_Numbers    ${old_owner}    ${owner}
 107     BuiltIn.Run_Keyword_Unless    ${new_elected}    BuiltIn.Should_Be_Equal_As_numbers    ${old_owner}    ${owner}
 108
 109 Get_Present_Brt_Owner_And_Successors
 110     [Arguments]    ${node_to_ask}    ${store}=${False}
 111     [Documentation]    Find a basic rpc test service owner and successors and store them if indicated.
 112     ${brt_owner}    ${brt_successors}=    ClusterManagement.Get_Owner_And_Successors_For_Device    ${SERVICE}    org.opendaylight.mdsal.ServiceEntityType    ${node_to_ask}
 113     BuiltIn.Run_Keyword_If    ${store}    BuiltIn.Set_Suite_Variable    ${brt_owner}    ${brt_owner}
 114     BuiltIn.Run_Keyword_If    ${store}    BuiltIn.Set_Suite_Variable    ${brt_successors}    ${brt_successors}
 115     BuiltIn.Return_From_Keyword    ${brt_owner}    ${brt_successors}