csit/suites/openstack/tempest/tempest.robot

   1 *** Settings ***
   2 Documentation     Test suite for running tempest tests. It is assumed that the test environment
   3 ...               is already deployed and ready.
   4 Suite Setup       Log In To Tempest Executor And Setup Test Environment
   5 Suite Teardown    Clean Up After Running Tempest
   6 Test Setup        SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
   7 Test Teardown     Run Keywords    Get Test Teardown Debugs
   8 Test Template     DevstackUtils.Run Tempest Tests
   9 Library           OperatingSystem
  10 Library           SSHLibrary
  11 Resource          ../../../libraries/DevstackUtils.robot
  12 Resource          ../../../libraries/OpenStackOperations.robot
  13 Resource          ../../../libraries/SetupUtils.robot
  14 Resource          ../../../libraries/Utils.robot
  15 Variables         ../../../variables/Variables.py
  16 Resource          ../../../variables/netvirt/Variables.robot
  17
  18 *** Variables ***
  19 ${blacklist_file}    /tmp/blacklist.txt
  20 @{stable/mitaka_exclusion_regexes}    test_routers_negative.RoutersNegativeIpV6Test.test_router_set_gateway_used_ip_returns_409    test_routers_negative.RoutersNegativeTest.test_router_set_gateway_used_ip_returns_409
  21 @{stable/newton_exclusion_regexes}    ${EMPTY}
  22 @{stable/ocata_exclusion_regexes}    ${EMPTY}
  23 ${tempest_config_file}    /opt/stack/tempest/etc/tempest.conf
  24 ${external_physical_network}    physnet1
  25 ${external_net_name}    external-net
  26 ${external_subnet_name}    external-subnet
  27 # Parameter values below are based on releng/builder - changing them requires updates in releng/builder as well
  28 ${external_gateway}    10.10.10.250
  29 ${external_subnet_allocation_pool}    start=10.10.10.2,end=10.10.10.249
  30 ${external_subnet}    10.10.10.0/24
  31
  32 *** Test Cases ***
  33 tempest.api.network
  34     ${TEST_NAME}    ${blacklist_file}    ${tempest_config_file}
  35
  36 tempest.scenario.test_network_basic_ops.TestNetworkBasicOps.test_connectivity_between_vms_on_different_networks
  37     ${TEST_NAME}    ${blacklist_file}    ${tempest_config_file}
  38
  39 tempest.scenario.test_network_basic_ops.TestNetworkBasicOps.test_hotplug_nic
  40     [Tags]    skip_if_stable/mitaka
  41     # Failing due to default security rules behavior missing in Mitaka
  42     ${TEST_NAME}    ${blacklist_file}    ${tempest_config_file}
  43
  44 tempest.scenario.test_network_basic_ops.TestNetworkBasicOps.test_mtu_sized_frames
  45     ${TEST_NAME}    ${blacklist_file}    ${tempest_config_file}
  46
  47 tempest.scenario.test_network_basic_ops.TestNetworkBasicOps.test_network_basic_ops
  48     ${TEST_NAME}    ${blacklist_file}    ${tempest_config_file}
  49
  50 tempest.scenario.test_network_basic_ops.TestNetworkBasicOps.test_preserve_preexisting_port
  51     ${TEST_NAME}    ${blacklist_file}    ${tempest_config_file}
  52
  53 tempest.scenario.test_network_basic_ops.TestNetworkBasicOps.test_router_rescheduling
  54     ${TEST_NAME}    ${blacklist_file}    ${tempest_config_file}
  55
  56 tempest.scenario.test_network_basic_ops.TestNetworkBasicOps.test_subnet_details
  57     ${TEST_NAME}    ${blacklist_file}    ${tempest_config_file}
  58
  59 tempest.scenario.test_aggregates_basic_ops.TestAggregatesBasicOps.test_aggregate_basic_ops
  60     ${TEST_NAME}    ${blacklist_file}    ${tempest_config_file}
  61
  62 tempest.scenario.test_network_advanced_server_ops.TestNetworkAdvancedServerOps.test_server_connectivity_pause_unpause
  63     ${TEST_NAME}    ${blacklist_file}    ${tempest_config_file}
  64
  65 tempest.scenario.test_network_advanced_server_ops.TestNetworkAdvancedServerOps.test_server_connectivity_stop_start
  66     ${TEST_NAME}    ${blacklist_file}    ${tempest_config_file}
  67
  68 tempest.scenario.test_network_advanced_server_ops.TestNetworkAdvancedServerOps.test_server_connectivity_reboot
  69     ${TEST_NAME}    ${blacklist_file}    ${tempest_config_file}
  70
  71 tempest.scenario.test_network_advanced_server_ops.TestNetworkAdvancedServerOps.test_server_connectivity_rebuild
  72     ${TEST_NAME}    ${blacklist_file}    ${tempest_config_file}
  73
  74 tempest.scenario.test_network_advanced_server_ops.TestNetworkAdvancedServerOps.test_server_connectivity_suspend_resume
  75     ${TEST_NAME}    ${blacklist_file}    ${tempest_config_file}
  76
  77 tempest.scenario.test_server_basic_ops.TestServerBasicOps.test_server_basic_ops
  78     ${TEST_NAME}    ${blacklist_file}    ${tempest_config_file}
  79
  80 tempest.scenario.test_network_basic_ops.TestNetworkBasicOps.test_port_security_macspoofing_port
  81     [Tags]    skip_if_transparent    skip_if_stable/mitaka
  82     # Failing due to default security rules behavior missing in Mitaka, and also in all transparent runs
  83     ${TEST_NAME}    ${blacklist_file}    ${tempest_config_file}
  84
  85 *** Keywords ***
  86 Log In To Tempest Executor And Setup Test Environment
  87     [Documentation]    Initialize SetupUtils, open SSH connection to a devstack system and source the openstack
  88     ...    credentials needed to run the tempest tests. The (sometimes empty) tempest blacklist file will be created
  89     ...    and pushed to the tempest executor.
  90     Create Blacklist File
  91     SetupUtils.Setup_Utils_For_Setup_And_Teardown
  92     # source_pwd is expected to exist in the below Create Network, Create Subnet keywords.    Might be a bug.
  93     ${source_pwd}    Set Variable    yes
  94     Set Suite Variable    ${source_pwd}
  95     # Tempest tests need an existing external network in order to create routers.
  96     Create Network    ${external_net_name}    --router:external --provider:network_type=flat --provider:physical_network=${PUBLIC_PHYSICAL_NETWORK}
  97     Create Subnet    ${external_net_name}    ${external_subnet_name}    ${external_subnet}    --gateway ${external_gateway} --allocation-pool ${external_subnet_allocation_pool}
  98     List Networks
  99     ${control_node_conn_id}=    SSHLibrary.Open Connection    ${OS_CONTROL_NODE_IP}    prompt=${DEFAULT_LINUX_PROMPT_STRICT}
 100     Utils.Flexible SSH Login    ${OS_USER}
 101     Write Commands Until Prompt    source ${DEVSTACK_DEPLOY_PATH}/openrc admin admin
 102     Write Commands Until Prompt    sudo rm -rf /opt/stack/tempest/.testrepository
 103     ${net_id}=    Get Net Id    ${external_net_name}    ${control_node_conn_id}
 104     Tempest Conf Add External Network    ${net_id}
 105
 106 Tempest Conf Add External Network
 107     [Arguments]    ${external_network_id}
 108     [Documentation]    Tempest will be run with a config file - this function will add the
 109     ...    given external network ID to the configuration file.
 110     Modify Config In File On Existing SSH Connection    ${tempest_config_file}    set    network    public_network_id    ${external_network_id}
 111     Modify Config In File On Existing SSH Connection    ${tempest_config_file}    set    DEFAULT    debug    False
 112     Modify Config In File On Existing SSH Connection    ${tempest_config_file}    set    DEFAULT    log_level    INFO
 113     Write Commands Until Prompt    sudo cat ${tempest_config_file}
 114     Write Commands Until Prompt    sudo chmod 777 ${tempest_config_file}
 115
 116 Modify Config In File On Existing SSH Connection
 117     [Arguments]    ${config_file}    ${modifier}    ${config_section}    ${config_key}    ${config_value}=${EMPTY}
 118     [Documentation]    uses crudini to populate oslo cofg file.
 119     # this keyword is only one line so seems like extra overhead, but this may be a good candidate to move
 120     # to a library at some point, when/if other suites need to use it, so wanted to make it generic.
 121     Write Commands Until Prompt    sudo -E crudini --${modifier} ${config_file} ${config_section} ${config_key} ${config_value}
 122
 123 Clean Up After Running Tempest
 124     [Documentation]    Clean up any extra leftovers that were created to allow tempest tests to run.
 125     Delete Network    ${external_net_name}
 126     List Networks
 127     Close All Connections
 128
 129 Create Blacklist File
 130     [Documentation]    For each exclusion regex in the required @{${OPENSTACK_BRANCH}_exclusion_regexes} list a new
 131     ...    line will be created in the required ${blacklist_file} location. This file is pushed to the OS_CONTROL_NODE
 132     ...    which is assumed to be the tempest executor.
 133     OperatingSystem.Create File    ${blacklist_file}
 134     : FOR    ${exclusion}    IN    @{${OPENSTACK_BRANCH}_exclusion_regexes}
 135     \    OperatingSystem.Append To File    ${blacklist_file}    ${exclusion}\n
 136     Log File    ${blacklist_file}
 137     SSHKeywords.Copy File To Remote System    ${OS_CONTROL_NODE_IP}    ${blacklist_file}    ${blacklist_file}