csit/suites/ovsdb/Netvirt_Cluster/010_Ovsdb_Netvirt_flow.robot

   1 *** Settings ***
   2 Documentation     Test suite for Ovsdb Southbound Cluster
   3 Suite Setup       Create Controller Sessions
   4 Suite Teardown    Delete All Sessions
   5 Library           RequestsLibrary
   6 Resource          ../../../libraries/ClusterOvsdb.robot
   7 Resource          ../../../libraries/ClusterKeywords.robot
   8 Resource          ../../../libraries/MininetKeywords.robot
   9 Variables         ../../../variables/Variables.py
  10 Library           ../../../libraries/Common.py
  11 Resource          ../../../libraries/Utils.robot
  12 Resource          ../../../libraries/OVSDB.robot
  13 Resource          ../../../libraries/KarafKeywords.robot
  14
  15 *** Variables ***
  16 ${OVSDB_CONFIG_DIR}    ${CURDIR}/../../../variables/ovsdb
  17 @{node_list}      ovsdb://uuid/
  18 ${EXT_NET1_ID}    7da709ff-397f-4778-a0e8-994811272fdb
  19 ${EXT_SUBNET1_ID}    00289199-e288-464a-ab2f-837ca67101a7
  20 ${TNT1_ID}        cde2563ead464ffa97963c59e002c0cf
  21
  22 *** Test Cases ***
  23 Create Original Cluster List
  24     [Documentation]    Create original cluster list.
  25     ${original_cluster_list}    Create Controller Index List
  26     Set Suite Variable    ${original_cluster_list}
  27     Log    ${original_cluster_list}
  28
  29 Verify Net-virt Features
  30     [Documentation]    Check Net-virt Console related features (odl-ovsdb-openstack)
  31     Verify Feature Is Installed    odl-ovsdb-openstack    ${ODL_SYSTEM_1_IP}
  32     Verify Feature Is Installed    odl-ovsdb-openstack    ${ODL_SYSTEM_2_IP}
  33     Verify Feature Is Installed    odl-ovsdb-openstack    ${ODL_SYSTEM_3_IP}
  34
  35 Check Shards Status Before Fail
  36     [Documentation]    Check Status for all shards in Ovsdb application.
  37     Check Ovsdb Shards Status    ${original_cluster_list}
  38
  39 Start Mininet Multiple Connections
  40     [Documentation]    Start mininet with connection to all cluster instances.
  41     ${mininet_conn_id}    Add Multiple Managers to OVS  ${TOOLS_SYSTEM_IP}    ${original_cluster_list}
  42     Set Suite Variable    ${mininet_conn_id}
  43     Log    ${mininet_conn_id}
  44
  45 Get manager connection
  46     [Documentation]    This will verify if the OVS manager is connected
  47     [Tags]    OVSDB netvirt
  48     Verify OVS Reports Connected
  49
  50 Check netvirt is loaded
  51     [Documentation]    Check if the netvirt piece has been loaded into the karaf instance
  52     [Tags]    Check netvirt is loaded
  53     ${netvirt}=    Create Dictionary    netvirt:1=1
  54     Wait Until Keyword Succeeds    6s    1s    Check Item Occurrence At URI In Cluster    ${original_cluster_list}    ${netvirt}    ${OPERATIONAL_NODES_NETVIRT}
  55
  56 Check External Net for Tenant
  57     [Documentation]    Check External Net for Tenant
  58     [Tags]    OpenStack Call Flow
  59     ${resp}=    Create Dictionary    "networks" : [ ]=1
  60     Check Item Occurrence At URI In Cluster    ${original_cluster_list}    ${resp}    ${ODLREST}/networks
  61
  62 Create External Net for Tenant
  63     [Documentation]    Create External Net for Tenant
  64     [Tags]    OpenStack Call Flow
  65     ${Data}    OperatingSystem.Get File    ${OVSDB_CONFIG_DIR}/create_ext_net.json
  66     ${Data}    Replace String    ${Data}    {netId}    ${EXT_NET1_ID}
  67     ${Data}    Replace String    ${Data}    {tntId}    ${TNT1_ID}
  68     Log    ${Data}
  69     Put And Check At URI In Cluster    ${original_cluster_list}    1    ${ODLREST}/networks    ${Data}