csit/suites/openflowplugin/Performance/010_Cbench.robot

   1 *** Settings ***
   2 Documentation     Cbench Latency and Throughput tests can be run from an external
   3 ...               cbench.
   4 ...               If cbench is run with a medium number of switches or higher (e.g. 32+)
   5 ...               the normal openflow operations seem to break.
   6 ...               BUG: https://bugs.opendaylight.org/show_bug.cgi?id=2897
   7 Suite Setup       Cbench Suite Setup
   8 Test Teardown     Log Results As Zero If Cbench Timed Out
   9 Force Tags        cbench
  10 Library           String
  11 Library           Process
  12 Resource          ../../../libraries/Utils.robot
  13 Resource          ../../../libraries/KarafKeywords.robot
  14
  15 *** Variables ***
  16 ${throughput_threshold}    30000
  17 ${latency_threshold}    10000
  18 ${switch_count}    8
  19 ${duration_in_secs}    12
  20 ${loops}          10
  21 ${num_of_unique_macs}    10000
  22 ${cbench_system}    ${TOOLS_SYSTEM_IP}
  23 ${cbench_executable}    /usr/local/bin/cbench
  24 ${throughput_results_file}    throughput.csv
  25 ${latency_results_file}    latency.csv
  26
  27 *** Testcases ***
  28 Cbench Latency Test
  29     [Documentation]    cbench executed in default latency mode. Test parameters have defaults, but can be overridden
  30     ...    on the pybot command line
  31     [Tags]    latency
  32     [Timeout]    ${test_timeout}
  33     Log    Cbench tests using ${loops} iterations of ${duration_in_secs} second tests. Switch Count: ${switch_count}. Unique MACS to cycle: ${num_of_unique_macs}
  34     Run Cbench And Log Results    -m ${duration_in_ms} -M ${num_of_unique_macs} -s ${switch_count} -l ${loops}    ${latency_threshold}    ${latency_results_file}
  35
  36 Cbench Throughput Test
  37     [Documentation]    cbench executed in throughput mode (-t). Test parameters have defaults, but can be overridden
  38     ...    on the pybot command line
  39     [Tags]    throughput
  40     [Timeout]    ${test_timeout}
  41     Log    Cbench tests using ${loops} iterations of ${duration_in_secs} second tests. Switch Count: ${switch_count}. Unique MACS to cycle: ${num_of_unique_macs}
  42     Run Cbench And Log Results    -t -m ${duration_in_ms} -M ${num_of_unique_macs} -s ${switch_count} -l ${loops}    ${throughput_threshold}    ${throughput_results_file}
  43     [Teardown]    Report_Failure_Due_To_Bug    6176
  44
  45 *** Keywords ***
  46 Run Cbench And Log Results
  47     [Arguments]    ${cbench_args}    ${average_threshold}    ${output_filename}=results.csv
  48     ##If the cbench command fails to return, the keyword to run it will time out.    The test tear
  49     ##down can catch this problem and log the results as zero.    However, we need to know which
  50     ##file to log to, so setting it as a suite variable here.
  51     Set Suite Variable    ${output_filename}
  52     ${output}=    Run Keyword If    "${cbench_system}" == "localhost"    Run Process    ${cbench_executable}    -c    ${ODL_SYSTEM_IP}
  53     ...    ${cbench_args}
  54     ...    ELSE    Run Command On Remote System    ${cbench_system}    ${cbench_executable} -c ${ODL_SYSTEM_IP} ${cbench_args}    prompt_timeout=${test_timeout}
  55     Log    ${output}
  56     Should Contain    ${output}    RESULT
  57     ${result_line}=    Get Lines Containing String    ${output}    RESULT
  58     @{results_list}=    Split String    ${result_line}
  59     Log    ${results_list[5]}
  60     Log    ${results_list[7]}
  61     @{result_name_list}=    Split String    ${results_list[5]}    /
  62     @{result_value_list}=    Split String    ${results_list[7]}    /
  63     ${num_stats}=    Get Length    ${result_name_list}
  64     : FOR    ${i}    IN RANGE    0    ${num_stats}
  65     \    Log    ${result_name_list[${i}]} :: ${result_value_list[${i}]}
  66     ${min}=    Set Variable    ${result_value_list[${0}]}
  67     ${max}=    Set Variable    ${result_value_list[${1}]}
  68     ${average}=    Set Variable    ${result_value_list[${2}]}
  69     ${stdev}=    Set Variable    ${result_value_list[${3}]}
  70     ${date}=    Get Time    d,m,s
  71     Log    CBench Result: ${date},${cbench_args},${min},${max},${average},${stdev}
  72     Log Results And Determine Status    ${min}    ${max}    ${average}    ${average_threshold}    ${output_filename}
  73
  74 Cbench Suite Setup
  75     Append To File    ${latency_results_file}    LATENCY_MIN,LATENCY_MAX,LATENCY_AVERAGE\n
  76     Append To File    ${throughput_results_file}    THROUGHPUT_MIN,THROUGHPUT_MAX,THROUGHPUT_AVERAGE\n
  77     ${duration_in_ms}    Evaluate    ${duration_in_secs} * 1000
  78     Set Suite Variable    ${duration_in_ms}
  79     ##Setting the test timeout dynamically in case larger values on command line override default
  80     ${test_timeout}    Evaluate    (${loops} * ${duration_in_secs}) * 1.5
  81     Set Suite Variable    ${test_timeout}
  82     Run Keyword If    "${cbench_system}" == "localhost"    File Should Exist    ${cbench_executable}
  83     ...    ELSE    Verify File Exists On Remote System    ${cbench_system}    ${cbench_executable}
  84     Should Be True    ${loops} >= 2    If number of loops is less than 2, cbench will not run
  85     Verify Feature Is Installed    odl-openflowplugin-drop-test
  86     Issue Command On Karaf Console    dropallpacketsrpc on
  87
  88 Log Results And Determine Status
  89     [Arguments]    ${min}    ${max}    ${average}    ${threshold}    ${output_file}
  90     Append To File    ${output_file}    ${min},${max},${average}\n
  91     Should Be True    ${average} > ${threshold}    ${average} flow_mods per/sec did not exceed threshold of ${threshold}
  92
  93 Log Results As Zero If Cbench Timed Out
  94     Run Keyword If Timeout Occurred    Log Results And Determine Status    0    0    0    0    ${output_filename}