csit/suites/netconf/CRUD/CRUD.robot

   1 *** Settings ***
   2 Documentation     netconf-connector CRUD test suite.
   3 ...
   4 ...               Copyright (c) 2015 Cisco Systems, Inc. and others. All rights reserved.
   5 ...
   6 ...               This program and the accompanying materials are made available under the
   7 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   8 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
   9 ...
  10 ...
  11 ...               Perform basic operations (Create, Read, Update and Delete or CRUD) on device
  12 ...               data mounted onto a netconf connector and see if they work.
  13 ...
  14 ...               FIXME: Replace the BuiltIn.Should_[Not_]Contain instances in the test cases
  15 ...               that check the car list related data with calls to keywords of a Resource
  16 ...               aimed at getting interesting pieces of data from the XML files and checking
  17 ...               them against expected data sets. See MDSAL/northbound.robot suite for
  18 ...               additional information.
  19 Suite Setup       Setup_Everything
  20 Suite Teardown    Teardown_Everything
  21 Test Setup        SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
  22 Library           Collections
  23 Library           RequestsLibrary
  24 Library           OperatingSystem
  25 Library           String
  26 Library           SSHLibrary    timeout=10s
  27 Resource          ${CURDIR}/../../../libraries/FailFast.robot
  28 Resource          ${CURDIR}/../../../libraries/KarafKeywords.robot
  29 Resource          ${CURDIR}/../../../libraries/NetconfKeywords.robot
  30 Resource          ${CURDIR}/../../../libraries/NetconfViaRestconf.robot
  31 Resource          ${CURDIR}/../../../libraries/SetupUtils.robot
  32 Resource          ${CURDIR}/../../../libraries/Utils.robot
  33 Variables         ${CURDIR}/../../../variables/Variables.py
  34
  35 *** Variables ***
  36 ${directory_with_template_folders}    ${CURDIR}/../../../variables/netconf/CRUD
  37 ${device_name}    netconf-test-device
  38
  39 *** Test Cases ***
  40 Start_Testtool
  41     [Documentation]    Deploy and start test tool, then wait for all its devices to become online.
  42     NetconfKeywords.Install_And_Start_Testtool    device-count=1    schemas=${CURDIR}/../../../variables/netconf/CRUD/schemas
  43
  44 Check_Device_Is_Not_Configured_At_Beginning
  45     [Documentation]    Sanity check making sure our device is not there. Fail if found.
  46     [Tags]    critical
  47     NetconfKeywords.Check_Device_Has_No_Netconf_Connector    ${device_name}
  48
  49 Configure_Device_On_Netconf
  50     [Documentation]    Make request to configure a testtool device on Netconf connector.
  51     [Tags]    critical
  52     NetconfKeywords.Configure_Device_In_Netconf    ${device_name}
  53
  54 Check_ODL_Has_Netconf_Connector_For_Device
  55     [Documentation]    Get the list of configured devices and search for our device there. Fail if not found.
  56     [Tags]    critical
  57     ${count}    NetconfKeywords.Count_Netconf_Connectors_For_Device    ${device_name}
  58     Builtin.Should_Be_Equal_As_Strings    ${count}    1
  59
  60 Wait_For_Device_To_Become_Connected
  61     [Documentation]    Wait until the device becomes available through Netconf.
  62     NetconfKeywords.Wait_Device_Connected    ${device_name}
  63
  64 Check_Device_Data_Is_Empty
  65     [Documentation]    Get the device data and make sure it is empty.
  66     Check_Config_Data    <data xmlns="${ODL_NETCONF_NAMESPACE}"></data>
  67
  68 Create_Device_Data_Label_Via_Xml
  69     [Documentation]    Send a sample test data label into the device and check that the request went OK.
  70     ${template_as_string}=    BuiltIn.Set_Variable    {'DEVICE_NAME': '${device_name}'}
  71     NetconfViaRestconf.Post_Xml_Template_Folder_Via_Restconf    ${directory_with_template_folders}${/}dataorig    ${template_as_string}
  72
  73 Check_Device_Data_Label_Is_Created
  74     [Documentation]    Get the device data label and make sure it contains the created content.
  75     Check_Config_Data    <data xmlns="${ODL_NETCONF_NAMESPACE}"><cont xmlns="urn:opendaylight:test:netconf:crud"><l>Content</l></cont></data>
  76
  77 Modify_Device_Data_Label_Via_Xml
  78     [Documentation]    Send a request to change the sample test data label and check that the request went OK.
  79     ${template_as_string}=    BuiltIn.Set_Variable    {'DEVICE_NAME': '${device_name}'}
  80     NetconfViaRestconf.Put_Xml_Template_Folder_Via_Restconf    ${directory_with_template_folders}${/}datamod1    ${template_as_string}
  81
  82 Check_Device_Data_Label_Is_Modified
  83     [Documentation]    Get the device data label and make sure it contains the modified content.
  84     Check_Config_Data    <data xmlns="${ODL_NETCONF_NAMESPACE}"><cont xmlns="urn:opendaylight:test:netconf:crud"><l>Modified Content</l></cont></data>
  85
  86 Modify_Device_Data_Label_Via_Json
  87     [Documentation]    Send a JSON request to change the sample test data label and check that the request went OK.
  88     ${template_as_string}=    BuiltIn.Set_Variable    {'DEVICE_NAME': '${device_name}'}
  89     NetconfViaRestconf.Put_Json_Template_Folder_Via_Restconf    ${directory_with_template_folders}${/}datamodjson    ${template_as_string}
  90
  91 Check_Device_Data_Label_Is_Modified_Via_Json
  92     [Documentation]    Get the device data label as XML and make sure it matches the content posted as JSON in the previous case.
  93     Check_Config_Data    <data xmlns="${ODL_NETCONF_NAMESPACE}"><cont xmlns="urn:opendaylight:test:netconf:crud"><l>Content Modified via JSON</l></cont></data>
  94
  95 Create_Car_List
  96     [Documentation]    Send a request to create a list of cars in the sample test data label and check that the request went OK.
  97     ${template_as_string}=    BuiltIn.Set_Variable    {'DEVICE_NAME': '${device_name}'}
  98     NetconfViaRestconf.Post_Xml_Template_Folder_Via_Restconf    ${directory_with_template_folders}${/}cars    ${template_as_string}
  99
 100 Check_Car_List_Created
 101     [Documentation]    Get the device data label as XML and make sure it matches the content posted as JSON in the previous case.
 102     ${data}=    Get_Config_Data
 103     BuiltIn.Should_Contain    ${data}    <id>KEEP</id>
 104     BuiltIn.Should_Not_Contain    ${data}    <id>SMALL</id>
 105     BuiltIn.Should_Not_Contain    ${data}    <model>Isetta</model>
 106     BuiltIn.Should_Not_Contain    ${data}    <manufacturer>BMW</manufacturer>
 107     BuiltIn.Should_Not_Contain    ${data}    <year>1953</year>
 108     BuiltIn.Should_Not_Contain    ${data}    <category>microcar</category>
 109     BuiltIn.Should_Not_Contain    ${data}    <id>TOYOTA</id>
 110     BuiltIn.Should_Not_Contain    ${data}    <model>Camry</model>
 111     BuiltIn.Should_Not_Contain    ${data}    <manufacturer>Toyota</manufacturer>
 112     BuiltIn.Should_Not_Contain    ${data}    <year>1982</year>
 113     BuiltIn.Should_Not_Contain    ${data}    <category>sedan</category>
 114
 115 Add_Device_Data_Item_1_Via_XML_Post
 116     [Documentation]    Send a request to create a data item in the test list and check that the request went OK.
 117     ${template_as_string}=    BuiltIn.Set_Variable    {'DEVICE_NAME': '${device_name}'}
 118     NetconfViaRestconf.Post_Xml_Template_Folder_Via_Restconf    ${directory_with_template_folders}${/}item1    ${template_as_string}
 119
 120 Check_Item1_Is_Created
 121     [Documentation]    Get the device data as XML and make sure it matches the content posted as JSON in the previous case.
 122     ${data}=    Get_Config_Data
 123     BuiltIn.Should_Contain    ${data}    <id>SMALL</id>
 124     BuiltIn.Should_Contain    ${data}    <model>Isetta</model>
 125     BuiltIn.Should_Contain    ${data}    <manufacturer>BMW</manufacturer>
 126     BuiltIn.Should_Contain    ${data}    <year>1953</year>
 127     BuiltIn.Should_Contain    ${data}    <category>microcar</category>
 128     BuiltIn.Should_Not_Contain    ${data}    <id>TOYOTA</id>
 129     BuiltIn.Should_Not_Contain    ${data}    <model>Camry</model>
 130     BuiltIn.Should_Not_Contain    ${data}    <manufacturer>Toyota</manufacturer>
 131     BuiltIn.Should_Not_Contain    ${data}    <year>1982</year>
 132     BuiltIn.Should_Not_Contain    ${data}    <category>sedan</category>
 133
 134 Add_Device_Data_Item_2_Via_JSON_Post
 135     [Documentation]    Send a JSON request to change the sample test data and check that the request went OK.
 136     ${template_as_string}=    BuiltIn.Set_Variable    {'DEVICE_NAME': '${device_name}'}
 137     NetconfViaRestconf.Post_Json_Template_Folder_Via_Restconf    ${directory_with_template_folders}${/}item2    ${template_as_string}
 138
 139 Check_Item2_Is_Created
 140     [Documentation]    Get the device data as XML and make sure it matches the content posted as JSON in the previous case.
 141     ${data}=    Get_Config_Data
 142     BuiltIn.Should_Contain    ${data}    <id>SMALL</id>
 143     BuiltIn.Should_Contain    ${data}    <model>Isetta</model>
 144     BuiltIn.Should_Contain    ${data}    <manufacturer>BMW</manufacturer>
 145     BuiltIn.Should_Contain    ${data}    <year>1953</year>
 146     BuiltIn.Should_Contain    ${data}    <category>microcar</category>
 147     BuiltIn.Should_Contain    ${data}    <id>TOYOTA</id>
 148     BuiltIn.Should_Contain    ${data}    <model>Camry</model>
 149     BuiltIn.Should_Contain    ${data}    <manufacturer>Toyota</manufacturer>
 150     BuiltIn.Should_Contain    ${data}    <year>1982</year>
 151     BuiltIn.Should_Contain    ${data}    <category>sedan</category>
 152
 153 Delete_Device_Data
 154     [Documentation]    Send a request to delete the sample test data on the device and check that the request went OK.
 155     ${template_as_string}=    BuiltIn.Set_Variable    {'DEVICE_NAME': '${device_name}'}
 156     NetconfViaRestconf.Delete_Xml_Template_Folder_Via_Restconf    ${directory_with_template_folders}${/}datamod1    ${template_as_string}
 157     NetconfViaRestconf.Delete_Xml_Template_Folder_Via_Restconf    ${directory_with_template_folders}${/}item1    ${template_as_string}
 158
 159 Check_Device_Data_Is_Deleted
 160     [Documentation]    Get the device data and make sure it is empty again.
 161     Check_Config_Data    <data xmlns="${ODL_NETCONF_NAMESPACE}"></data>
 162
 163 Deconfigure_Device_From_Netconf
 164     [Documentation]    Make request to deconfigure the testtool device on Netconf connector.
 165     [Tags]    critical
 166     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 167     NetconfKeywords.Remove_Device_From_Netconf    ${device_name}
 168
 169 Check_Device_Going_To_Be_Gone_After_Deconfiguring
 170     [Documentation]    Check that the device is really going to be gone. Fail
 171     ...    if found after one minute. This is an expected behavior as the
 172     ...    delete request is sent to the config subsystem which then triggers
 173     ...    asynchronous destruction of the netconf connector referring to the
 174     ...    device and the device's data. This test makes sure this
 175     ...    asynchronous operation does not take unreasonable amount of time
 176     ...    by making sure that both the netconf connector and the device's
 177     ...    data is gone before reporting success.
 178     [Tags]    critical
 179     NetconfKeywords.Wait_Device_Fully_Removed    ${device_name}
 180
 181 *** Keywords ***
 182 Setup_Everything
 183     [Documentation]    Setup everything needed for the test cases.
 184     # Setup resources used by the suite.
 185     SetupUtils.Setup_Utils_For_Setup_And_Teardown
 186     RequestsLibrary.Create_Session    operational    http://${ODL_SYSTEM_IP}:${RESTCONFPORT}${OPERATIONAL_API}    auth=${AUTH}
 187     NetconfKeywords.Setup_Netconf_Keywords
 188
 189 Teardown_Everything
 190     [Documentation]    Teardown the test infrastructure, perform cleanup and release all resources.
 191     Teardown_Netconf_Via_Restconf
 192     RequestsLibrary.Delete_All_Sessions
 193     BuiltIn.Run_Keyword_And_Ignore_Error    NetconfKeywords.Stop_Testtool
 194
 195 Get_Config_Data
 196     [Documentation]    Get and return the config data from the device.
 197     ${url}=    Builtin.Set_Variable    network-topology:network-topology/topology/topology-netconf/node/${device_name}/yang-ext:mount
 198     ${data}=    Utils.Get_Data_From_URI    nvr_session    ${url}    headers=${ACCEPT_XML}
 199     [Return]    ${data}
 200
 201 Check_Config_Data
 202     [Arguments]    ${expected}    ${contains}=False
 203     ${data}=    Get_Config_Data
 204     BuiltIn.Run_Keyword_Unless    ${contains}    BuiltIn.Should_Be_Equal_As_Strings    ${data}    ${expected}
 205     BuiltIn.Run_Keyword_If    ${contains}    BuiltIn.Should_Contain    ${data}    ${expected}