csit/suites/netvirt/upgrade/upgrade.robot

   1 *** Settings ***
   2 Documentation     Test suite for ODL Upgrade. It is assumed that OLD + OpenStack
   3 ...               integrated environment is deployed and ready.
   4 Suite Setup       Suite Setup
   5 Suite Teardown    Upgrade Suite Teardown
   6 Test Setup        SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
   7 Test Teardown     Get Test Teardown Debugs
   8 Library           OperatingSystem
   9 Library           RequestsLibrary
  10 Library           SSHLibrary
  11 Resource          ../../../libraries/ClusterManagement.robot
  12 Resource          ../../../libraries/DevstackUtils.robot
  13 Resource          ../../../libraries/KarafKeywords.robot
  14 Resource          ../../../libraries/OpenStackOperations.robot
  15 Resource          ../../../libraries/OVSDB.robot
  16 Resource          ../../../libraries/SetupUtils.robot
  17 Resource          ../../../libraries/Utils.robot
  18
  19 *** Variables ***
  20 ${SECURITY_GROUP}    upgrade_sg
  21 @{NETWORKS}       upgrade_net_1    upgrade_net_2
  22 @{SUBNETS}        upgrade_sub_1    upgrade_sub_2
  23 @{NET_1_VMS}      upgrade_net_1_vm_1    upgrade_net_1_vm_2
  24 @{NET_2_VMS}      upgrade_net_2_vm_1    upgrade_net_2_vm_2
  25 @{SUBNETS_RANGE}    91.0.0.0/24    92.0.0.0/24
  26 ${ROUTER}         upgrade_router_1
  27 ${TYPE}           tun
  28 ${PASSIVE_MANAGER}    ptcp:6641:127.0.0.1
  29 @{DEBUG_LOG_COMPONENTS}    org.opendaylight.ovsdb    org.opendaylight.ovsdb.lib    org.opendaylight.netvirt    org.opendaylight.genius
  30 ${UPDATE_FLAG_PATH}    /restconf/config/genius-mdsalutil:config
  31
  32 *** Test Cases ***
  33 Create Setup And Verify Instance Connectivity
  34     [Documentation]    Create 2 VXLAN networks, subnets with 2 VMs each and a router. Ping all 4 VMs.
  35     Check Resource Connectivity
  36     DevstackUtils.Set Node Data For Control Only Node Setup
  37     Dump Debug With Annotations    POST_SETUP
  38
  39 Stop ODL
  40     ClusterManagement.Stop_Members_From_List_Or_All
  41
  42 Disconnect OVS
  43     [Documentation]    Delete OVS manager, controller and groups and tun ports
  44     : FOR    ${node}    IN    @{OS_ALL_IPS}
  45     \    OVSDB.Delete OVS Manager    ${node}
  46     \    OVSDB.Delete OVS Controller    ${node}
  47     \    OVSDB.Delete Groups On Bridge    ${node}    ${INTEGRATION_BRIDGE}
  48     \    OVSDB.Delete Ports On Bridge By Type    ${node}    ${INTEGRATION_BRIDGE}    ${TYPE}
  49
  50 Wipe Local Data
  51     [Documentation]    Delete data/, journal/, snapshots/
  52     ClusterManagement.Clean_Journals_Data_And_Snapshots_On_List_Or_All
  53
  54 Start ODL
  55     [Documentation]    Start controller, wait for it to come "UP" and make sure netvirt is installed
  56     ClusterManagement.Start_Members_From_List_Or_All    wait_for_sync=True
  57     Wait Until Keyword Succeeds    100s    5s    Utils.Check Diagstatus
  58     BuiltIn.Set_Suite_Variable    \${ClusterManagement__has_setup_run}    False
  59     KarafKeywords.Verify_Feature_Is_Installed    odl-netvirt-openstack
  60     Set Custom Component Logging To    DEBUG
  61
  62 Wait For Full Sync
  63     [Documentation]    Wait for networking_odl to sync neutron configuration
  64     Wait Until Keyword Succeeds    90s    5s    Canary Network Should Exist
  65
  66 Set Upgrade Flag
  67     ${resp} =    RequestsLibrary.Put Request    session    ${UPDATE_FLAG_PATH}    {"config":{"upgradeInProgress":true}}
  68     BuiltIn.Should Be Equal As Strings    ${resp.status_code}    200
  69
  70 Set OVS Manager And Controller
  71     [Documentation]    Set controller and manager on each OpenStack node and check that egress flows are present
  72     : FOR    ${node}    IN    @{OS_ALL_IPS}
  73     \    Utils.Run Command On Remote System And Log    ${node}    sudo ovs-vsctl set-manager tcp:${ODL_SYSTEM_IP}:${OVSDBPORT} ${PASSIVE_MANAGER}
  74     Wait Until Keyword Succeeds    180s    15s    Check OVS Nodes Have Egress Flows
  75
  76 UnSet Upgrade Flag
  77     ${resp} =    RequestsLibrary.Put Request    session    ${UPDATE_FLAG_PATH}    {"config":{"upgradeInProgress":false}}
  78     BuiltIn.Should Be Equal As Strings    ${resp.status_code}    200
  79
  80 Check Connectivity With Previously Created Resources And br-int Info
  81     [Documentation]    Check that pre-existing instance connectivity still works after the new controller is brought
  82     ...    up and config is sync'd
  83     Dump Debug With Annotations    POST_UPGRADE
  84     Wait Until Keyword Succeeds    90s    10s    Check Resource Connectivity
  85
  86 *** Keywords ***
  87 Suite Setup
  88     OpenStackOperations.OpenStack Suite Setup
  89     Create Resources
  90     OpenStackOperations.Show Debugs    @{NET_1_VMS}    @{NET_2_VMS}
  91     OpenStackOperations.Get Suite Debugs
  92
  93 Create Resources
  94     [Documentation]    Create 2 VXLAN networks, subnets with 2 VMs each and a router. Ping all 4 VMs.
  95     : FOR    ${net}    IN    @{NETWORKS}
  96     \    OpenStackOperations.Create Network    ${net}
  97     OpenStackOperations.Create SubNet    @{NETWORKS}[0]    @{SUBNETS}[0]    @{SUBNETS_RANGE}[0]
  98     OpenStackOperations.Create SubNet    @{NETWORKS}[1]    @{SUBNETS}[1]    @{SUBNETS_RANGE}[1]
  99     OpenStackOperations.Create Allow All SecurityGroup    ${SECURITY_GROUP}
 100     OpenStackOperations.Create Nano Flavor
 101     : FOR    ${vm}    IN    @{NET_1_VMS}
 102     \    OpenStackOperations.Create Vm Instance On Compute Node    @{NETWORKS}[0]    ${vm}    ${OS_CMP1_HOSTNAME}    sg=${SECURITY_GROUP}
 103     : FOR    ${vm}    IN    @{NET_2_VMS}
 104     \    OpenStackOperations.Create Vm Instance On Compute Node    @{NETWORKS}[1]    ${vm}    ${OS_CMP2_HOSTNAME}    sg=${SECURITY_GROUP}
 105     OpenStackOperations.Create Router    ${ROUTER}
 106     : FOR    ${interface}    IN    @{SUBNETS}
 107     \    OpenStackOperations.Add Router Interface    ${ROUTER}    ${interface}
 108     @{NET1_VM_IPS}    ${NET1_DHCP_IP} =    OpenStackOperations.Get VM IPs    @{NET_1_VMS}
 109     @{NET2_VM_IPS}    ${NET2_DHCP_IP} =    OpenStackOperations.Get VM IPs    @{NET_2_VMS}
 110     BuiltIn.Set Suite Variable    @{NET1_VM_IPS}
 111     BuiltIn.Set Suite Variable    @{NET2_VM_IPS}
 112     BuiltIn.Should Not Contain    ${NET1_VM_IPS}    None
 113     BuiltIn.Should Not Contain    ${NET2_VM_IPS}    None
 114     BuiltIn.Should Not Contain    ${NET1_DHCP_IP}    None
 115     BuiltIn.Should Not Contain    ${NET2_DHCP_IP}    None
 116
 117 Check Resource Connectivity
 118     [Documentation]    Ping 2 VMs in the same net and 1 from another net.
 119     OpenStackOperations.Ping Vm From DHCP Namespace    upgrade_net_1    @{NET1_VM_IPS}[0]
 120     OpenStackOperations.Ping Vm From DHCP Namespace    upgrade_net_1    @{NET1_VM_IPS}[1]
 121     OpenStackOperations.Ping Vm From DHCP Namespace    upgrade_net_1    @{NET2_VM_IPS}[0]
 122     OpenStackOperations.Ping Vm From DHCP Namespace    upgrade_net_2    @{NET2_VM_IPS}[0]
 123     OpenStackOperations.Ping Vm From DHCP Namespace    upgrade_net_2    @{NET2_VM_IPS}[1]
 124     OpenStackOperations.Ping Vm From DHCP Namespace    upgrade_net_2    @{NET1_VM_IPS}[0]
 125
 126 Check OVS Nodes Have Egress Flows
 127     [Documentation]    Loop over all openstack nodes to ensure they have the proper flows installed.
 128     : FOR    ${node}    IN    @{OS_ALL_IPS}
 129     \    Does OVS Have Multiple Egress Flows    ${node}
 130
 131 Does OVS Have Multiple Egress Flows
 132     [Arguments]    ${ip}
 133     [Documentation]    Verifies that at least 1 flow exists on the node for the ${EGRESS_L2_FWD_TABLE}
 134     ${flows} =    Utils.Run Command On Remote System And Log    ${ip}    sudo ovs-ofctl -O OpenFlow13 dump-flows ${INTEGRATION_BRIDGE}
 135     ${egress_flows} =    String.Get Lines Containing String    ${flows}    table=${EGRESS_LPORT_DISPATCHER_TABLE}
 136     ${num_egress_flows} =    String.Get Line Count    ${egress_flows}
 137     BuiltIn.Should Be True    ${num_egress_flows} > 1
 138
 139 Set Custom Component Logging To
 140     [Arguments]    ${level}
 141     SetupUtils.Setup_Logging_For_Debug_Purposes_On_List_Or_All    ${level}    ${DEBUG_LOG_COMPONENTS}
 142     KarafKeywords.Issue_Command_On_Karaf_Console    log:list
 143
 144 Dump Debug With Annotations
 145     [Arguments]    ${tag}
 146     [Documentation]    Dump tons of debug logs for each OS node but also emit tags to make parsing easier
 147     Builtin.Log    Start dumping at phase ${tag}
 148     : FOR    ${node}    IN    @{OS_ALL_IPS}
 149     \    ${conn_id} =    DevstackUtils.Open Connection    ${node}_CONNECTION_NAME    ${node}
 150     \    Builtin.Log    Start dumping for ${node} at phase ${tag}
 151     \    OpenStackOperations.Get DumpFlows And Ovsconfig    ${conn_id}
 152     \    Builtin.Log    End dumping for ${node} at phase ${tag}
 153     \    SSHLibrary.Close Connection
 154     Builtin.Log    End dumping at phase ${tag}
 155
 156 Canary Network Should Exist
 157     OpenStackOperations.Get Neutron Network Rest    bd8db3a8-2b30-4083-a8b3-b3fd46401142
 158
 159 Upgrade Suite Teardown
 160     Set Custom Component Logging To    INFO
 161     OpenStackOperations.OpenStack Suite Teardown