csit/suites/netconf/CRUD/CRUD.robot

   1 *** Settings ***
   2 Documentation     netconf-connector CRUD test suite.
   3 ...
   4 ...               Copyright (c) 2015 Cisco Systems, Inc. and others. All rights reserved.
   5 ...
   6 ...               This program and the accompanying materials are made available under the
   7 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   8 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
   9 ...
  10 ...
  11 ...               Perform basic operations (Create, Read, Update and Delete or CRUD) on device
  12 ...               data mounted onto a netconf connector and see if they work.
  13 ...
  14 ...               FIXME: Replace the BuiltIn.Should_[Not_]Contain instances in the test cases
  15 ...               that check the car list related data with calls to keywords of a Resource
  16 ...               aimed at getting interesting pieces of data from the XML files and checking
  17 ...               them against expected data sets. See MDSAL/northbound.robot suite for
  18 ...               additional information.
  19 Suite Setup       Setup_Everything
  20 Suite Teardown    Teardown_Everything
  21 Test Setup        SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
  22 Library           Collections
  23 Library           RequestsLibrary
  24 Library           OperatingSystem
  25 Library           String
  26 Library           SSHLibrary    timeout=10s
  27 Resource          ${CURDIR}/../../../libraries/FailFast.robot
  28 Resource          ${CURDIR}/../../../libraries/KarafKeywords.robot
  29 Resource          ${CURDIR}/../../../libraries/NetconfKeywords.robot
  30 Resource          ${CURDIR}/../../../libraries/NetconfViaRestconf.robot
  31 Resource          ${CURDIR}/../../../libraries/SetupUtils.robot
  32 Resource          ${CURDIR}/../../../libraries/Utils.robot
  33 Variables         ${CURDIR}/../../../variables/Variables.py
  34
  35 *** Variables ***
  36 ${directory_with_template_folders}    ${CURDIR}/../../../variables/netconf/CRUD
  37 ${device_name}    netconf-test-device
  38
  39 *** Test Cases ***
  40 Start_Testtool
  41     [Documentation]    Deploy and start test tool, then wait for all its devices to become online.
  42     NetconfKeywords.Install_And_Start_Testtool    device-count=1    schemas=${CURDIR}/../../../variables/netconf/CRUD/schemas
  43
  44 Check_Device_Is_Not_Configured_At_Beginning
  45     [Documentation]    Sanity check making sure our device is not there. Fail if found.
  46     [Tags]    critical
  47     NetconfKeywords.Check_Device_Has_No_Netconf_Connector    ${device_name}
  48
  49 Configure_Device_On_Netconf
  50     [Documentation]    Make request to configure a testtool device on Netconf connector.
  51     [Tags]    critical
  52     NetconfKeywords.Configure_Device_In_Netconf    ${device_name}
  53
  54 Check_ODL_Has_Netconf_Connector_For_Device
  55     [Documentation]    Get the list of configured devices and search for our device there. Fail if not found.
  56     [Tags]    critical
  57     ${count}    NetconfKeywords.Count_Netconf_Connectors_For_Device    ${device_name}
  58     Builtin.Should_Be_Equal_As_Strings    ${count}    1
  59
  60 Wait_For_Device_To_Become_Connected
  61     [Documentation]    Wait until the device becomes available through Netconf.
  62     NetconfKeywords.Wait_Device_Connected    ${device_name}
  63
  64 Check_Device_Data_Is_Empty
  65     [Documentation]    Get the device data and make sure it is empty.
  66     Check_Config_Data    <data xmlns="${ODL_NETCONF_NAMESPACE}"></data>
  67
  68 Create_Device_Data_Label_Via_Xml
  69     [Documentation]    Send a sample test data label into the device and check that the request went OK.
  70     ${template_as_string}=    BuiltIn.Set_Variable    {'DEVICE_NAME': '${device_name}'}
  71     NetconfViaRestconf.Post_Xml_Template_Folder_Via_Restconf    ${directory_with_template_folders}${/}dataorig    ${template_as_string}
  72
  73 Check_Device_Data_Label_Is_Created
  74     [Documentation]    Get the device data label and make sure it contains the created content.
  75     Check_Config_Data    <data xmlns="${ODL_NETCONF_NAMESPACE}"><cont xmlns="urn:opendaylight:test:netconf:crud"><l>Content</l></cont></data>
  76
  77 Modify_Device_Data_Label_Via_Xml
  78     [Documentation]    Send a request to change the sample test data label and check that the request went OK.
  79     ${template_as_string}=    BuiltIn.Set_Variable    {'DEVICE_NAME': '${device_name}'}
  80     NetconfViaRestconf.Put_Xml_Template_Folder_Via_Restconf    ${directory_with_template_folders}${/}datamod1    ${template_as_string}
  81
  82 Check_Device_Data_Label_Is_Modified
  83     [Documentation]    Get the device data label and make sure it contains the modified content.
  84     Check_Config_Data    <data xmlns="${ODL_NETCONF_NAMESPACE}"><cont xmlns="urn:opendaylight:test:netconf:crud"><l>Modified Content</l></cont></data>
  85
  86 Deconfigure_Device_From_Netconf_Temporarily
  87     [Documentation]    Make request to deconfigure the testtool device on Netconf connector.
  88     ...    This is the first part of the "configure/deconfigure" cycle of the device
  89     ...    The purpose of cycling the device like this is to see that the configuration
  90     ...    data was really stored in the device.
  91     [Tags]    critical
  92     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
  93     NetconfKeywords.Remove_Device_From_Netconf    ${device_name}
  94
  95 Wait_For_Device_To_Be_Gone
  96     [Documentation]    Wait for the device to completely disappear.
  97     NetconfKeywords.Wait_Device_Fully_Removed    ${device_name}
  98
  99 Configure_The_Device_Back
 100     [Documentation]    Configure the device again.
 101     ...    This is the second step of the device configuration.
 102     [Tags]    critical
 103     NetconfKeywords.Configure_Device_In_Netconf    ${device_name}
 104
 105 Wait_For_Device_To_Reconnect
 106     [Documentation]    Wait until the device becomes available through Netconf.
 107     NetconfKeywords.Wait_Device_Connected    ${device_name}
 108
 109 Check_Modified_Device_Data_Is_Still_There
 110     [Documentation]    Get the device data and make sure it contains the created content.
 111     BuiltIn.Wait_Until_Keyword_Succeeds    60s    1s    Check_Config_Data    <data xmlns="${ODL_NETCONF_NAMESPACE}"><cont xmlns="urn:opendaylight:test:netconf:crud"><l>Modified Content</l></cont></data>
 112
 113 Modify_Device_Data_Again
 114     [Documentation]    Send a request to change the sample test data and check that the request went OK.
 115     ${template_as_string}=    BuiltIn.Set_Variable    {'DEVICE_NAME': '${device_name}'}
 116     NetconfViaRestconf.Put_Xml_Template_Folder_Via_Restconf    ${DIRECTORY_WITH_TEMPLATE_FOLDERS}${/}datamod2    ${template_as_string}
 117
 118 Check_Device_Data_Is_Modified_Again
 119     [Documentation]    Get the device data and make sure it contains the created content.
 120     Check_Config_Data    <data xmlns="${ODL_NETCONF_NAMESPACE}"><cont xmlns="urn:opendaylight:test:netconf:crud"><l>Another Modified Content</l></cont></data>
 121
 122 Modify_Device_Data_Label_Via_Json
 123     [Documentation]    Send a JSON request to change the sample test data label and check that the request went OK.
 124     ${template_as_string}=    BuiltIn.Set_Variable    {'DEVICE_NAME': '${device_name}'}
 125     NetconfViaRestconf.Put_Json_Template_Folder_Via_Restconf    ${directory_with_template_folders}${/}datamodjson    ${template_as_string}
 126
 127 Check_Device_Data_Label_Is_Modified_Via_Json
 128     [Documentation]    Get the device data label as XML and make sure it matches the content posted as JSON in the previous case.
 129     Check_Config_Data    <data xmlns="${ODL_NETCONF_NAMESPACE}"><cont xmlns="urn:opendaylight:test:netconf:crud"><l>Content Modified via JSON</l></cont></data>
 130
 131 Create_Car_List
 132     [Documentation]    Send a request to create a list of cars in the sample test data label and check that the request went OK.
 133     ${template_as_string}=    BuiltIn.Set_Variable    {'DEVICE_NAME': '${device_name}'}
 134     NetconfViaRestconf.Post_Xml_Template_Folder_Via_Restconf    ${directory_with_template_folders}${/}cars    ${template_as_string}
 135
 136 Check_Car_List_Created
 137     [Documentation]    Get the device data label as XML and make sure it matches the content posted as JSON in the previous case.
 138     ${data}=    Get_Config_Data
 139     BuiltIn.Should_Contain    ${data}    <id>KEEP</id>
 140     BuiltIn.Should_Not_Contain    ${data}    <id>SMALL</id>
 141     BuiltIn.Should_Not_Contain    ${data}    <model>Isetta</model>
 142     BuiltIn.Should_Not_Contain    ${data}    <manufacturer>BMW</manufacturer>
 143     BuiltIn.Should_Not_Contain    ${data}    <year>1953</year>
 144     BuiltIn.Should_Not_Contain    ${data}    <category>microcar</category>
 145     BuiltIn.Should_Not_Contain    ${data}    <id>TOYOTA</id>
 146     BuiltIn.Should_Not_Contain    ${data}    <model>Camry</model>
 147     BuiltIn.Should_Not_Contain    ${data}    <manufacturer>Toyota</manufacturer>
 148     BuiltIn.Should_Not_Contain    ${data}    <year>1982</year>
 149     BuiltIn.Should_Not_Contain    ${data}    <category>sedan</category>
 150
 151 Add_Device_Data_Item_1_Via_XML_Post
 152     [Documentation]    Send a request to create a data item in the test list and check that the request went OK.
 153     ${template_as_string}=    BuiltIn.Set_Variable    {'DEVICE_NAME': '${device_name}'}
 154     NetconfViaRestconf.Post_Xml_Template_Folder_Via_Restconf    ${directory_with_template_folders}${/}item1    ${template_as_string}
 155
 156 Check_Item1_Is_Created
 157     [Documentation]    Get the device data as XML and make sure it matches the content posted as JSON in the previous case.
 158     ${data}=    Get_Config_Data
 159     BuiltIn.Should_Contain    ${data}    <id>SMALL</id>
 160     BuiltIn.Should_Contain    ${data}    <model>Isetta</model>
 161     BuiltIn.Should_Contain    ${data}    <manufacturer>BMW</manufacturer>
 162     BuiltIn.Should_Contain    ${data}    <year>1953</year>
 163     BuiltIn.Should_Contain    ${data}    <category>microcar</category>
 164     BuiltIn.Should_Not_Contain    ${data}    <id>TOYOTA</id>
 165     BuiltIn.Should_Not_Contain    ${data}    <model>Camry</model>
 166     BuiltIn.Should_Not_Contain    ${data}    <manufacturer>Toyota</manufacturer>
 167     BuiltIn.Should_Not_Contain    ${data}    <year>1982</year>
 168     BuiltIn.Should_Not_Contain    ${data}    <category>sedan</category>
 169
 170 Add_Device_Data_Item_2_Via_JSON_Post
 171     [Documentation]    Send a JSON request to change the sample test data and check that the request went OK.
 172     ${template_as_string}=    BuiltIn.Set_Variable    {'DEVICE_NAME': '${device_name}'}
 173     NetconfViaRestconf.Post_Json_Template_Folder_Via_Restconf    ${directory_with_template_folders}${/}item2    ${template_as_string}
 174
 175 Check_Item2_Is_Created
 176     [Documentation]    Get the device data as XML and make sure it matches the content posted as JSON in the previous case.
 177     ${data}=    Get_Config_Data
 178     BuiltIn.Should_Contain    ${data}    <id>SMALL</id>
 179     BuiltIn.Should_Contain    ${data}    <model>Isetta</model>
 180     BuiltIn.Should_Contain    ${data}    <manufacturer>BMW</manufacturer>
 181     BuiltIn.Should_Contain    ${data}    <year>1953</year>
 182     BuiltIn.Should_Contain    ${data}    <category>microcar</category>
 183     BuiltIn.Should_Contain    ${data}    <id>TOYOTA</id>
 184     BuiltIn.Should_Contain    ${data}    <model>Camry</model>
 185     BuiltIn.Should_Contain    ${data}    <manufacturer>Toyota</manufacturer>
 186     BuiltIn.Should_Contain    ${data}    <year>1982</year>
 187     BuiltIn.Should_Contain    ${data}    <category>sedan</category>
 188
 189 Delete_Device_Data
 190     [Documentation]    Send a request to delete the sample test data on the device and check that the request went OK.
 191     ${template_as_string}=    BuiltIn.Set_Variable    {'DEVICE_NAME': '${device_name}'}
 192     NetconfViaRestconf.Delete_Xml_Template_Folder_Via_Restconf    ${directory_with_template_folders}${/}datamod1    ${template_as_string}
 193     NetconfViaRestconf.Delete_Xml_Template_Folder_Via_Restconf    ${directory_with_template_folders}${/}item1    ${template_as_string}
 194
 195 Check_Device_Data_Is_Deleted
 196     [Documentation]    Get the device data and make sure it is empty again.
 197     Check_Config_Data    <data xmlns="${ODL_NETCONF_NAMESPACE}"></data>
 198
 199 Deconfigure_Device_From_Netconf
 200     [Documentation]    Make request to deconfigure the testtool device on Netconf connector.
 201     [Tags]    critical
 202     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 203     NetconfKeywords.Remove_Device_From_Netconf    ${device_name}
 204
 205 Check_Device_Going_To_Be_Gone_After_Deconfiguring
 206     [Documentation]    Check that the device is really going to be gone. Fail
 207     ...    if found after one minute. This is an expected behavior as the
 208     ...    delete request is sent to the config subsystem which then triggers
 209     ...    asynchronous destruction of the netconf connector referring to the
 210     ...    device and the device's data. This test makes sure this
 211     ...    asynchronous operation does not take unreasonable amount of time
 212     ...    by making sure that both the netconf connector and the device's
 213     ...    data is gone before reporting success.
 214     [Tags]    critical
 215     NetconfKeywords.Wait_Device_Fully_Removed    ${device_name}
 216
 217 *** Keywords ***
 218 Setup_Everything
 219     [Documentation]    Setup everything needed for the test cases.
 220     # Setup resources used by the suite.
 221     SetupUtils.Setup_Utils_For_Setup_And_Teardown
 222     RequestsLibrary.Create_Session    operational    http://${ODL_SYSTEM_IP}:${RESTCONFPORT}${OPERATIONAL_API}    auth=${AUTH}
 223     NetconfKeywords.Setup_Netconf_Keywords
 224
 225 Teardown_Everything
 226     [Documentation]    Teardown the test infrastructure, perform cleanup and release all resources.
 227     Teardown_Netconf_Via_Restconf
 228     RequestsLibrary.Delete_All_Sessions
 229     BuiltIn.Run_Keyword_And_Ignore_Error    NetconfKeywords.Stop_Testtool
 230
 231 Get_Config_Data
 232     [Documentation]    Get and return the config data from the device.
 233     ${url}=    Builtin.Set_Variable    network-topology:network-topology/topology/topology-netconf/node/${device_name}/yang-ext:mount
 234     ${data}=    Utils.Get_Data_From_URI    nvr_session    ${url}    headers=${ACCEPT_XML}
 235     [Return]    ${data}
 236
 237 Check_Config_Data
 238     [Arguments]    ${expected}    ${contains}=False
 239     ${data}=    Get_Config_Data
 240     BuiltIn.Run_Keyword_Unless    ${contains}    BuiltIn.Should_Be_Equal_As_Strings    ${data}    ${expected}
 241     BuiltIn.Run_Keyword_If    ${contains}    BuiltIn.Should_Contain    ${data}    ${expected}