csit/suites/tsdr/H2/040_QueueMetrics.robot

   1 *** Settings ***
   2 Documentation     Test suite for H2 DataStore Queue Metrics Verification
   3 Suite Setup       Run Keywords    Start Tsdr Suite    Configuration of Queue on Switch
   4 Suite Teardown    Stop Tsdr Suite
   5 Library           SSHLibrary
   6 Library           Collections
   7 Library           String
   8 Library           ../../../libraries/Common.py
   9 Resource          ../../../libraries/KarafKeywords.robot
  10 Resource          ../../../libraries/TsdrUtils.robot
  11 Variables         ../../../variables/Variables.py
  12
  13 *** Variables ***
  14 @{QUEUE_METRICS}    TransmittedPackets    TransmittedBytes    TransmissionErrors
  15 ${TSDR_QUEUE_STATS}    tsdr:list QueueStats
  16 @{CMD_LIST}       FlowGroupStats    FlowMeterStats    FlowStats    FlowTableStats    PortStats    QueueStats
  17
  18 *** Test Cases ***
  19 Verify the Queue Stats attributes exist thru Karaf console
  20     [Documentation]    Verify the QueueMetrics attributes exist on Karaf Console
  21     Wait Until Keyword Succeeds    60s    1s    Verify the Metric is Collected?    ${TSDR_QUEUE_STATS}    Transmitted
  22     ${output}=    Issue Command On Karaf Console    ${TSDR_QUEUE_STATS}    ${ODL_SYSTEM_IP}    ${KARAF_SHELL_PORT}    30
  23     FOR    ${list}    IN    @{QUEUE_METRICS}
  24         Should Contain    ${output}    ${list}
  25     END
  26
  27 Verify QueueStats-Attributes on H2 Datastore using JDBC Client
  28     [Documentation]    Verify the QueueStats,attributes on H2 Datastore using JDBC Client
  29     FOR    ${list}    IN    @{QUEUE_METRICS}
  30         ${output}=    Query Metrics on H2 Datastore    QUEUESTATS    ${list}
  31         Should Contain    ${output}    ${list}
  32     END
  33
  34 Verify tsdr:purgeall command
  35     [Documentation]    Verify the tsdr:purgeall command
  36     Issue Command On Karaf Console    tsdr:purgeall    ${ODL_SYSTEM_IP}    ${KARAF_SHELL_PORT}
  37     FOR    ${list}    IN    @{CMD_LIST}
  38         ${out}=    Issue Command On Karaf Console    tsdr:list ${list}    ${ODL_SYSTEM_IP}    ${KARAF_SHELL_PORT}
  39         Should Contain    ${out}    no data of this category
  40     END
  41     FOR    ${list}    IN    @{QUEUE_METRICS}
  42         ${out}=    Query Metrics on H2 Datastore    QUEUESTATS    ${list}
  43         Should not Contain    ${out}    ${list}
  44     END
  45
  46 *** Keyword ***
  47 Configuration of Queue on Switch
  48     [Documentation]    Queue configuration on openvswitch
  49     Configure the Queue on Switch    s2-eth2