csit/suites/distribution/karaf_sequence_install.robot

   1 *** Settings ***
   2 Documentation     Bug 4462 test suite.
   3 ...
   4 ...               Copyright (c) 2016-2017 Cisco Systems, Inc. and others. All rights reserved.
   5 ...
   6 ...               This program and the accompanying materials are made available under the
   7 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   8 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
   9 ...
  10 ...
  11 ...               Try to detect whether Karaf hangs when trying to install
  12 ...               list of features one by one. Default list is odl-integration-compatible-with-all.
  13 Suite Setup       SetupUtils.Setup_Utils_For_Setup_And_Teardown
  14 Default Tags      critical    distribution    features
  15 Resource          ${CURDIR}/../../libraries/distribution/StreamDistro.robot
  16 Resource          ${CURDIR}/../../libraries/ClusterManagement.robot
  17 Resource          ${CURDIR}/../../libraries/SetupUtils.robot
  18 Resource          ${CURDIR}/../../libraries/SSHKeywords.robot
  19 Resource          ${CURDIR}/../../variables/Variables.robot
  20 Library           XML
  21 Library           SSHLibrary
  22
  23 *** Variables ***
  24 ${FEATURES_LIST_NAME}    odl-integration-compatible-with-all
  25 ${FEATURE_INSTALL_TIMEOUT}    10m
  26
  27 *** Test Cases ***
  28 Install_Features_One_By_One
  29     [Documentation]    Try to install current list of features and check whether Karaf hangs on it or not (bug 4462).
  30     SSHKeywords.Open_Connection_To_ODL_System
  31     ${filename_prefix} =    StreamDistro.Compose_Zip_Filename_Prefix
  32     ${actual_version} =    BuiltIn.Evaluate    '''${BUNDLEFOLDER}'''[len("${filename_prefix}-"):]
  33     ${features_test} =    StreamDistro.Compose_Test_Feature_Repo_Name
  34     SSHLibrary.Get_File    ${WORKSPACE}/${BUNDLEFOLDER}/system/org/opendaylight/integration/${features_test}/${actual_version}/${features_test}-${actual_version}-features.xml    features.xml
  35     @{features} =    XML.Get_Elements_Texts    features.xml    .feature[@name="${FEATURES_LIST_NAME}"]/feature
  36     Collections.Log_List    ${features}
  37     KarafKeywords.Open_Controller_Karaf_Console_With_Timeout    ${1}    ${FEATURE_INSTALL_TIMEOUT}
  38     FOR    ${feature}    IN    @{features}
  39         KarafKeywords.Log_Message_To_Controller_Karaf    Installing feature: ${feature}
  40         KarafKeywords.Install_a_Feature_Using_Active_Connection    ${feature}
  41     END