csit/suites/openflowplugin/Bug_Validation/8723.robot

   1 *** Settings ***
   2 Documentation       Test suite for Split connection bug.
   3
   4 Library             XML
   5 Library             SSHLibrary
   6 Library             RequestsLibrary
   7 Library             Collections
   8 Resource            ../../../libraries/MininetKeywords.robot
   9 Resource            ../../../libraries/FlowLib.robot
  10 Resource            ../../../libraries/OVSDB.robot
  11 Resource            ../../../variables/Variables.robot
  12 Resource            ../../../variables/openflowplugin/Variables.robot
  13
  14 Suite Setup         Initialization Phase
  15 Suite Teardown      Final Phase
  16
  17
  18 *** Variables ***
  19 ${ODL_OF_PORT1}     6653
  20 ${SH_CNTL_CMD}      ovs-vsctl list Controller
  21 ${lprompt}          mininet>
  22
  23
  24 *** Test Cases ***
  25 Create Two Active Switch Connections To Controller And Check OVS Connections
  26     [Documentation]    Make a second connection from switch s1 to a controller
  27     ${controller_opt} =    BuiltIn.Set Variable
  28     ${controller_opt} =    BuiltIn.Catenate
  29     ...    ${controller_opt}
  30     ...    ${SPACE}tcp:${ODL_SYSTEM_IP}:${ODL_OF_PORT}${SPACE}tcp:${ODL_SYSTEM_IP}:${ODL_OF_PORT1}
  31     OVSDB.Set Controller In OVS Bridge    ${TOOLS_SYSTEM_IP}    s1    ${controller_opt}
  32     BuiltIn.Wait Until Keyword Succeeds    20s    1s    OVSDB.Check OVS OpenFlow Connections    ${TOOLS_SYSTEM_IP}    1
  33     Check Master Connection    30
  34     [Teardown]    Report_Failure_Due_To_Bug    8723
  35
  36 Restore original Connection To Controller And Check OVS Connection
  37     [Documentation]    Restore original Connection To Controller And Check OVS Connection
  38     ${controller_opt} =    BuiltIn.Set Variable
  39     ${controller_opt} =    BuiltIn.Catenate    ${controller_opt}    ${SPACE}tcp:${ODL_SYSTEM_IP}:${ODL_OF_PORT}
  40     OVSDB.Set Controller In OVS Bridge    ${TOOLS_SYSTEM_IP}    s1    ${controller_opt}
  41     BuiltIn.Wait Until Keyword Succeeds    20s    1s    OVSDB.Check OVS OpenFlow Connections    ${TOOLS_SYSTEM_IP}    1
  42     Check Master Connection    20
  43     FlowLib.Check Number Of Flows    1
  44     [Teardown]    Report_Failure_Due_To_Bug    8723
  45
  46
  47 *** Keywords ***
  48 Initialization Phase
  49     [Documentation]    Starts mininet and verify if topology is in operational datastore.
  50     ${mininet_conn_id} =    MininetKeywords.Start Mininet Single Controller
  51     BuiltIn.Set Suite Variable    ${mininet_conn_id}
  52     RequestsLibrary.Create Session
  53     ...    session
  54     ...    http://${ODL_SYSTEM_IP}:${RESTCONFPORT}
  55     ...    auth=${AUTH}
  56     ...    headers=${HEADERS_XML}
  57     BuiltIn.Wait Until Keyword Succeeds    10s    1s    FlowLib.Check Switches In Topology    1
  58
  59 Final Phase
  60     [Documentation]    Stops mininet.
  61     BuiltIn.Run Keyword And Ignore Error    RequestsLibrary.Delete Request    session    ${RFC8040_NODES_API}
  62     MininetKeywords.Stop Mininet And Exit    ${mininet_conn_id}
  63     RequestsLibrary.Delete All Sessions
  64
  65 Check Master Connection
  66     [Documentation]    Execute OvsVsctl List Controllers Command and check for master connection.
  67     [Arguments]    ${timeout}=20
  68     ${output} =    Utils.Run Command On Mininet
  69     ...    ${TOOLS_SYSTEM_IP}
  70     ...    sudo timeout --signal=KILL ${timeout} ovsdb-client monitor Controller target,role
  71     BuiltIn.Set Suite Variable    ${output}
  72     Should Contain    ${output}    master
  73     Log    ${output}
  74     RETURN    ${output}