csit/suites/groupbasedpolicy/GBPSFC/6-node/__init__.robot

   1 *** Settings ***
   2 Documentation     Setup/teardown for GBPSFC 6-node topology
   3 Suite Setup       Setup Everything
   4 Suite Teardown    Teardown Everything
   5 Library           SSHLibrary
   6 Library           RequestsLibrary
   7 Resource          ../../../../libraries/Utils.robot
   8 Resource          ../../../../libraries/GBP/ConnUtils.robot
   9 Resource          Variables.robot
  10 Variables         ../../../../variables/Variables.py
  11
  12 *** Variables ***
  13 ${timeout}        10s
  14
  15 *** Keywords ***
  16 Setup Everything
  17     [Documentation]    Initial setup of remote VM. Copying of scripts and installation python packages to virtual env if missing.
  18     Create Session    session    http://${ODL}:${RESTCONFPORT}    auth=${AUTH}    headers=${HEADERS}
  19     Wait Until Keyword Succeeds    10x    30 s    Get Data From URI    session    ${OF_OVERLAY_CONFIG_PATH}    headers=${headers}
  20     Delete All Sessions
  21     FOR    ${GBPSFC}    IN    @{GBPSFCs}
  22         ConnUtils.Connect and Login    ${GBPSFC}    timeout=${timeout}
  23         # TODO if something extra needs to be installed, please do it in virt-env
  24         ${stderr}    SSHLibrary.Execute Command    virtualenv --system-site-packages ${VE_DIR}    return_stdout=False    return_stderr=True    return_rc=False
  25         Should Be Empty    ${stderr}
  26         SSHLibrary.Put File    ${CURDIR}/../../common_scripts/*    ${VM_HOME_FOLDER}${/}${VM_SCRIPTS_FOLDER}/    mode=0755
  27         ${stdout}    ${stderr}    ${rc}    ConnUtils.Execute in VE    pip freeze | grep ipaddr -q || pip install ipaddr    timeout=${timeout}
  28         Should Be Equal As Numbers    ${rc}    0
  29         SSHLibrary.Close Connection
  30     END
  31     Set ODL Variables
  32
  33 Teardown Everything
  34     [Documentation]    Clearing remote VM - removing copied scripts.
  35     Log    stop_suite_in_6_node
  36     FOR    ${GBPSFC}    IN    @{GBPSFCs}
  37         ConnUtils.Connect and Login    ${GBPSFC}    timeout=${timeout}
  38         SSHLibrary.Execute Command    sudo rm -rf ${VM_HOME_FOLDER}${/}${VM_SCRIPTS_FOLDER}
  39         SSHLibrary.Close Connection
  40     END