csit/suites/openflowplugin/Reconciliation/010_Group_Flows.robot

   1 *** Settings ***
   2 Documentation     Test reconciliation of chained groups and flows after switch connection and controller are restarted.
   3 Suite Setup       Initialization Phase
   4 Suite Teardown    Final Phase
   5 Library           RequestsLibrary
   6 Resource          ../../../libraries/ClusterManagement.robot
   7 Resource          ../../../libraries/TemplatedRequests.robot
   8 Resource          ../../../libraries/MininetKeywords.robot
   9 Resource          ../../../libraries/FlowLib.robot
  10 Resource          ../../../libraries/Utils.robot
  11 Resource          ../../../variables/Variables.robot
  12 Resource          ../../../variables/openflowplugin/Variables.robot
  13
  14 *** Variables ***
  15 ${SWITCHES}       3
  16 ${ITER}           100
  17 ${VAR_DIR}        ${CURDIR}/../../../variables/openflowplugin
  18
  19 *** Test Cases ***
  20 Add Group 1 In Every Switch
  21     [Documentation]    Add ${ITER} groups of type 1 in every switch.
  22     FOR    ${switch}    IN RANGE    1    ${switches+1}
  23         &{mapping}    BuiltIn.Create_Dictionary    NODE=openflow:${switch}
  24         TemplatedRequests.Post As Json Templated    folder=${VAR_DIR}/add-group-1    mapping=${mapping}    session=session    iterations=${iter}
  25     END
  26
  27 Add Group 2 In Every Switch
  28     [Documentation]    Add ${ITER} groups of type 2 in every switch.
  29     FOR    ${switch}    IN RANGE    1    ${switches+1}
  30         &{mapping}    BuiltIn.Create_Dictionary    NODE=openflow:${switch}
  31         TemplatedRequests.Post As Json Templated    folder=${VAR_DIR}/add-group-2    mapping=${mapping}    session=session    iterations=${iter}
  32     END
  33
  34 Add Flow to Group 2 In Every Switch
  35     [Documentation]    Add ${ITER} flows to group type 2 in every switch.
  36     FOR    ${switch}    IN RANGE    1    ${switches+1}
  37         &{mapping}    BuiltIn.Create_Dictionary    NODE=openflow:${switch}
  38         TemplatedRequests.Post As Json Templated    folder=${VAR_DIR}/add-flow    mapping=${mapping}    session=session    iterations=${ITER}
  39     END
  40
  41 Start Mininet Linear
  42     [Documentation]    Start Mininet Linear with ${SWITCHES} switches.
  43     MininetKeywords.Start Mininet Linear    ${SWITCHES}
  44
  45 Check Linear Topology
  46     [Documentation]    Check Linear Topology.
  47     BuiltIn.Wait Until Keyword Succeeds    30s    1s    FlowLib.Check Linear Topology    ${SWITCHES}
  48
  49 Check Flows In Operational DS
  50     [Documentation]    Check Groups after mininet starts.
  51     BuiltIn.Wait Until Keyword Succeeds    30s    1s    FlowLib.Check Number Of Flows    ${all_flows}
  52
  53 Check Groups In Operational DS
  54     [Documentation]    Check Flows after mininet starts.
  55     FlowLib.Check Number Of Groups    ${all_groups}
  56
  57 Check Flows In Switch
  58     [Documentation]    Check Flows after mininet starts.
  59     MininetKeywords.Check Flows In Mininet    ${mininet_conn_id}    ${all_flows}
  60
  61 Disconnect Mininet
  62     [Documentation]    Disconnect Mininet.
  63     Disconnect Controller Mininet
  64
  65 Check No Switches After Disconnect
  66     [Documentation]    Check no switches in topology.
  67     BuiltIn.Wait Until Keyword Succeeds    30s    1s    FlowLib.Check No Switches In Topology    ${SWITCHES}
  68
  69 Reconnect Mininet
  70     [Documentation]    Connect Mininet.
  71     Disconnect Controller Mininet    restore
  72
  73 Check Linear Topology After Mininet Reconnects
  74     [Documentation]    Check Linear Topology.
  75     BuiltIn.Wait Until Keyword Succeeds    30s    1s    FlowLib.Check Linear Topology    ${SWITCHES}
  76
  77 Remove Flows And Groups After Mininet Reconnects
  78     [Documentation]    Remove some groups and flows while network is down.
  79     FOR    ${switch}    IN RANGE    1    ${switches+1}
  80         RequestsLibrary.Delete Request    session    ${RFC8040_NODES_API}/node=openflow%3A${switch}/flow-node-inventory:table=0/flow=1
  81         RequestsLibrary.Delete Request    session    ${RFC8040_NODES_API}/node=openflow%3A${switch}/flow-node-inventory:group=1
  82         RequestsLibrary.Delete Request    session    ${RFC8040_NODES_API}/node=openflow%3A${switch}/flow-node-inventory:group=1000
  83     END
  84
  85 Check Flows In Operational DS After Mininet Reconnects
  86     [Documentation]    Check Flows after mininet starts.
  87     BuiltIn.Wait Until Keyword Succeeds    30s    1s    FlowLib.Check Number Of Flows    ${less_flows}
  88
  89 Check Groups In Operational DS After Mininet Reconnects
  90     [Documentation]    Check Flows after mininet starts.
  91     FlowLib.Check Number Of Groups    ${less_groups}
  92
  93 Check Flows In Switch After Mininet Reconnects
  94     [Documentation]    Check Flows after mininet starts.
  95     MininetKeywords.Check Flows In Mininet    ${mininet_conn_id}    ${less_flows}
  96
  97 Restart Controller
  98     [Documentation]    Stop and Start controller.
  99     # Try to stop contoller, if stop does not work or takes too long, kill controller.
 100     ${status}    ${result}=    BuiltIn.Run Keyword And Ignore Error    ClusterManagement.Stop_Members_From_List_Or_All
 101     BuiltIn.Run Keyword If    '${status}' != 'PASS'    ClusterManagement.Kill_Members_From_List_Or_All
 102     ClusterManagement.Start_Members_From_List_Or_All    wait_for_sync=False
 103
 104 Check Linear Topology After Controller Restarts
 105     [Documentation]    Check Linear Topology.
 106     BuiltIn.Wait Until Keyword Succeeds    300s    2s    FlowLib.Check Linear Topology    ${SWITCHES}
 107
 108 Check Flows In Operational DS After Controller Restarts
 109     [Documentation]    Check Flows after mininet starts.
 110     BuiltIn.Wait Until Keyword Succeeds    30s    1s    FlowLib.Check Number Of Flows    ${less_flows}
 111
 112 Check Groups In Operational DS After Controller Restarts
 113     [Documentation]    Check Flows after mininet starts.
 114     FlowLib.Check Number Of Groups    ${less_groups}
 115
 116 Check Flows In Switch After Controller Restarts
 117     [Documentation]    Check Flows after mininet starts.
 118     MininetKeywords.Check Flows In Mininet    ${mininet_conn_id}    ${less_flows}
 119
 120 Stop Mininet
 121     [Documentation]    Stop Mininet.
 122     MininetKeywords.Stop Mininet And Exit
 123
 124 Check No Switches
 125     [Documentation]    Check no switches in topology.
 126     BuiltIn.Wait Until Keyword Succeeds    5s    1s    FlowLib.Check No Switches In Topology    ${SWITCHES}
 127
 128 *** Keywords ***
 129 Initialization Phase
 130     [Documentation]    Create controller session and set variables.
 131     ClusterManagement.ClusterManagement_Setup
 132     # Still need to open controller HTTP session with name session because of old FlowLib.robot library dependency.
 133     RequestsLibrary.Create Session    session    http://${ODL_SYSTEM_IP}:${RESTCONFPORT}    auth=${AUTH}
 134     ${switches}    Convert To Integer    ${SWITCHES}
 135     ${iter}    Convert To Integer    ${ITER}
 136     ${all_groups}=    BuiltIn.Evaluate    ${switches} * ${iter} * 2
 137     ${less_groups}=    BuiltIn.Evaluate    ${all_groups} - ${switches} * 2
 138     # Stale flows/groups feature enabled in Boron onwards.
 139     ${all_flows}=    BuiltIn.Evaluate    ${switches} * ${iter+1}
 140     ${less_flows}=    BuiltIn.Evaluate    ${all_flows} - ${switches}
 141     # Stale flows/groups feature enabled in Boron onwards.
 142     BuiltIn.Set Suite Variable    ${switches}
 143     BuiltIn.Set Suite Variable    ${iter}
 144     BuiltIn.Set Suite Variable    ${all_groups}
 145     BuiltIn.Set Suite Variable    ${less_groups}
 146     BuiltIn.Set Suite Variable    ${all_flows}
 147     BuiltIn.Set Suite Variable    ${less_flows}
 148     BuiltIn.Set Suite Variable    ${no_flows}    ${SWITCHES}
 149
 150 Final Phase
 151     [Documentation]    Delete all sessions.
 152     ${command} =    BuiltIn.Set Variable    sudo iptables -v -F
 153     Utils.Run Command On Controller    cmd=${command}
 154     BuiltIn.Run Keyword And Ignore Error    RequestsLibrary.Delete Request    session    ${RFC8040_NODES_API}
 155     RequestsLibrary.Delete All Sessions
 156
 157 Disconnect Controller Mininet
 158     [Arguments]    ${action}=break
 159     [Documentation]    Break and restore controller to mininet connection via iptables.
 160     ${rule} =    BuiltIn.Set Variable    OUTPUT -p all --source ${ODL_SYSTEM_IP} --destination ${TOOLS_SYSTEM_IP} -j DROP
 161     ${command} =    BuiltIn.Set Variable If    '${action}'=='restore'    sudo /sbin/iptables -D ${rule}    sudo /sbin/iptables -I ${rule}
 162     Utils.Run Command On Controller    cmd=${command}
 163     ${command} =    BuiltIn.Set Variable    sudo /sbin/iptables -L -n
 164     ${output} =    Utils.Run Command On Controller    cmd=${command}
 165     BuiltIn.Log    ${output}