csit/suites/netvirt/vpnservice/vpn_basic_ipv6.robot

   1 *** Settings ***
   2 Documentation     Test suite to validate IPv6 vpnservice functionality in an Openstack integrated environment.
   3 ...               The assumption of this suite is that the environment is already configured with the proper
   4 ...               integration bridges and vxlan tunnels.
   5 Suite Setup       Suite Setup
   6 Suite Teardown    Suite Teardown
   7 Test Setup        SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
   8 Test Teardown     OpenStackOperations.Get Test Teardown Debugs
   9 Library           OperatingSystem
  10 Library           RequestsLibrary
  11 Resource          ../../../libraries/Utils.robot
  12 Resource          ../../../libraries/OpenStackOperations.robot
  13 Resource          ../../../libraries/DevstackUtils.robot
  14 Resource          ../../../libraries/VpnOperations.robot
  15 Resource          ../../../libraries/OVSDB.robot
  16 Resource          ../../../libraries/SetupUtils.robot
  17 Resource          ../../../libraries/Tcpdump.robot
  18 Resource          ../../../variables/Variables.robot
  19 Resource          ../../../variables/netvirt/Variables.robot
  20
  21 *** Variables ***
  22 ${SECURITY_GROUP}    vpn6_sg
  23 @{NETWORKS}       vpn6_net_1    vpn6_net_2
  24 @{SUBNETS}        vpn6_sub_1    vpn6_sub_2
  25 @{SUBNET_CIDRS}    2001:db8:0:2::/64    2001:db8:0:3::/64
  26 @{PORTS}          vpn6_net_1_port_1    vpn6_net_1_port_2    vpn6_net_2_port_1    vpn6_net_2_port_2
  27 @{NET_1_VMS}      vpn6_net_1_vm_1    vpn6_net_1_vm_2
  28 @{NET_2_VMS}      vpn6_net_2_vm_1    vpn6_net_2_vm_2
  29 ${ROUTER}         vpn6_router
  30 @{EXTRA_NW_IP}    2001:db9:cafe:d::10    2001:db9:abcd:d::20
  31 @{EXTRA_NW_SUBNET}    2001:db9:cafe:d::/64    2001:db9:abcd:d::/64
  32 ${UPDATE_NETWORK}    UpdateNetworkV6
  33 ${UPDATE_SUBNET}    UpdateSubnetV6
  34 ${UPDATE_PORT}    UpdatePortV6
  35 @{VPN_INSTANCE_IDS}    4ae8cd92-48ca-49b5-94e1-b2921a261661    4ae8cd92-48ca-49b5-94e1-b2921a261662    4ae8cd92-48ca-49b5-94e1-b2921a261663
  36 @{VPN_NAMES}      vpn6_1    vpn6_2    vpn6_3
  37 @{RDS}            ["2206:2"]    ["2306:2"]    ["2406:2"]
  38
  39 *** Test Cases ***
  40 Check ELAN Datapath Traffic Within The Networks
  41     ${output}=    OpenStackOperations.Execute Command on VM Instance    @{NETWORKS}[0]    @{VM_IP_NET10}[0]    ping6 -c 3 @{VM_IP_NET10}[1]
  42     BuiltIn.Should Contain    ${output}    64 bytes
  43     ${output}=    OpenStackOperations.Execute Command on VM Instance    @{NETWORKS}[1]    @{VM_IP_NET20}[0]    ping6 -c 3 @{VM_IP_NET20}[1]
  44     BuiltIn.Should Contain    ${output}    64 bytes
  45
  46 Check L3_Datapath Traffic Across Networks With Router
  47     BuiltIn.Log    Verification of FIB Entries and Flow
  48     @{tcpdump_conn_ids} =    OpenStackOperations.Start Packet Capture On Nodes    tcpdump_vpn6    ${EMPTY}    @{OS_ALL_IPS}
  49     ${vm_ips} =    BuiltIn.Create List    @{VM_IP_NET10}    @{VM_IP_NET20}
  50     BuiltIn.Wait Until Keyword Succeeds    30s    10s    Utils.Check For Elements At URI    ${FIB_ENTRY_URL}    ${vm_ips}
  51     BuiltIn.Wait Until Keyword Succeeds    30s    10s    VpnOperations.Verify Flows Are Present For L3VPN    ${OS_CMP1_IP}    ${VM_IP_NET10}
  52     BuiltIn.Wait Until Keyword Succeeds    30s    10s    VpnOperations.Verify Flows Are Present For L3VPN    ${OS_CMP1_IP}    ${VM_IP_NET20}
  53     BuiltIn.Wait Until Keyword Succeeds    30s    10s    VpnOperations.Verify GWMAC Entry On ODL    ${GWMAC_ADDRS}
  54     Verify GWMAC Flow Entry On Flow Table On All Compute Nodes    ipv6
  55     ${dst_ip_list} =    BuiltIn.Create List    @{VM_IP_NET10}[1]    @{VM_IP_NET20}
  56     OpenStackOperations.Test Operations From Vm Instance    @{NETWORKS}[0]    @{VM_IP_NET10}[0]    ${dst_ip_list}
  57     ${dst_ip_list} =    BuiltIn.Create List    @{VM_IP_NET20}[1]    @{VM_IP_NET10}
  58     OpenStackOperations.Test Operations From Vm Instance    @{NETWORKS}[1]    @{VM_IP_NET20}[0]    ${dst_ip_list}
  59     [Teardown]    VpnOperations.Test Teardown With Tcpdump Stop    ${tcpdump_conn_ids}
  60
  61 Add Multiple Extra Routes And Check Datapath Before L3VPN Creation
  62     ${CONFIG_EXTRA_ROUTE_IP1} =    BuiltIn.Catenate    sudo ip -6 addr add @{EXTRA_NW_IP}[0]/64 dev eth0
  63     ${output} =    OpenStackOperations.Execute Command on VM Instance    @{NETWORKS}[0]    @{VM_IP_NET10}[0]    ${CONFIG_EXTRA_ROUTE_IP1}
  64     ${output} =    OpenStackOperations.Execute Command on VM Instance    @{NETWORKS}[0]    @{VM_IP_NET10}[0]    ip -6 a
  65     ${CONFIG_EXTRA_ROUTE_IP2} =    BuiltIn.Catenate    sudo ip -6 addr add @{EXTRA_NW_IP}[1]/64 dev eth0
  66     ${output} =    OpenStackOperations.Execute Command on VM Instance    @{NETWORKS}[0]    @{VM_IP_NET10}[0]    ${CONFIG_EXTRA_ROUTE_IP2}
  67     ${output} =    OpenStackOperations.Execute Command on VM Instance    @{NETWORKS}[0]    @{VM_IP_NET10}[0]    ip -6 a
  68     ${EXT_RT1} =    Set Variable    destination=@{EXTRA_NW_SUBNET}[0],gateway=@{VM_IP_NET10}[0]
  69     ${EXT_RT2} =    Set Variable    destination=@{EXTRA_NW_SUBNET}[1],gateway=@{VM_IP_NET10}[0]
  70     ${cmd} =    BuiltIn.Catenate    ${RT_OPTIONS}    ${EXT_RT1}    ${RT_OPTIONS}    ${EXT_RT2}
  71     OpenStackOperations.Update Router    ${ROUTER}    ${cmd}
  72     OpenStackOperations.Show Router    ${ROUTER}    -D
  73     ${vm_ips} =    BuiltIn.Create List    @{EXTRA_NW_SUBNET}
  74     BuiltIn.Wait Until Keyword Succeeds    30s    10s    Utils.Check For Elements At URI    ${FIB_ENTRY_URL}    ${vm_ips}
  75     ${output} =    OpenStackOperations.Execute Command on VM Instance    @{NETWORKS}[0]    @{VM_IP_NET10}[1]    ping6 -c 3 @{EXTRA_NW_IP}[1]
  76     BuiltIn.Should Contain    ${output}    64 bytes
  77     ${output} =    OpenStackOperations.Execute Command on VM Instance    @{NETWORKS}[1]    @{VM_IP_NET20}[1]    ping6 -c 3 @{EXTRA_NW_IP}[1]
  78     BuiltIn.Should Contain    ${output}    64 bytes
  79     ${output} =    OpenStackOperations.Execute Command on VM Instance    @{NETWORKS}[0]    @{VM_IP_NET10}[1]    ping6 -c 3 @{EXTRA_NW_IP}[0]
  80     BuiltIn.Should Contain    ${output}    64 bytes
  81
  82 Delete Extra Route
  83     OpenStackOperations.Update Router    ${ROUTER}    ${RT_CLEAR}
  84     OpenStackOperations.Show Router    ${ROUTER}    -D
  85
  86 Delete And Recreate Extra Route
  87     [Documentation]    Recreate multiple extra route and check data path before L3VPN creation
  88     ${CONFIG_EXTRA_ROUTE_IP1} =    BuiltIn.Catenate    sudo ip -6 addr add @{EXTRA_NW_IP}[1]/64 dev eth0
  89     ${output} =    OpenStackOperations.Execute Command on VM Instance    @{NETWORKS}[0]    @{VM_IP_NET10}[0]    ${CONFIG_EXTRA_ROUTE_IP1}
  90     ${EXT_RT1} =    Set Variable    destination=@{EXTRA_NW_SUBNET}[0],gateway=@{VM_IP_NET10}[0]
  91     ${cmd} =    BuiltIn.Catenate    ${RT_OPTIONS}    ${EXT_RT1}
  92     OpenStackOperations.Update Router    ${ROUTER}    ${cmd}
  93     OpenStackOperations.Show Router    ${ROUTER}    -D
  94     ${output} =    OpenStackOperations.Execute Command on VM Instance    @{NETWORKS}[0]    @{VM_IP_NET10}[1]    ping6 -c 3 @{EXTRA_NW_IP}[0]
  95     BuiltIn.Should Contain    ${output}    64 bytes
  96     # clear off extra-routes before the next set of tests
  97     [Teardown]    BuiltIn.Run Keywords    OpenStackOperations.Update Router    ${ROUTER}    ${RT_CLEAR}
  98     ...    AND    OpenStackOperations.Show Router    ${ROUTER}    -D
  99     ...    AND    OpenStackOperations.Get Test Teardown Debugs
 100
 101 Create L3VPN
 102     ${net_id} =    OpenStackOperations.Get Net Id    @{NETWORKS}[0]
 103     ${tenant_id} =    OpenStackOperations.Get Tenant ID From Network    ${net_id}
 104     VpnOperations.VPN Create L3VPN    vpnid=@{VPN_INSTANCE_IDS}[0]    name=@{VPN_NAMES}[0]    rd=@{RDS}[0]    exportrt=@{RDS}[0]    importrt=@{RDS}[0]    tenantid=${tenant_id}
 105     ${resp}=    VpnOperations.VPN Get L3VPN    vpnid=@{VPN_INSTANCE_IDS}[0]
 106     BuiltIn.Should Contain    ${resp}    @{VPN_INSTANCE_IDS}[0]
 107
 108 Associate L3VPN To Routers
 109     ${router_id} =    OpenStackOperations.Get Router Id    ${ROUTER}
 110     VpnOperations.Associate VPN to Router    routerid=${router_id}    vpnid=@{VPN_INSTANCE_IDS}[0]
 111     ${resp}=    VpnOperations.VPN Get L3VPN    vpnid=@{VPN_INSTANCE_IDS}[0]
 112     BuiltIn.Should Contain    ${resp}    ${router_id}
 113
 114 Verify L3VPN Datapath With Router Association
 115     BuiltIn.Log    Verify VPN interfaces, FIB entries and Flow table
 116     ${vm_ips} =    BuiltIn.Create List    @{VM_IP_NET10}    @{VM_IP_NET20}
 117     BuiltIn.Wait Until Keyword Succeeds    30s    10s    Utils.Check For Elements At URI    ${VPN_IFACES_URL}    ${vm_ips}
 118     ${RD} =    Strip String    @{RDS}[0]    characters="[]
 119     BuiltIn.Wait Until Keyword Succeeds    60s    15s    Utils.Check For Elements At URI    ${CONFIG_API}/odl-fib:fibEntries/vrfTables/${RD}/    ${vm_ips}
 120     Verify Flows Are Present For L3VPN On All Compute Nodes    ${vm_ips}
 121     BuiltIn.Wait Until Keyword Succeeds    30s    10s    VpnOperations.Verify GWMAC Entry On ODL    ${GWMAC_ADDRS}
 122     Verify GWMAC Flow Entry On Flow Table On All Compute Nodes    ipv6
 123     BuiltIn.Log    Check datapath from network1 to network2
 124     ${dst_ip_list} =    BuiltIn.Create List    @{VM_IP_NET10}[1]    @{VM_IP_NET20}
 125     OpenStackOperations.Test Operations From Vm Instance    @{NETWORKS}[0]    @{VM_IP_NET10}[0]    ${dst_ip_list}
 126     BuiltIn.Log    Check datapath from network2 to network1
 127     ${dst_ip_list} =    BuiltIn.Create List    @{VM_IP_NET20}[1]    @{VM_IP_NET10}
 128     OpenStackOperations.Test Operations From Vm Instance    @{NETWORKS}[1]    @{VM_IP_NET20}[0]    ${dst_ip_list}
 129
 130 Dissociate L3VPN From Routers
 131     ${router_id}=    OpenStackOperations.Get Router Id    ${ROUTER}
 132     VpnOperations.Dissociate VPN to Router    routerid=${router_id}    vpnid=@{VPN_INSTANCE_IDS}[0]
 133     ${resp}=    VpnOperations.VPN Get L3VPN    vpnid=@{VPN_INSTANCE_IDS}[0]
 134     BuiltIn.Should Not Contain    ${resp}    ${router_id}
 135
 136 Delete Router And Router Interfaces With L3VPN
 137     ${router_id}=    OpenStackOperations.Get Router Id    ${ROUTER}
 138     VpnOperations.Associate VPN to Router    routerid=${router_id}    vpnid=@{VPN_INSTANCE_IDS}[0]
 139     ${resp} =    VpnOperations.VPN Get L3VPN    vpnid=@{VPN_INSTANCE_IDS}[0]
 140     BuiltIn.Should Contain    ${resp}    ${router_id}
 141     : FOR    ${INTERFACE}    IN    @{SUBNETS}
 142     \    OpenStackOperations.Remove Interface    ${ROUTER}    ${INTERFACE}
 143     ${interface_output} =    OpenStackOperations.Show Router Interface    ${ROUTER}
 144     : FOR    ${INTERFACE}    IN    @{SUBNETS}
 145     \    ${subnet_id} =    OpenStackOperations.Get Subnet Id    ${INTERFACE}
 146     \    BuiltIn.Should Not Contain    ${interface_output}    ${subnet_id}
 147     OpenStackOperations.Delete Router    ${ROUTER}
 148     ${router_output} =    OpenStackOperations.List Routers
 149     BuiltIn.Should Not Contain    ${router_output}    ${ROUTER}
 150     @{router_list} =    BuiltIn.Create List    ${ROUTER}
 151     BuiltIn.Wait Until Keyword Succeeds    3s    1s    Utils.Check For Elements Not At URI    ${ROUTER_URL}    ${router_list}
 152     ${resp}=    VpnOperations.VPN Get L3VPN    vpnid=@{VPN_INSTANCE_IDS}[0]
 153     BuiltIn.Should Not Contain    ${resp}    ${router_id}
 154     Verify GWMAC Flow Entry Removed From Flow Table On All Compute Nodes
 155
 156 Delete Router With NonExistentRouter Name
 157     ${rc}    ${output}=    Run And Return Rc And Output    neutron router-delete nonExistentRouter
 158     BuiltIn.Should Match Regexp    ${output}    Unable to find router with name or id 'nonExistentRouter'|Unable to find router\\(s\\) with id\\(s\\) 'nonExistentRouter'
 159
 160 Associate L3VPN To Networks
 161     ${network1_id} =    OpenStackOperations.Get Net Id    @{NETWORKS}[0]
 162     ${network2_id} =    OpenStackOperations.Get Net Id    @{NETWORKS}[1]
 163     VpnOperations.Associate L3VPN To Network    networkid=${network1_id}    vpnid=@{VPN_INSTANCE_IDS}[0]
 164     ${resp} =    VpnOperations.VPN Get L3VPN    vpnid=@{VPN_INSTANCE_IDS}[0]
 165     BuiltIn.Should Contain    ${resp}    ${network1_id}
 166     VpnOperations.Associate L3VPN To Network    networkid=${network2_id}    vpnid=@{VPN_INSTANCE_IDS}[0]
 167     ${resp} =    VpnOperations.VPN Get L3VPN    vpnid=@{VPN_INSTANCE_IDS}[0]
 168     BuiltIn.Should Contain    ${resp}    ${network2_id}
 169
 170 Dissociate L3VPN From Networks
 171     ${network1_id} =    OpenStackOperations.Get Net Id    @{NETWORKS}[0]
 172     ${network2_id} =    OpenStackOperations.Get Net Id    @{NETWORKS}[1]
 173     VpnOperations.Dissociate L3VPN From Networks    networkid=${network1_id}    vpnid=@{VPN_INSTANCE_IDS}[0]
 174     ${resp}=    VpnOperations.VPN Get L3VPN    vpnid=@{VPN_INSTANCE_IDS}[0]
 175     BuiltIn.Should Not Contain    ${resp}    ${network1_id}
 176     VpnOperations.Dissociate L3VPN From Networks    networkid=${network2_id}    vpnid=@{VPN_INSTANCE_IDS}[0]
 177     ${resp}=    VpnOperations.VPN Get L3VPN    vpnid=@{VPN_INSTANCE_IDS}[0]
 178     BuiltIn.Should Not Contain    ${resp}    ${network2_id}
 179
 180 Delete L3VPN
 181     VpnOperations.VPN Delete L3VPN    vpnid=@{VPN_INSTANCE_IDS}[0]
 182
 183 Create Multiple L3VPN
 184     ${net_id} =    Get Net Id    @{NETWORKS}[0]
 185     ${tenant_id} =    Get Tenant ID From Network    ${net_id}
 186     VpnOperations.VPN Create L3VPN    vpnid=@{VPN_INSTANCE_IDS}[0]    name=@{VPN_NAMES}[0]    rd=@{RDS}[0]    exportrt=@{RDS}[0]    importrt=@{RDS}[0]    tenantid=${tenant_id}
 187     VpnOperations.VPN Create L3VPN    vpnid=@{VPN_INSTANCE_IDS}[1]    name=@{VPN_NAMES}[1]    rd=@{RDS}[1]    exportrt=@{RDS}[1]    importrt=@{RDS}[1]    tenantid=${tenant_id}
 188     VpnOperations.VPN Create L3VPN    vpnid=@{VPN_INSTANCE_IDS}[2]    name=@{VPN_NAMES}[2]    rd=@{RDS}[2]    exportrt=@{RDS}[2]    importrt=@{RDS}[2]    tenantid=${tenant_id}
 189     ${resp}=    VpnOperations.VPN Get L3VPN    vpnid=@{VPN_INSTANCE_IDS}[0]
 190     BuiltIn.Should Contain    ${resp}    @{VPN_INSTANCE_IDS}[0]
 191     ${resp}=    VpnOperations.VPN Get L3VPN    vpnid=@{VPN_INSTANCE_IDS}[1]
 192     BuiltIn.Should Contain    ${resp}    @{VPN_INSTANCE_IDS}[1]
 193     ${resp}=    VpnOperations.VPN Get L3VPN    vpnid=@{VPN_INSTANCE_IDS}[2]
 194     BuiltIn.Should Contain    ${resp}    @{VPN_INSTANCE_IDS}[2]
 195
 196 *** Keywords ***
 197 Suite Setup
 198     VpnOperations.Basic Suite Setup
 199     OpenStackOperations.Create Network    @{NETWORKS}[0]
 200     OpenStackOperations.Create Network    @{NETWORKS}[1]
 201     BuiltIn.Wait Until Keyword Succeeds    3s    1s    Utils.Check For Elements At URI    ${NETWORK_URL}    ${NETWORKS}
 202     OpenStackOperations.Update Network    @{NETWORKS}[0]    additional_args=--description ${UPDATE_NETWORK}
 203     ${output} =    OpenStackOperations.Show Network    @{NETWORKS}[0]
 204     BuiltIn.Should Contain    ${output}    ${UPDATE_NETWORK}
 205     ${net1_additional_args}=    BuiltIn.Catenate    --ip-version=6 --ipv6-address-mode=slaac --ipv6-ra-mode=slaac ${NET1_IPV6_ADDR_POOL}
 206     ${net2_additional_args}=    BuiltIn.Catenate    --ip-version=6 --ipv6-address-mode=slaac --ipv6-ra-mode=slaac ${NET2_IPV6_ADDR_POOL}
 207     OpenStackOperations.Create SubNet    @{NETWORKS}[0]    @{SUBNETS}[0]    @{SUBNET_CIDRS}[0]    ${net1_additional_args}
 208     OpenStackOperations.Create SubNet    @{NETWORKS}[1]    @{SUBNETS}[1]    @{SUBNET_CIDRS}[1]    ${net2_additional_args}
 209     BuiltIn.Wait Until Keyword Succeeds    3s    1s    Utils.Check For Elements At URI    ${SUBNETWORK_URL}    ${SUBNETS}
 210     OpenStackOperations.Update SubNet    @{SUBNETS}[0]    additional_args=--description ${UPDATE_SUBNET}
 211     ${output} =    OpenStackOperations.Show SubNet    @{SUBNETS}[0]
 212     BuiltIn.Should Contain    ${output}    ${UPDATE_SUBNET}
 213     OpenStackOperations.Create Router    ${ROUTER}
 214     ${router_list} =    BuiltIn.Create List    ${ROUTER}
 215     BuiltIn.Wait Until Keyword Succeeds    3s    1s    Utils.Check For Elements At URI    ${ROUTER_URL}    ${router_list}
 216     : FOR    ${interface}    IN    @{SUBNETS}
 217     \    OpenStackOperations.Add Router Interface    ${ROUTER}    ${interface}
 218     ${interface_output} =    OpenStackOperations.Show Router Interface    ${ROUTER}
 219     : FOR    ${interface}    IN    @{SUBNETS}
 220     \    ${subnet_id} =    OpenStackOperations.Get Subnet Id    ${interface}
 221     \    BuiltIn.Should Contain    ${interface_output}    ${subnet_id}
 222     ${GWMAC_ADDRS}    ${GWIP_ADDRS} =    VpnOperations.Get Gateway MAC And IP Address    ${ROUTER}    ${IP6_REGEX}
 223     BuiltIn.Set Suite Variable    ${GWMAC_ADDRS}
 224     BuiltIn.Set Suite Variable    ${GWIP_ADDRS}
 225     OpenStackOperations.Create Allow All SecurityGroup    ${SECURITY_GROUP}    IPv6
 226     ${allowed_address_pairs_args} =    BuiltIn.Set Variable    --allowed-address ip-address=@{EXTRA_NW_SUBNET}[0] --allowed-address ip-address=@{EXTRA_NW_SUBNET}[1]
 227     Create Port    @{NETWORKS}[0]    @{PORTS}[0]    sg=${SECURITY_GROUP}    additional_args=${allowed_address_pairs_args}
 228     Create Port    @{NETWORKS}[0]    @{PORTS}[1]    sg=${SECURITY_GROUP}    additional_args=${allowed_address_pairs_args}
 229     Create Port    @{NETWORKS}[1]    @{PORTS}[2]    sg=${SECURITY_GROUP}    additional_args=${allowed_address_pairs_args}
 230     Create Port    @{NETWORKS}[1]    @{PORTS}[3]    sg=${SECURITY_GROUP}    additional_args=${allowed_address_pairs_args}
 231     BuiltIn.Wait Until Keyword Succeeds    3s    1s    Check For Elements At URI    ${PORT_URL}    ${PORTS}
 232     OpenStackOperations.Update Port    @{PORTS}[0]    additional_args=--name ${UPDATE_PORT}
 233     ${output} =    Show Port    ${UPDATE_PORT}
 234     BuiltIn.Should Contain    ${output}    ${UPDATE_PORT}
 235     OpenStackOperations.Update Port    ${UPDATE_PORT}    additional_args=--name @{PORTS}[0]
 236     OpenStackOperations.Create Vm Instance With Port On Compute Node    @{PORTS}[0]    @{NET_1_VMS}[0]    ${OS_CMP1_HOSTNAME}    sg=${SECURITY_GROUP}
 237     OpenStackOperations.Create Vm Instance With Port On Compute Node    @{PORTS}[1]    @{NET_1_VMS}[1]    ${OS_CMP2_HOSTNAME}    sg=${SECURITY_GROUP}
 238     OpenStackOperations.Create Vm Instance With Port On Compute Node    @{PORTS}[2]    @{NET_2_VMS}[0]    ${OS_CMP1_HOSTNAME}    sg=${SECURITY_GROUP}
 239     OpenStackOperations.Create Vm Instance With Port On Compute Node    @{PORTS}[3]    @{NET_2_VMS}[1]    ${OS_CMP2_HOSTNAME}    sg=${SECURITY_GROUP}
 240     ${vms}=    BuiltIn.Create List    @{NET_1_VMS}    @{NET_2_VMS}
 241     : FOR    ${vm}    IN    @{vms}
 242     \    OpenStackOperations.Poll VM Is ACTIVE    ${vm}
 243     BuiltIn.Wait Until Keyword Succeeds    30s    10s    Wait For Routes To Propogate    ${NETWORKS}    ${SUBNET_CIDRS}
 244     ${prefix_net10} =    Replace String    @{SUBNET_CIDRS}[0]    ::/64    (:[a-f0-9]{,4}){,4}
 245     ${status}    ${message}    Run Keyword And Ignore Error    BuiltIn.Wait Until Keyword Succeeds    3x    60s    OpenStackOperations.Collect VM IPv6 SLAAC Addresses
 246     ...    fail_on_none=true    vm_list=${NET_1_VMS}    network=@{NETWORKS}[0]    subnet=${prefix_net10}
 247     ${prefix_net20} =    Replace String    @{SUBNET_CIDRS}[1]    ::/64    (:[a-f0-9]{,4}){,4}
 248     ${status}    ${message}    Run Keyword And Ignore Error    BuiltIn.Wait Until Keyword Succeeds    3x    60s    OpenStackOperations.Collect VM IPv6 SLAAC Addresses
 249     ...    fail_on_none=true    vm_list=${NET_2_VMS}    network=@{NETWORKS}[1]    subnet=${prefix_net20}
 250     ${VM_IP_NET10} =    OpenStackOperations.Collect VM IPv6 SLAAC Addresses    fail_on_none=false    vm_list=${NET_1_VMS}    network=@{NETWORKS}[0]    subnet=${prefix_net10}
 251     ${VM_IP_NET20} =    OpenStackOperations.Collect VM IPv6 SLAAC Addresses    fail_on_none=false    vm_list=${NET_2_VMS}    network=@{NETWORKS}[1]    subnet=${prefix_net20}
 252     ${VM_INSTANCES} =    Collections.Combine Lists    ${NET_1_VMS}    ${NET_2_VMS}
 253     ${VM_IPS}=    Collections.Combine Lists    ${VM_IP_NET10}    ${VM_IP_NET20}
 254     ${LOOP_COUNT}    BuiltIn.Get Length    ${NET_1_VMS}
 255     : FOR    ${index}    IN RANGE    0    ${LOOP_COUNT}
 256     \    ${status}    ${message}    Run Keyword And Ignore Error    BuiltIn.Should Not Contain    @{VM_IPS}[${index}]    None
 257     \    Run Keyword If    '${status}' == 'FAIL'    OpenStack CLI    openstack console log show @{VM_INSTANCES}[${index}]    30s
 258     OpenStackOperations.Copy DHCP Files From Control Node
 259     BuiltIn.Set Suite Variable    ${VM_IP_NET10}
 260     BuiltIn.Set Suite Variable    ${VM_IP_NET20}
 261     BuiltIn.Should Not Contain    ${VM_IP_NET10}    None
 262     BuiltIn.Should Not Contain    ${VM_IP_NET20}    None
 263     OpenStackOperations.Show Debugs    @{NET_1_VMS}    @{NET_2_VMS}
 264     OpenStackOperations.Get Suite Debugs
 265
 266 Suite Teardown
 267     [Documentation]    Delete the setup
 268     BuiltIn.Run Keyword And Ignore Error    VpnOperations.VPN Delete L3VPN    vpnid=@{VPN_INSTANCE_IDS}[0]
 269     BuiltIn.Run Keyword And Ignore Error    VpnOperations.VPN Delete L3VPN    vpnid=@{VPN_INSTANCE_IDS}[1]
 270     BuiltIn.Run Keyword And Ignore Error    VpnOperations.VPN Delete L3VPN    vpnid=@{VPN_INSTANCE_IDS}[2]
 271     OpenStackOperations.OpenStack Suite Teardown