csit/suites/netconf/ready/netconfready.robot

   1 *** Settings ***
   2 Documentation     netconf-connector readiness test suite.
   3 ...
   4 ...               Copyright (c) 2015 Cisco Systems, Inc. and others. All rights reserved.
   5 ...
   6 ...               This program and the accompanying materials are made available under the
   7 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   8 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
   9 ...
  10 ...
  11 ...               Try to detect whether Netconf is up and running and wait for
  12 ...               it for a configurable time if it is not yet up and running.
  13 ...
  14 ...               By default this is done by querying netconf-connector and
  15 ...               seeing whether it works. Some testsuites expect netconf-connector
  16 ...               to be ready as soon as possible and will fail if it is not. We
  17 ...               want to see a failure if this is the cause of the failure.
  18 ...
  19 ...               If the netconf-connector is not ready upon startup (as seen by
  20 ...               the first test case failing), the second case starts to repeat
  21 ...               the query for a minute to see whether it is going "to fix itself"
  22 ...               within the minute. If yes, then the testcase will pass, which
  23 ...               indicates that the "ODL cooldown" of 1 minute is not long enough
  24 ...               to allow for netconf-connector to initialize properly.
  25 ...
  26 ...               If the USE_NETCONF_CONNECTOR is forced to be False by the Robot
  27 ...               invocation argument, then the suite does not use netconf
  28 ...               connector for the readiness detection but merely waits for the
  29 ...               Netconf topology to appear. This is a weaker condition when
  30 ...               Netconf connector is about to be used but is necessary if the
  31 ...               suite in question does not use the Netconf connector.
  32 ...
  33 ...               If the first test case passed, then the second test case does
  34 ...               nothing.
  35 ...
  36 ...               The third test case then checks whether Netconf can pretty print
  37 ...               data. This sometimes makes problems, most likely due to too
  38 ...               new Robot Requests library with an interface incompatible with
  39 ...               this test suite.
  40 Suite Setup       Setup_Everything
  41 Suite Teardown    Teardown_Everything
  42 Test Teardown     SetupUtils.Teardown_Test_Show_Bugs_If_Test_Failed
  43 Library           RequestsLibrary
  44 Resource          ${CURDIR}/../../../libraries/KarafKeywords.robot
  45 Resource          ${CURDIR}/../../../libraries/NetconfKeywords.robot
  46 Resource          ${CURDIR}/../../../libraries/SetupUtils.robot
  47 Resource          ${CURDIR}/../../../libraries/Utils.robot
  48 Variables         ${CURDIR}/../../../variables/Variables.py
  49
  50 *** Variables ***
  51 ${netconf_is_ready}    False
  52 ${NETCONFREADY_WAIT}    60s
  53 ${USE_NETCONF_CONNECTOR}    True
  54 ${DEBUG_LOGGING_FOR_EVERYTHING}    False
  55 ${NETCONFREADY_WAIT_MDSAL}    60s
  56
  57 *** Test Cases ***
  58 Check_Whether_Netconf_Is_Up_And_Running
  59     [Documentation]    Make one request to Netconf topology to see whether Netconf is up and running.
  60     [Tags]    exclude
  61     SetupUtils.Set_Known_Bug_Id    4708
  62     Check_Netconf_Up_And_Running
  63     BuiltIn.Set_Suite_Variable    ${netconf_is_ready}    True
  64
  65 Wait_For_Netconf
  66     [Documentation]    Wait for the Netconf to go up for configurable time.
  67     [Tags]    critical
  68     BuiltIn.Set_Suite_Variable    ${netconf_not_ready_cause}    4583
  69     SetupUtils.Set_Known_Bug_Id    4583
  70     BuiltIn.Run_Keyword_Unless    ${netconf_is_ready}    BuiltIn.Wait_Until_Keyword_Succeeds    ${NETCONFREADY_WAIT}    1s    Check_Netconf_Up_And_Running
  71     BuiltIn.Set_Suite_Variable    ${netconf_is_ready}    True
  72
  73 Check_For_Bug_5014
  74     [Documentation]    If Netconf appears to be down, it may be due to bug 5014. Check if it is so and fail if yes.
  75     ...    Bug 5014 is about Netconf playing dead on boot until a device
  76     ...    configuration request is sent to it. To uncover this attempt to
  77     ...    configure and then deconfigure a device and then check if Netconf
  78     ...    is now up and running. If that turns out to be true, fail the case
  79     ...    as this signifies the bug 5014 to be present. Skip this testcase
  80     ...    if Netconf is detected to be up and running.
  81     [Tags]    critical
  82     SetupUtils.Set_Known_Bug_Id    5014
  83     BuiltIn.Pass_Execution_If    ${netconf_is_ready}    Netconf was detected to be up and running so bug 5014 did not show up.
  84     ${status}    ${error}=    BuiltIn.Run_Keyword_And_Ignore_Error    Check_Netconf_Usable
  85     BuiltIn.Run_Keyword_If    '${status}'=='PASS'    BuiltIn.Set_Suite_Variable    ${netconf_is_ready}    True
  86     BuiltIn.Should_Be_Equal    '${status}'    'FAIL'
  87
  88 Check_Whether_Netconf_Can_Pretty_Print
  89     [Documentation]    Make one request to netconf-connector and see if it works.
  90     [Tags]    critical
  91     SetupUtils.Set_Known_Bug_Id    ${netconf_not_ready_cause}
  92     BuiltIn.Run_Keyword_Unless    ${netconf_is_ready}    Fail    Netconf is not ready so it can't pretty-print now.
  93     Check_Netconf_Up_And_Running    ?prettyPrint=true
  94
  95 Wait_For_MDSAL
  96     [Documentation]    Wait for the MDSAL feature to become online
  97     SetupUtils.Set_Known_Bug_Id    4583
  98     ${status}    ${message}=    BuiltIn.Run_Keyword_And_Ignore_Error    KarafKeywords.Verify_Feature_Is_Installed    odl-netconf-mdsal
  99     BuiltIn.Run_Keyword_If    '${status}' == 'FAIL'    BuiltIn.Pass_Execution    The 'odl-netconf-mdsal' feature is not installed so no need to wait for it.
 100     SSHKeywords.Open_Connection_To_ODL_System
 101     BuiltIn.Wait_Until_Keyword_Succeeds    ${NETCONFREADY_WAIT_MDSAL}    1s    Check_Netconf_MDSAL_Up_And_Running
 102     SSHLibrary.Close_Connection
 103
 104 *** Keywords ***
 105 Setup_Everything
 106     [Documentation]    Setup requests library and log into karaf.log that the netconf readiness wait starts.
 107     ${connector}=    BuiltIn.Set_Variable_If    ${USE_NETCONF_CONNECTOR}    /node/controller-config/yang-ext:mount/config:modules/module/odl-sal-netconf-connector-cfg:sal-netconf-connector/controller-config    ${EMPTY}
 108     BuiltIn.Set_Suite_Variable    ${netconf_connector}    ${connector}
 109     KarafKeywords.Open_Controller_Karaf_Console_On_Background
 110     KarafKeywords.Log_Message_To_Controller_Karaf    Starting Netconf readiness test suite
 111     BuiltIn.Run_Keyword_If    ${DEBUG_LOGGING_FOR_EVERYTHING}    KarafKeywords.Execute_Controller_Karaf_Command_On_Background    log:set DEBUG
 112     RequestsLibrary.Create_Session    ses    http://${ODL_SYSTEM_IP}:${RESTCONFPORT}    auth=${AUTH}
 113     NetconfKeywords.Setup_Netconf_Keywords
 114
 115 Teardown_Everything
 116     [Documentation]    Destroy all sessions in the requests library and log into karaf.log that the netconf readiness wait is over.
 117     KarafKeywords.Log_Message_To_Controller_Karaf    Ending Netconf readiness test suite
 118     RequestsLibrary.Delete_All_Sessions
 119
 120 Check_Netconf_Up_And_Running
 121     [Arguments]    ${pretty_print}=${EMPTY}
 122     [Documentation]    Make a request to netconf connector's list of mounted devices and check that the request was successful.
 123     ${response}=    RequestsLibrary.Get_Request    ses    restconf/config/network-topology:network-topology/topology/topology-netconf${netconf_connector}${pretty_print}
 124     BuiltIn.Log    ${response.text}
 125     ${status}=    BuiltIn.Run_Keyword_And_Return_Status    BuiltIn.Should_Contain    ${response.text}    data model content does not exist
 126     BuiltIn.Run_Keyword_If    ${status}    BuiltIn.Set_Suite_Variable    ${netconf_not_ready_cause}    5832
 127     BuiltIn.Run_Keyword_If    ${status}    SetupUtils.Set_Known_Bug_Id    5832
 128     BuiltIn.Should_Be_Equal_As_Strings    ${response.status_code}    200
 129
 130 Check_Netconf_Usable
 131     NetconfKeywords.Configure_Device_In_Netconf    test-device    device_type=configure-via-topology
 132     NetconfKeywords.Remove_Device_From_Netconf    test-device
 133     Check_Netconf_Up_And_Running
 134
 135 Check_Netconf_MDSAL_Up_And_Running
 136     ${count}=    SSHKeywords.Count_Port_Occurences    ${ODL_NETCONF_MDSAL_PORT}    LISTEN    java
 137     BuiltIn.Should_Be_Equal_As_Integers    ${count}    1